Office: Verweis über mehrere Arbeitsblätter

Mahlzeit,

zur letzten Basketballsaison habe ich mal aus Langeweile für mein Team ein kleines Statistiktool über Excel entwickelt.
Für die nun neue Saison will ich es gerne verfeinern, bleibe jedoch an einer wichtigen Stelle hängen.

Ich möchte auf einem Arbeitsblatt über ein DD den Spielernamen wählen und es sollen alle Spiele aufgelistet werden an denen der Spieler teilgenommen hat.
=WENN(Arbeitsblatt!E2:E13=A2;E15;"") funktioniert leider nicht und ich will ungern jedes einzelne Feld abfragen müssen, ie. die Wenn Funktion immer nur für eine Zelle beschreiben.
Noch weniger (und besser für meine Faulheit) funktioniert es mit einer INDIREKT Funktion, damit ich nich für jedes Arbeitsblatt eine Funktion schreiben muss.

Auf dem Arbeitsblatt "Spieler" sieht man den Anfang. A5 ist die Funktion wie ich sie gerne hätte und A6 ist die Funktion wie sie bisher nur funktioniert für mich.

 

Hallo!

Meinst du so?

=WENN(ZÄHLENWENN('Löhne G'!E2:E13;A2);Löhne G!E15;"")

 

10 Minuten und schon ein Ergebnis :-D

Das ist auf jeden Fall ein guter Lösungsansatz für mich.
Ich hab jetzt auch einen Ansatz gefunden über einen sverweis.

=WENN(SVERWEIS(A2;INDIREKT("'"&{"Löhne G";"Bulldogs H";"GTV G";"Kirchlengern H";"Quelle G";"Rheda H";"Bünde G";"Espelkamp H";"Borgholzhausen G";"Brackwede H";"Löhne H";"Bulldogs G";"GTV H";"Herford G";"Kirchlengern G";"Quelle H";"Rheda G";"Bünde H";"Borgholzhausen H";"Brackwede G"}&"'!E2:E13");1;FALSCH)=A2;INDIREKT("'"&{"Löhne G";"Bulldogs H";"GTV G";"Kirchlengern H";"Quelle G";"Rheda H";"Bünde G";"Espelkamp H";"Borgholzhausen G";"Brackwede H";"Löhne H";"Bulldogs G";"GTV H";"Herford G";"Kirchlengern G";"Quelle H";"Rheda G";"Bünde H";"Borgholzhausen H";"Brackwede G"}&"'!E15");"")

Mit dieser Form bekomme ich aber immer nur das erste Ergebnis ausgegeben, also Löhne G.
Gibt es noch eine Möglichkeit eine Reihenfolge reinzubekommen? Zum Beispiel auf den Arbeitsblättern bei E18 ein Datum eintragen?

 

Hallo!

Ein SVERWEIS über mehrere Blätter ist leider nur sehr bedingt möglich und funktioniert nur bei Zahlen.
Siehe dazu hier: http://excelformeln.de/formeln.html?welcher=233
Formelmäßig wirst du dir hier also etwas anderes überlegen müssen; oder diese Abfragen in VBA programmieren.

 

Hallo,

da ich für VBA zu doof bin, muss ich es mit Bordmitteln umsetzen. Mit nem Makro4Befehl (leider nach XL2010 nicht mehr unterstützt, lt. MS)
werden alle Blätter-Namen ausgelesen und daneben die Spalten.
Dann geht es mittels INDEX() und KKLEINSTE.

 

Hallo,

ich habe Dir die Datei mal überarbeitet. Bis auf die ausgefoult-Summe sollte es jetzt passen. Sieh sie Dir einfach mal an.


Sehe gerade, das es noch eine, für mich leider nicht lesbare Lösung gibt! Tsss...
Aber es sollte doch mit der Variante gehen, die <Peter> immer anwendet, zumal hier schon eine komplette Spielerliste in jedem Blatt existiert.


P.S. Die Datei läßt sich nicht anhängen. Geht doch, als zip.

Gruß

Edgar

 

Hallo Edgar,

in als xls, allerdings hab ich die WENNFEHLER Formel nicht geändert!

 

Hallo,

ich glaube, da habe ich einen Teil der Aufgabe falsch verstanden. Hier mal eine kleine Ergänzung:

1.VBA-Code, folgt im nächsten Beitrag
2.Auswertung mit Formeln, als Ergänzung zu meiner Tabelle von vorhin:

Arbeitsblatt mit dem Namen 'Spieler'
	A	B	C	D	E	F	G	H	I
