Office: (Office 365) Wechselkurs vom Vortag sowie WE

Guten Morgen,

in der beigefuegten Tabelle muessten der Wechselkurs fuer € und US$ jeweils vom Vortag uebernommen werden. Generell habe ich es hinbekommen, aber bei den Wochenenden sowie beim Montag muesste der Freitag uebernommen werden. es ginge ueber die Wochentage. Die Wechselkurse sollten aus den Spalten G+H in B+C eingetragen werden. In Spalte E sind die Wochentage zu finden.

Das Datum erscheint in einem anderen Report als yyyymmdd. Mit Text habe ich es geschafft auf ein Datum umzustellen und eine Formel drauss zu stricken. Die Wochentage konnte ich damit herauslesen, aber wie ich es zusammenbekomme, dass es mir fuer die Wochenenden+Montag automatisch den Freitag ausgibt erschliesst sich mir nicht. Vielleicht mit if(weekdays()1 bis 4,dann...? Wie schreibe ich 1 bis 4?

Darueber hinaus waere es gut, wenn die Wochenenden farblich markiert wuerden, was ich ueber bedingte Formatierung fuer Spalte A versucht habe und an den Datumsangaben gescheitert bin, falls hierzu jemand eine Idee haette?

Viele Gruesse
Matthias

Nachtrag: Wenn ich =IF(WEEKDAY(TEXT(RIGHT(A8,2)&"/"&MID(A8,5,2)&"/"&LEFT(A8,4),"dd/mm/yyyy")*1,2)=4,INDEX(H:H,MATCH((TEXT(RIGHT(A8,2)&"/"&MID(A8,5,2)&"/"&LEFT(A8,4),"dd/mm/yyyy")*1)-1,F:F,0),),"Y") eingebe funktioniert es fuer einen Tag, aber die anderen drei gehen auf "Y".

 

Hola,
das korrekte Datum aus Spalte A ermittelst du mit:
=DATUM(LINKS(A5;4);TEIL(A5;5;2);RECHTS(A5;2))
Die Tageskurse holst du dir dann mit einem Sverweis (Suchkriterium ist das Datum mit obiger Formel minus 1) aus der Suchmatrix F4:H29, mit dem vierten Parameter WAHR.
Die Färbung der Wochentage ist insofern falsch als dass deine Daten erst in A5 beginnen, die Formel aber mit A2. Außerdem musst du auch hier wieder die obige Formel als Grundlage nehmen.
Gruß,
steve1da

 

Hola,
super, danke dir @steve1da. Eine Frage ist mir entgangen bzw. war nicht in der Datei, weil das Datum erst von Datum in Text umgewandelt wird um es dann als Datum wieder zu nutzen. Der Report wird mit dem Datum wie in Spalte A geliefert wird. Habe es mit der Datumsformel oben probiert und fuer Spalte F kommt 01/01/4520 (bezogen auf den 2.10.23) raus. Mit der Textformel =TEXT(LEFT(M3,4)&MID(M3,5,2)&RIGHT(M3,2),"YYYYMMDD") kommt #Value raus. Wie kann ich es mit der Customsformatierung in eine Zahl umwandeln?
Gruss
Matthias

Nachtrag: Bin mit =YEAR(M3)&MONTH(M3)&DAY(M3) recht nahe, aber wird als Text ausgegeben und der Tag nur mit einer Stelle. Ich braeuchte acht Stellen.

 

Das hier hat funktioniert: =TEXT(DATE(YEAR(M3),MONTH(M3),DAY(M3)),"YYYYMMDD")*1. Weiss nicht, ob was eleganteres gibt, aber es scheint zu gehen. Konnte noch keine Fehler entdecken.

Wuerdest du mir noch erklaeren, wie es funktioniert, dass der Sverweis fuer die drei Tage die richtige Rate findet? Falls es daran liegt.

 

Lade bitte eine neue Datei hoch, keine Ahnung was in M3 steht.
Und ebenfalls weiß ich nicht was du mit dem Sverweis meinst. Welche 3 Tage? Woran soll was liegen?

 

Hallo,

du hast als Excel-Version Excel365 angegeben. Ich habe daher im Folgenden die Vorteile dieser Version etwas ausgenutzt.

Ich habe dir 3 benutzerdefinierte Funktionen in den Namensmanager eingefügt. Diese können in der vorliegenden Arbeitsmappe wie eingebaute Funktionen verwendet werden. Sie dienen dazu, das Leben im Arbeitsblatt erheblich zu vereinfachen.
Unter dem Namen
YMD: = LAMBDA(txt; DATUM(LINKS(txt;4);TEIL(txt;5;2);RECHTS(txt;2)))
YMDWoTg: = LAMBDA(txt; WOCHENTAG(YMD(txt);2))
YMDWoEnde: = LAMBDA(txt; YMDWoTg(txt)>5)
Wie sie anzuwenden sind und welche Rückgabewerte sie liefern, habe ich dir in einer kleinen Demo-Tabelle in M3:P11 dargestellt.

Ferner habe ich Gebrauch gemacht von der XVERWEIS-Funktion, die Parameter besitzt, die genau bei deinem Problem von großem Vorteil sind (fett bzw. rot eingefärbt):
Formel in Zelle B5: =XVERWEIS(YMD($A5)-1;$F$7:$F$29;$H$7:$H$29;"nichts";-1;1)
Formel in Zelle C5: =XVERWEIS(YMD($A5)-1;$F$7:$F$29;$G$7:$G$29;"nichts";-1;1)
Formel in Zelle E5: =YMDWoTg(A5)

Als Formel für die bedingte Formatierung des Bereiches A5:C38 habe ich folgende Formel verwendet:
=YMDWoEnde($A5)

Datei liegt bei.

 

Hallo,
entschuldige, ist mir entgangen. Neuer Job und Land unter. Werde es gleich ausprobieren, vielen Dank.
VG
Matthias