Office: (Office 2016) Wenn in Spalte A etwas eingetragen wird, dann....

Helfe beim Thema Wenn in Spalte A etwas eingetragen wird, dann.... in Microsoft Excel Hilfe um das Problem gemeinsam zu lösen; Moin zusammen, folgendes Problem: Ich sitze in der Produktionsplanung und ich versuche eine Excel Tabelle zu erstellen für Terminverschiebungen. Das... Dieses Thema im Forum "Microsoft Excel Hilfe" wurde erstellt von MakroBeginner, 13. November 2021.

  1. Wenn in Spalte A etwas eingetragen wird, dann....


    Moin zusammen,

    folgendes Problem: Ich sitze in der Produktionsplanung und ich versuche eine Excel Tabelle zu erstellen für Terminverschiebungen. Das ganze läuft so ab, dass die Produktionsmitarbeiter eintragen sollen, welche Produktion sie nicht rechtzeitig fertigen können und wir in der Planung tragen Auftragsnummer ein und versenden eine Mail an den Vertrieb. So weit so gut.

    Um den manuellen Aufwand so gering wie möglich zu halten, habe ich schon einiges geschafft. Ich scheitere aber gerade an einer (so scheint es mir zumindest) einfachen Idee:
    Sofern in Spalte A ein neuer Eintrag erfolgt ("Produktionsnummer"), dann soll erstmals geprüft werden, ob diese Nummer schon in Spalte A existiert. Sollte diese Nummer beriets eingetragen sein, soll eine Fehlermeldung erscheinen.
    Sollte der Eintrag neu sein, soll in Spalte G der Wert "neu" eingetragen werden (die Werte dazwischen sind Datenbankabfragen).
    Andersherum soll die Spalte G natürlich nichts mehr enthalten, sollte der Wert in Spalte A mal wieder rausgenommen werden. Mit einer Wenn Funktion wäre das sehr simpel, wie funktioniert das im Makro?

    Ich freue mich über jeden sachdienlichen Hinweise ;) :D Das würde uns sehr viel Arbeit abnehmen.
    Vielen Dank vorab!
     
    MakroBeginner, 13. November 2021
    #1
  2. Hajo_Zi
    Hajo_Zi Erfahrener User
    das geht nur per VBA.
    starte den VBA Editor (Alt+F11), Bild sollte zweigeteilt sein ansonsten Strg+R, Doppelklick auf Deine Datei, Doppelklick auf Deine Tabelle, Code ins rechte Fenster kopieren, VBA Editor schließen.
    Das Makro wird automatisch gestartet.
    Der Code wirkt nur in dieser Tabelle.

    Code:
    Option Explicit
    
    Private Sub Worksheet_Change(ByVal Target As Range)
        Dim Rafound As Range
        Set Rafound = Columns(1).Find(Target, Range("A1"), , xlPart, , xlNext)
        ' xlPart enthalten
        ' xlWhole kompletter Vergleich
        If Not Rafound Is Nothing Then
            Range("G" & Target.Row) = "Neu"
        Else
            MsgBox "schon vorhanden in Zeile " & Target.Row
        End If
        Set Rafound = Nothing
    End Sub
    
    Wenn in Spalte A etwas eingetragen wird, dann.... GrußformelWenn in Spalte A etwas eingetragen wird, dann.... Homepage
     
  3. Hi,

    danke schonmal Hajo_Zi. Es arbeitet schon mal gut. Problem ist jetzt, dass er immer anzeigt, dass die Produktion schon existiert, nämlich in der gerade eingefügten Zeile. Wie kann das umgangen werden?
    Er soll ja nur bei doppelten Werten sich melden. Aber die MsgBox mit der Anzeige, wo die bereits vorhanden ist, ist klasse!
     
    MakroBeginner, 13. November 2021
    #3
  4. Beverly
    Beverly Erfahrener User

    Wenn in Spalte A etwas eingetragen wird, dann....

    Hi,

    hier eine Variante, die nur ausgeführt wird wenn in Spalte A etwas eingegeben wird, bei einer Doppeleingabe wieder rückgängig gemacht und beim (späteren) Löschen eines Eintrags auch Spalte G wieder geleert wird:

    Code:
    Private Sub Worksheet_Change(ByVal Target As Range)
        Dim rngFind As Range
        Set Target = Intersect(Target, Columns(1))
        ' Eingabe erfolgt in Spalte A
        If Not Target Is Nothing Then
            ' Inhalt wurde gelöscht
            If Target = "" Then
                ' Spalte G leeren
                Target.Offset(0, 6).ClearContents
            Else
                ' suche die Eingabe in Spalte A
                Set rngFind = Columns(1).Find(Target.Value, lookat:=xlWhole)
                ' Eingabe nur einmal vorhanden
                If rngFind.Address = Target.Address Then
                    ' in Spalte G Eintrag
                    Target.Offset(0, 6) = "neu"
                ' Eingabe bereits vorhanden
                Else
                    ' Reaktion auf Eingabe abschalten
                    Application.EnableEvents = False
                    MsgBox "Bereits vorhanden"
                    ' Eingabe rückgängig machen
                    Application.Undo
                    ' Reaktion auf Eingabe wieder einschalten
                    Application.EnableEvents = True
                End If
            End If
        End If
    End Sub
    
    

    Wenn in Spalte A etwas eingetragen wird, dann.... GrußformelWenn in Spalte A etwas eingetragen wird, dann.... Beverly's Excel - Inn
     
  5. Hajo_Zi
    Hajo_Zi Erfahrener User
    Entschuldigung, nicht ausführlich getestet.
    Code:
    Option Explicit
    
    Private Sub Worksheet_Change(ByVal Target As Range)
        Dim Rafound As Range
        If Target.Column = 1 Then
            Set Rafound = Columns(1).Find(Target, Range("A1"), , xlPart, , xlNext)
            ' xlPart enthalten
            ' xlWhole kompletter Vergleich
            If Rafound Is Nothing Or Target.Address = Rafound.Address Then
                Application.EnableEvents = False
                Range("G" & Target.Row) = "Neu"
                Application.EnableEvents = True
            Else
                MsgBox "schon vorhanden in Zeile " & Rafound.Row
            End If
            Set Rafound = Nothing
        End If
    End Sub
    
     
  6. Wow klasse! Das funktioniert.

    Vielen lieben Dank!!!
     
    MakroBeginner, 13. November 2021
    #6
