Office: Wenn gestaffelt mit Sverweis

Hallo,

ich stell mich mal wieder sowas von blöd an.

Im Grunde habe ich zwei Werte in der Tabelle in B4 (HR#) und B3 (SHh#), die ich vorgebe, um dann in untiger Tabelle den Wert raussuchen zu lassen, wenn B4 = 24 ist soll er mit sverweis die SHh# vergleichen aus B3 und mir den 2. Wert aus der Spalte ausgeben.
Beispiel:
B3=44
B4=24
Ergebnis=5

Zusätzlich habe ich noch eine Frage: Gibt es die Möglichkeit dieses Feld was die Formel dann raussucht noch gelb zu markieren?

• SHh | HR 22 | HR 24 | HR 26
  38 | 2 | |
  39 | 3 | 1
  40 | 3 | 1
  41 | 4 | 2
  42 | 5 | 3 | 1
  43 | 6 | 4 | 2
  44 | 7 | 5 | 3
  45 | | 5 | 3
  46 | | 6 | 4
  47 | | 7 | 5
  48 | | | 6
  49 | | | 7

Folgenden Versuch habe ich schon angefangen, irgendetwas mache ich aber falsch:
=WENN("HR "&$B$4<"HR "&24;SVERWEIS($B$3;$C$14:$O$25;2;);WENN("HR "&$B$4="HR "&24;SVERWEIS($B$3;$C$14:$O$25;3;);SVERWEIS($B$3;$C$14:$O$25;4;)))

Vielen Dank schon vorab!
SethSeb

 

Hallo!

	A	B	C	D	E	F
1	SHh	HR 22	HR 24	HR 26		44
2	38	2				24
3	39	3	1			5
4	40	3	1
5	41	4	2
6	42	5	3	1
7	43	6	4	2
8	44	7	5	3
9	45		5	3
10	46		6	4
11	47		7	5
12	48			6
13	49			7

Zelle	Formel
F3	=INDEX(B2:D13;VERGLEICH(F1;A2:A13;);VERGLEICH("HR "&F2;B1:D1;))

 

Hi Schatzi,

bist ein Schatz .
Hat einwandfrei funktioniert.

Eine Frage habe ich jedoch noch.
Gibt es die Möglichkeit das Feld in den Spalten B-D farblich zu markieren, als sogenanntes visuelles Kontrollfeld?

Vielen Dank auch hier für die Hilfe.
SethSeb

 

Hallo!

Mit der bedingten Formatierung (bezogen auf mein Beispiel):
Markiere B2:D13 (von B2 aus)
Bedingte Formatierung > Formel ist >
=(VERGLEICH($F$1;$A$2:$A$13;)=ZEILE(A1))*(VERGLEICH("HR "&$F$2;$B$1:$D$1;)=SPALTE(A1))

 

Hallo Schatzi,

vielen Dank, jedoch stell ich mich entweder zu doof an oder mach einen Fehler.
Bei mir funktioniert das nicht.

ich habe deine Formel mal umgeschrieben und die Datei angehangen, vielleicht findest du meinen Fehler

=(VERGLEICH($B$3;$D$14:$O$25;)=ZEILE($C$13))*(VERGLEICH("HR "&$B$4;$D$13:$O$13;)=SPALTE($C$13))

LG & Danke
SethSeb

 

Hallo!

Diese Formel in der Bedingten Formatierung:

=(VERGLEICH($B$3;$C$14:$C$25;)=ZEILE(A1))*(VERGLEICH("HR "&$B$4;$D$13:$O$13;)=SPALTE(A1))

 

Hallo Schatzi,

vielen Dank das funktioniert super.

Kannst man das auch mit der unteren Tabelle machen?
Mein Ansatz war da folgende Formel, funktionieren tuts leider nicht, kenne mich leider kein bischen mit der bedingten Formatierung aus:

=(VERGLEICH($B$6;$C$32:$C$38;)=ZEILE(A1))*(VERGLEICH("HR "&$B$4;$D$30:$O$30;)=SPALTE(A1))*(VERGLEICH($B$5;$D$31:$O$31)=SPALTE(A1))

Vielen Dank schon jetzt für die Hilfe.

LG
SethSeb

 

Hallo!

Deine verbundenen Zellen machen die Sache komplizierter als nötig...
Wenn du wieder einmal eine Tabelle erstellst, dann versuche auf verbundene Zellen zu verzichten!

ohne Gewähr:

=(VERGLEICH("HR "&$B$4;$D$30:$O$30;)=1+KÜRZEN((SPALTE(A$1)-1)/4)*4)*(D$31=$B$5)*($C32=$B$6)