Office: Welcher User hat andere Excel-Datei geöffnet

fischerpeter · 3. September 2016

Hallo,
nach mehrstündigem Suchen in vielen Excel-Foren habe ich nichts Passendes gefunden und versuche es jetzt auf diesem Weg.

Ich öffne per vba eine andere Excel-Datei (test.xls), die auch von anderen Usern im Netzwerk geöffnet werden kann, aber bewusst keinen Mehrfachschreibzugriff erlaubt.

Wenn ein anderer User diese test.xls geöffnet hat und ich öffne nun per vba die test.xls, dann sehe ich diese Datei auf meinem Monitor, allerdings im Modus schreibgeschützt.

Ich möchte gerne an die Information kommen, wie dieser andere User heißt. Kann mir jemand helfen?

Grüße
fischerpeter

:)

fischerpeter · 5. September 2016

Nachtrag zum Problem von fischerpeter von geradeeben:
Auf die Excel-Datei test.xls habe ich keinen Zugriff, ich kann dort also keinen Code einbauen, also z.b. immer wenn ein User die Datei geöffnet hat, in test.xls den Usernamen in einer bestimmten Zelle zu hinterlegen, damit ich ihn abfragen kann. Das geht also nicht.

Viele Grüße
fischerpeter

Tacker · 5. September 2016

Guten Abend,

Bevor ich auf .csv umgestiegen bin habe ich .xls als Datenbank für mein Makro im CAD benutzt, und wenn ich mich richtig erinnere dann hat Excel erstens einen Wert bereit ob das Worksheet schreibgeschützt ist und auch wer momentan die Berechtigung zum Bearbeiten hat. Hab hier kein Excel, frühestens morgen könnte ich was dazu sagen. Aber definiere dir die test.xls doch mal als Worksheet, stoppe dann den Code (F9) öffne dein "Locals" Fenster und schau mal was in deiner Variablen alles drinsteht.

Gruß Tacker

Scorefun · 5. September 2016

Ich habe im Netz mal diesen Code gefunden, der allerdings nur bei xls funktioniert, und nicht bei xlsx oder xlsm

Code:

Public Function LastUser(strPath As String) As String
'// Code by Helen from You searched for • Visual Basic Forum
'// This routine gets the Username of the File In Use
'// Credit goes to Helen for code & Mark for the idea
'// Insomniac for xl97 inStrRev
'// Amendment 25th June 2004 by IFM
'// : Name changes will show old setting
'// : you need to get the Len of the Name stored just before
'// : the double Padded Nullstrings
Dim strXl As String
Dim strFlag1 As String, strflag2 As String
Dim i As Integer, j As Integer
Dim hdlFile As Long
Dim lNameLen As Byte

strFlag1 = Chr(0) & Chr(0)
strflag2 = Chr(32) & Chr(32)

hdlFile = FreeFile
Open strPath For Binary As #hdlFile
strXl = Space(LOF(hdlFile))
Get 1, , strXl
Close #hdlFile

j = InStr(1, strXl, strflag2)

#If Not VBA6 Then
'// Xl97
For i = j - 1 To 1 Step -1
If Mid(strXl, i, 1) = Chr(0) Then Exit For
Next
i = i + 1
#Else
'// Xl2000+
i = InStrRev(strXl, strFlag1, j) + Len(strFlag1)
#End If

'// IFM
lNameLen = Asc(Mid(strXl, i - 3, 1))
LastUser = Mid(strXl, i, lNameLen)

End Function
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

edit:

Hierzu ist auch noch folgende Routine hilfreich

Code:

Function IsFileOpen(strFullPathFileName As String) As Boolean
'// VBA version to check if File is Open
'// We can use this for ANY FILE not just Excel!
'// Ivan F Moala
'// http://www.xcelfiles.com
Dim hdlFile As Long

'// Error is generated if you try
'// opening a File for ReadWrite lock >> MUST BE OPEN!
On Error GoTo FileIsOpen:
hdlFile = FreeFile
Open strFullPathFileName For Random Access Read Write Lock Read Write As hdlFile
IsFileOpen = False
Close hdlFile
Exit Function
FileIsOpen:
'// Someone has it open!
IsFileOpen = True
Close hdlFile
End Function
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Demnach wie folgt anzuwenden:

Code:

dim sFile as string
dim sUser as string

sFile = "u:\test.xls"

if isFileopen(sFile) then
sUser = LastUser(sFile)
msgbox "Datei wird von " & sUser & " verwendet"
else
'Datei normal öffnen
end if
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

fischerpeter · 5. September 2016

Hallo scorefun,
leider habe ich genau die Ausnahme, wo es nicht geht, nämlich eine xlsx-Datei.

Grüße
fischerpeter

fischerpeter · 5. September 2016

Hallo Tacker,
ich habe mir die Locals mal bei gestoppten Code angeschaut, da ist der User, der die Datei gerade geöffnet hat, nicht dabei. Leider, wäre ein guter Ansatz gewesen.

Grüße
fischerpeter