1	Name	Anzahl Spiele						Löhne G	32
2	Barteldrees, J.							Bulldogs H	32
3								GTV G	32
4	Spiele	Punkte	3er	Freiwürfe	Fouls	Nummer		Kirchlengern H	32
5	Löhne G	9	9	0	2	32		Quelle G	0
6	Bulldogs H	16	12	0	1	32		Rheda H	32
7	GTV G	25	18	1	2	32		Bünde G	32
8	Kirchlengern H	24	18	2	3	32		Espelkamp H	32
9	Rheda H	11	3	0	0	32		Borgholzhausen G	32
10	Bünde G	30	6	0	3	32		Brackwede H	32
11	Espelkamp H	11	3	2	2	32		Löhne H	32
12	Borgholzhausen G	29	24	3	3	32		Bulldogs G	32
13	Brackwede H	12	12	0	2	32		GTV H	9
14	Löhne H	5	3	0	4	32		Herford G	32
15	Bulldogs G	24	18	0	1	32		Kirchlengern G	32
16	GTV H	20	18	0	0	9		Quelle H	32
17	Herford G	32	9	7	0	32		Rheda G	32
18	Kirchlengern G	20	18	0	2	32		Bünde H	32
19	Quelle H	34	24	0	2	32		Borgholzhausen H	32
20	Rheda G	13	12	1	2	32		Brackwede G	32
21	Bünde H	44	24	0	0	32
22	Borgholzhausen H	30	24	0	2	32

Name	Bezug
Team	=Team!$A$2:$A$24

Zelle	Formel
A5	{=WENN(ZEILE(A1)<ZÄHLENWENN($I$1:$I$20;">0");INDEX(H:H;KKLEINSTE(WENN($I$1:$I$20>0;ZEILE($1:$20));ZEILE(A1)));"")}
B5	=WENN(A5="";"";SVERWEIS($A$2;INDIREKT("'"&$A5&"'!L2:Q30");2;0))
C5	=WENN(A5="";"";SVERWEIS($A$2;INDIREKT("'"&$A5&"'!L2:Q30");5;0))
D5	=WENN(A5="";"";SVERWEIS($A$2;INDIREKT("'"&$A5&"'!L2:Q30");3;0))
E5	=WENN(A5="";"";SVERWEIS($A$2;INDIREKT("'"&$A5&"'!L2:Q30");6;0))
F5	=WENN(A5="";"";SVERWEIS(A5;$H$1:$I$20;2;0))
A6	{=WENN(ZEILE(A2)<ZÄHLENWENN($I$1:$I$20;">0");INDEX(H:H;KKLEINSTE(WENN($I$1:$I$20>0;ZEILE($1:$20));ZEILE(A2)));"")}
B6	=WENN(A6="";"";SVERWEIS($A$2;INDIREKT("'"&$A6&"'!L2:Q30");2;0))
C6	=WENN(A6="";"";SVERWEIS($A$2;INDIREKT("'"&$A6&"'!L2:Q30");5;0))
D6	=WENN(A6="";"";SVERWEIS($A$2;INDIREKT("'"&$A6&"'!L2:Q30");3;0))
E6	=WENN(A6="";"";SVERWEIS($A$2;INDIREKT("'"&$A6&"'!L2:Q30");6;0))
F6	=WENN(A6="";"";SVERWEIS(A6;$H$1:$I$20;2;0))
I1	=INDEX(INDIREKT("'"&H1&"'!K:K");VERGLEICH($A$2;INDIREKT("'"&H1&"'!L:L");0))
I2	=INDEX(INDIREKT("'"&H2&"'!K:K");VERGLEICH($A$2;INDIREKT("'"&H2&"'!L:L");0))

<table><tr><td>Achtung, Matrixformel enthalten!</td></tr><tr><td><span>Die geschweiften Klammern{} werden </span><span>nicht</span><span> eingegeben.</span></td></tr><tr><td><span>Verlassen Sie den Zelleneditor mit </span><span>Strg+Shift + Enter</span><span>, statt Enter alleine.</span></td></tr></table>[/parsehtml]

Zelle	Gültigkeitstyp	Operator	Wert1	Wert2
A2	Liste		=Team

<table><tr><td>Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg</td></tr></table>[/parsehtml]


Gruß

Edgar

 

Hallo,

hier der VBA-Code für "Diese Arbeitsmappe"

Der Code schreibt beim Öffnen der Tabelle alle Tabellennamen in Spalte H


Gruß

Edgar

 

Vielen vielen Dank an alle 3 Helfer.
Das hat mich mächtig nach vorne gebracht.

Vor allem hat es mich auch einiges gelehrt.
Im Nachhinein hätte ich mir ja schon einige Kopfschmerzen ersparen können, wenn ich gewusst hätte, dass ich eine Summe über Arbeitsblätter bilden kann a la 'arbeitsblatt1:arbeitsblattx'!A1 und mein Plan hätte sich insgesamt leichter gestalten können, indem ich nicht so kompliziert versuche eine Abbildung zu erstellen von einem variable Arbeitsbereich.
Erstmal alles in eine feste Tabelle, von der daraufhin ausgelesen werden kann.

EDIT: Ein kleiner Fehler ist mir jetzt aber noch aufgefallen. Das letzte Saisonspiel fehlt jeweils. Und wenn man nur 1 Spiel die Saison gemacht hat, dann wird dieses gar nicht erst in der Liste angezeigt.