Office: VPA Suchfunktion mit Ausblenden

Hallo zusammen,

Ich habe ein Problem und finde nichts passendes.
Ich möchte mit einem Suchbutton, den Text eingeben und die tabelle1 (Spalte A15 bis B1000)durchsuchen.
Es sollten nur noch die gefundenen Zeilen gezeigt werden und der Rest ausgeblendet werden.

Wie kann ich das den lösen?

Wäre sehr dankbar über Hilfe, Danke euch!

 

Benutze Autofilter, kein VBA.

 

Hi,

Code:

Sub Ausblenden()
    Dim rngZelle As Range
    Dim varFrage As Variant
    Dim strStart As String
    Dim rngBereich As Range
    varFrage = Application.InputBox("Suchbegriff eingeben:")
    If varFrage <> False And varFrage <> "Falsch" Then
        Range("A1:A10000").EntireRow.Hidden = False
        Set rngZelle = Range("A1:B1000").Find(varFrage, lookat:=xlWhole)
        If Not rngZelle Is Nothing Then
            strStart = rngZelle.Address
            Do
                If rngBereich Is Nothing Then
                    Set rngBereich = Rows(rngZelle.Row)
                Else
                    Set rngBereich = Union(rngBereich, Rows(rngZelle.Row))
                End If
                Set rngZelle = Range("A1:B1000").FindNext(rngZelle)
            Loop While rngZelle.Address <> strStart
            rngBereich.EntireRow.Hidden = True
        Else
            MsgBox varFrage & " nicht gefunden"
        End If
    End If
End Sub

---

 

Hi,
Vielen dank für deine rasche Hilfe.
Leider blendet das VPA mir nun die Zeilen aus die im Suchbegriff gefunden wurden.
Ich würde aber genau nur die zur Ansicht benötigen.

Vielen Dank für deine Hilfe!

 

Hi,

dann so:

Code:

Sub Ausblenden()
    Dim lngZelle As Long
    Dim lngLetzte As Long
    Dim varFrage As Variant
    Dim strStart As String
    Dim rngBereich As Range
    varFrage = Application.InputBox("Suchbegriff eingeben:")
    If varFrage <> False And varFrage <> "Falsch" Then
        lngLetzte = Columns("A:B").Find(What:="*", SearchOrder:=xlByRows, SearchDirection:=xlPrevious).Row
        Range(Cells(1, 1), Cells(lngLetzte, 1)).EntireRow.Hidden = False
        For lngZelle = 1 To lngLetzte
            If Application.CountIf(Range(Cells(lngZelle, 1), Cells(lngZelle, 2)), varFrage) = 0 Then
                If rngBereich Is Nothing Then
                    Set rngBereich = Cells(lngZelle, 1)
                Else
                    Set rngBereich = Union(rngBereich, Cells(lngZelle, 1))
                End If
            End If
        Next lngZelle
        If Not rngBereich Is Nothing Then rngBereich.EntireRow.Hidden = True
    End If
End Sub

---

 

Hallo,

Vielen dank, soweit funktioniert das Makro sehr gut.
Kann man es noch schaffen das das Makro nur in der Tabelle1 A15:B1000 funktioniert.
So das mein Overlay Zeil1-13 eingeblendet bleibt?

Vielen Vielen Dank
LG

 

Hi,

in dieser Zeile

Code:

       For lngZelle = 1 To lngLetzte

wird festegelegt, von welcher Zeile an geprüft werden soll - passe dies einfach an.

---

 

Vielen herzlichen Dank!