Scorefun · 12. Januar 2021

von fischerpeter

Hallo scorefun,
leider habe ich genau die Ausnahme, wo es nicht geht, nämlich eine xlsx-Datei.

Grüße
fischerpeter
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Das steht aber nicht in Deiner Fragestellung, denn sonst hätte ich mir meine Antwort sparen können

Scorefun · 6. September 2016

Für xlsx und xlsm Mappen hatte ich mir vor ziemlich exakt 2 Jahren mal einen Workaround gebastelt:
(Bitte nicht lachen über den Funktionsnamen)

Code:

Public Function wilma(sPathFile As String) As String
'Wilma = Who is locking my Arbeitsmappe ;-))
'Erstellt von scorefun in 09/2014

'Ermittelt den Benutzer einer geöffneten xlsx oder xlsm Arbeitsmappe
'anhand der von Excel angelegten Temp-Datei im gleichen Verzeichnis, die mit ~$ beginnt

'Arbeitsmappe = c:\test.xlsx
'Tempdatei = c:\~$test.xlsx

'Rückgabe ist allerdings nicht der Windows-Anmeldename, sondern
'der Benutzername, der in den Excel-Optionen unter Allgemein eingetragen ist.
'Wenn da nichts steht: Pech gehabt - dann wird halt nur 'Unbekannter Benutzer' zurückgegeben

Dim FSO As Object
Dim oFile As Object
Dim sExt As String
Dim sFileTemp As String, tempFolder As String, sFileTempCopy As String
Dim p As Integer
Dim sLines
Dim s As String
Dim sPath As String
Dim sFile As String
Set FSO = CreateObject("Scripting.FileSystemObject")

sExt = Right(sPathFile, 4)

If Mid(sExt, 1, 3) "xls" Then
MsgBox "Bitte nur Excel-Dateien > Office 2003 übergeben", 48, "WILMA - Who is Locking My Arbeitsmappe?"
Exit Function
Else

p = InStrRev(sPathFile, "\", -1, 1)
'Komplette Datei aufteilen in Pfad...
sPath = Left(sPathFile, p)
'...und Datei
sFile = Mid(sPathFile, p + 1, Len(sPathFile) - p)
'Temp-Dateiname ermitteln
sFileTemp = sPath & "~$" & sFile
'Temp-Folder des Rechners ermitteln
tempFolder = FSO.GetSpecialFolder(2) & "\"

If FSO.FileExists(sFileTemp) Then
'Temp-Datei ins Temp-Verzeichnis kopieren,
'da kein direkter Zugriff möglich
sFileTempCopy = tempFolder & sFile
FSO.copyFile sFileTemp, sFileTempCopy
'Datei öffnen
Set oFile = FSO.OpenTextFile(sFileTempCopy)
sLines = Split(oFile.ReadAll, vbCrLf)
'In der ersten Zeile steht der Name
s = sLines(0)
s = Left(s, InStr(1, s, " ", vbTextCompare) - 1)

'Manchmal steht da noch ein Sonderzeichen vor
If Asc(Left(s, 1)) < 65 Then
s = Mid(s, 2, Len(s) - 1)
End If
'Datei schließen
oFile.Close
'Temp-Datei löschen
FSO.DeleteFile sFileTempCopy
'Benutzer zurückgeben, falls vorhanden
If Len(Trim(s)) > 0 Then
wilma = Trim(s)
Else
wilma = "Unbekannter Benutzer"
End If
Else
'Datei ist nicht geöffnet
wilma = ""
End If

End If

Set oFile = Nothing
Set FSO = Nothing
End Function
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

fischerpeter · 6. September 2016

Hallo scorefun,
ich bin immer wieder erstaunt, welches geballtes Excel-Wissen in diesem Forum steckt. Deine Version mit dem temp-Datei funktioniert einwandfrei.
Vielen Dank, du hast mir sehr geholfen.
fischerpeter

Scorefun · 6. September 2016

Danke, dann kannst Du dieses Thema ja auf erledigt setzen und mit 5 Sternen bewerten ;-)

xlph · 6. September 2016

Wie vergibt man 5 Sterne?

Scorefun · 12. Januar 2021

von xlph

Wie vergibt man 5 Sterne?
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Über dem ersten Beitrag der Button rechts "Thema bewerten" *Smilie

Office: Welcher User hat andere Excel-Datei geöffnet

Welcher User hat andere Excel-Datei geöffnet

Welcher User hat andere Excel-Datei geöffnet

Welcher User hat andere Excel-Datei geöffnet

Welcher User hat andere Excel-Datei geöffnet

Welcher User hat andere Excel-Datei geöffnet - Similar Threads - User Excel Datei

Bearbeitung nur für bestimmte User

Userform unterdrücken - wenn Datei von andere Datei geöffnet wird

User form Drucken Position

User Form

VBA Hilfe Abfrage ob UserForm vom anderen User geöffnet ist

Windows User Name in Excel

Exceldatei nur von bestimmten Personen öffnen