Thema:

Wenn in Spalte A etwas eingetragen wird, dann....

Die Seite wird geladen...
  1. Wenn in Spalte A etwas eingetragen wird, dann.... - Similar Threads - Spalte eingetragen

  2. identische Werte in Spalte nur einmal zählen

    in Microsoft Excel Hilfe
    identische Werte in Spalte nur einmal zählen: Hallo. Ich bitte um eure Unterstützung. Ich bin auf der Suche nach der richtigen Formel um die Anzahl der unterschiedlichen Tage angezeigt zu bekommen. Es soll auch dann noch gezählt werden, wenn...
  3. Größte zahl in spalte in TextBox

    in Microsoft Excel Hilfe
    Größte zahl in spalte in TextBox: Hallo zusammen Ich möchte gerne das die größte zahl aus der Spalte B in der TextBox angezeigt wird. So weit bin ich schon gekommen. Private Sub CommandButton1_Click() Dim Spalte As Long Dim...
  4. Wie kann ich die x häufigsten Ausdrücke aus einer Spalte ermitteln?

    in Microsoft Excel Hilfe
    Wie kann ich die x häufigsten Ausdrücke aus einer Spalte ermitteln?: Nach umfangreicher Recherche und einigem Probieren konnte ich meine Anforderung noch nicht erfüllen. Nun hoffe ich auf Eure Unterstützung. Für ein Tippspiel importieren wir regelmäßig aus einer...
  5. Wenn ein Wert ein einer Spalte, dann komplette Zeile im anderen Blatt untereinander einfügen.

    in Microsoft Excel Hilfe
    Wenn ein Wert ein einer Spalte, dann komplette Zeile im anderen Blatt untereinander einfügen.: Hallo, kann mir jemand bitte bei folgenderm Helfen. Habe etwas ähnliches gefunden was ich brauche, nur noch eine kleine Änderung ist notwendig. Aufgabe: Es wird geprüft, ob in Spalte Q ein Wert...
  6. Mittelwert aus mehreren Spalten als dynamisches Array

    in Microsoft Excel Hilfe
    Mittelwert aus mehreren Spalten als dynamisches Array: Hallo liebes Forum, ich bin bei folgendem Problem ratlos: Ich berechne für verschiedene Dozenten Feedback anhand von 3 verschiedenen Kriterien. Die Stammdaten der Feedbacks stehen in einer...
  7. den zuletzt eingetragenen Wert aus einer Spalte in eine Zelle übernehmen

    in Microsoft Excel Hilfe
    den zuletzt eingetragenen Wert aus einer Spalte in eine Zelle übernehmen: Seit langem habe ich mal wieder ein Problem, das ich hoffentlich mit eurer Hilfe gelöst bekomme. Ich möchte immer den zuletzt eingetragenen Wert aus einer Spalte in eine Zelle übernehmen. Ich habe...
  8. Spalte zählen wenn dort Wert eingetragen

    in Microsoft Excel Hilfe
    Spalte zählen wenn dort Wert eingetragen: Frage zu Excel: Benötige eine Formel für folgenden Fall: In einer Spalte sind mehrere x eingetragen. Manchmal auch keins. Als Ausgabewert soll dann entweder eine 1 stehen (wenn ein oder mehrere x...
  1. Diese Seite verwendet Cookies, um Inhalte zu personalisieren, diese deiner Erfahrung anzupassen und dich nach der Registrierung angemeldet zu halten.
    Auf dieser Website werden Cookies für die Zugriffsanalyse und Anzeigenmessung verwendet.
    Wenn du dich weiterhin auf dieser Seite aufhältst, akzeptierst du unseren Einsatz von Cookies.
    Information ausblenden