Office: verweiss mit mehreren kriterien

Den Anhang help.xlsx betrachten

Servus,

ich bräuchte unbedingt Unterstützung bei einem verweis.
das ist die erste Woche in der ich mit Excel arbeite und habe doch schon einiges geschafft.

Für meine aktuelle Tabelle bräuchte ich einen wverweiss mit UND-Funktion.. ..aber das bekomme ich leider nicht hin.
Anbei eine vereinfachte Version meiner .xlsx in der ich das Problem mit einer WENN (UND)-Funktion gelöst habe, dass geht nur leider im Original nicht, Weil Excel nicht unendlich Verschachtelungen zulässt, außerdem würde man bestimmt 8Std. nur am Verschachteln sein.

Ich bin mir sicher, dass Ihr mir hier weiterhelfen könnt.

Danke schon einmal

 

Hallo!

Verbundene Zellen machen bei fast jeder Auswertung Schwierigkeiten! Wenn du diese auflöst, dann wird's einfach:

	A	B	C	D	E	F	G	H	I	J	K	L	M	N	O
7		Haupttyp	klein
8		Untertyp	18
9	WENN	Zuordnung	25
10	VERWEISS	Zuordnung	25
11
12										Haupttyp	klein	klein	groß	groß	groß
13										Untertyp	15	18	18	22	25
14										Zuordnung	18	25	45	60	70

Name	Bezug
groß	=Tabelle1!$L$3:$L$6
klein	=Tabelle1!$K$3:$K$5

Zelle	Formel
C9	=WENN(UND(C7=K3;C8=K4);K14;WENN(UND(C7=K3;C8=K5);L14;WENN(UND(C7=L3;C8=L4);M14;WENN(UND(C7=L3;C8=L5);N14;WENN(UND(C7=L3;C8=L6);O14;)))))
C10	=VERWEIS(2;1/((K12:O12=C7)*(K13:O13=C8));K14:O14)
K12	=K3
M12	=L3
K13	=K4
L13	=K5
M13	=L4
N13	=L5
O13	=L6

 

hi, alternativ, (und wenn's auch so bleiben soll)..:

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D	E	F	G	H	I	J	K	L	M	N	O
2
3											klein	groß
4											15	18
5											18	22
6												25
7		Haupttyp	groß
8		Untertyp	25
9	WENN	Zuordnung	70
10	VERWEISS	Zuordnung	70
11	INDEX	Zuordnung	70
12										Haupttyp	klein		groß
13										Untertyp	15	18	18	22	25
14										Zuordnung	18	25	45	60	70
15

Zelle	Formel
C10	=VERWEIS(C8;WENN(C7=K3;K13:L13;M13:O13);WENN(C7=K3;K14:L14;M14:O14))
C11	=INDEX(WAHL(VERGLEICH(C7;K3:L3;0);K14:L14;M14:O14);;VERGLEICH(C8;WAHL(VERGLEICH(C7;K3:L3;0);K13:L13;M13:O13)))

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

 

hi und ein WVERWEIS() ginge hier freilich auch..:

=WVERWEIS(C8;WAHL(VERGLEICH(C7;K3:L3;0);K13:L14;M13:O14);2;0)

 

super leute!! habs am gleichen abend in meiner großen Datei eingebracht und die ersten Kollegen arbeiten schon damit. :)