Office: Wechsel von WAHR auf FALSCH identifzieren

Hallo zusammen!

Ich habe eine Tabelle erstellt, ob Merkmale in einem bestimmten Quartal mit Istwerten belegt sind oder nicht. Ich möchte diejenige Zeile nun kennzeichnen, sofern die Ausprägung innerhalb einer Zeile von WAHR auf FALSCH umspringt. Siehe auch gerne meine Beispieldatei.

Habt ihr dafür eine Formel für mich?

yorcky

 

Hola,
warum soll denn C16 markiert werden?
Gruß,
steve1da

 

Hallo.
Sorry, wenn ich mich unklar ausgedrückt habe. Ich möchte eine Formel, die mir in M16 "Problem" ausgibt, wenn die Ausprägung innerhalb einer Zeile von WAHR auf FALSCH umspringt. Ansonsten soll "ok" ausgegeben werden.

 

So?
=WENN(UND(ZÄHLENWENN($B14:$D14;WAHR)>0;ZÄHLENWENN($C14:$E14;FALSCH)>0);"Problem";"Ok")

 

Hallo steve1da,
das ist leider noch nicht die Lösung. Mit deiner Formel kann es Fälle geben, die ein Problem anzeigen, wo keines ist. Siehe die neue Mappe2, Zeile 18.
Ich möchte "Problem" nur angezeigt bekommen, wenn das Merkmal von WAHR auf FALSCH umspringt.

 

=WENN(ISTZAHL(SUCHEN("wahrfalsch";TEXTVERKETTEN(;FALSCH;B14:E14)));"Problem";"Ok")
oder
=WENN(ISTZAHL(SUCHEN("wahrfalsch";B14&C14&D14&E14));"Problem";"Ok")

 

Super, es funktioniert.
Ganz herzlichen Dank!

 

etwas kürzer:
=WENN(ZÄHLENWENN(B14:E14;WAHR)=4;"OK";"Problem")

oder bei variabler Spaltenanzahl:

=WENN(ZÄHLENWENN(B14:E14;WAHR)=SPALTEN(B14:E14);"OK";"Problem")

 

Mein Vorschlag:
=WENN(SUMME(B14:D14*NICHT(C14:E14));"Problem";"OK")
Oder wenn man auf die WAHR/FALSCH-Tabelle verzichten will:
=WENN(SUMME(ISTZAHL(B4:D4)*NICHT(ISTZAHL(C4:E4)));"Problem";"OK")
Wenn statt "Problem" und "OK" auch 1 und 0 gehen:
=SUMME(ISTZAHL(B4:D4)*NICHT(ISTZAHL(C4:E4)))
Alle diese Formel muss man runter ziehen. Als Spill-Variante geht auch
=NACHZEILE(B4:D9;LAMBDA(xx;SUMME(ISTZAHL(xx)*NICHT(ISTZAHL(BEREICH.VERSCHIEBEN(xx;;1))))))
Oder, wenn man auf das volatile BEREICH.VERSCHIEBEN verzichten will, und außerdem den vollen Bereich angeben will, ohne zu beachten, dass in der vorigen Formel die letzte Spalte bei der Angabe weggelassen werden muss:
=NACHZEILE(B4:E9;LAMBDA(xx;SUMME(ISTZAHL(WEGLASSEN(xx;;-1))*NICHT(ISTZAHL(WEGLASSEN(xx;;1))))))