Office: (Office 2013) Wenn Texteingabe in x, dann Textänderung in y (DropDownMenü)

Hallo direkt ein zweites Mal. :p

Ich hätte da noch eine Frage zu meiner Tabelle.

In Spalte B habe ich eine Auswahlliste ("Auftragsstatus") und je nachdem, welcher Status festgelegt wird, ändert sich die Farbformatierung der Zeile. In Spalte E soll der Name des Auftragnehmers eingetragen werden und ich würde gerne, dass sich bei dessen Eingabe der Auftragsstatus (Spalte B) automatisch auf den Auswahllistenwert "Übergeben" ändert.

Also, sobald eine Eingabe in z.B. Zelle E5 erfolgt (ist), soll der Text in B5 in "Übergeben" geändert werden.

Das ist zwar nicht wirklich notwendig, aber wäre ein nettes Detail :D


Liebe Grüße.

 

Hallo Nina97,

auch hier wieder der Hinweis auf die Beispieldatei.
Und für jede einzelne Frage einen eigenen Thread aufzumachen, halte ich für extrem unübersichtlich.
Besser wäre beide Fragestellungen gemeinsam zu behandeln, da es ja um die gleiche Datei geht.

 

Hi Nina,

mit folgendem Code im Codemodul des betreffenden Tabellenblattes lässt sich das lösen:

Code:

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim rngBereich As Range
    Set rngBereich = Columns(2).SpecialCells(xlCellTypeAllValidation)
    If Target.Column = 5 Then
        If Target.Count = 1 And Target <> "" Then
            If Not Intersect(Target.Offset(0, -3), rngBereich) Is Nothing Then
                Application.EnableEvents = False
                Target.Offset(0, -3) = "Übergeben"
                Application.EnableEvents = True
            End If
        End If
    End If
    Set rngBereich = Nothing
End Sub

Bis später,
Karin

 

Hey,

also, ich bin über ALT+F11 in dieses VBA gewechselt und habe dann dort den Codeabschnitt eingefügt, das klappt wie gewünscht :)

Jetzt wollte ich das Ganze noch auf die "Artikelbezeichnung"+Spalte ausweiten und habe den Code dementsprechend angepasst - und einzeln für sich funktionieren beide, leider aber nicht gemeinsam. Ich kenne mich aber auch überhaupt nicht aus mit dem Thema

Es kam die Fehlermeldung: "Fehler beim Kompilieren: Mehrdeutiger Name: Worksheet_Change"

Dann habe ich eine "Sub Worksheet_Change"-Zeile in "Sub Worksheet_Change2" umbenannt, ging auch nicht :p

Code:

Sub Worksheet_Change(ByVal Target As Range)
'Bei Eingabe der Artikelbezeichnung wird der Auftragsstatus auf "Erstellt" gesetzt
    Dim rngBereich As Range
    Set rngBereich = Columns(2).SpecialCells(xlCellTypeAllValidation)
    If Target.Column = 4 Then
        If Target.Count = 1 And Target <> "" Then
            If Not Intersect(Target.Offset(0, -2), rngBereich) Is Nothing Then
                Application.EnableEvents = False
                Target.Offset(0, -2) = "Erstellt"
                Application.EnableEvents = True
            End If
        End If
    End If
    Set rngBereich = Nothing
End Sub

Sub Worksheet_Change(ByVal Target As Range)
'Bei Eingabe des Auftragnehmers wird der Auftragsstatus auf "Übergeben" gesetzt
    Dim rngBereich As Range
    Set rngBereich = Columns(2).SpecialCells(xlCellTypeAllValidation)
    If Target.Column = 5 Then
        If Target.Count = 1 And Target <> "" Then
            If Not Intersect(Target.Offset(0, -3), rngBereich) Is Nothing Then
                Application.EnableEvents = False
                Target.Offset(0, -3) = "Übergeben"
                Application.EnableEvents = True
            End If
        End If
    End If
    Set rngBereich = Nothing
End Sub

Wie schaffe ich es denn, mehrere Makros(?) einzufügen und wo genau muss ich das tun - oder war ich da schon richtig?

Ich habe dieses Mal die Datei mit angehangen, danke für eure Hilfe :)

Liebe Grüße.


Edit:

Ich hab's doch noch hinbekommen, indem ich rngBereich1 und rngBereich2 benutzt habe :)

Könnte man den Code vielleicht auch noch so erweitern, dass, wenn "Auftragnehmer" wieder <>"" ist, aber "Artikelbezeichnung" noch Text enthält, der Status auf "Erstellt" zurückwechselt - und wenn beide Zellen (Artikelbezeichnung und Auftragnehmer) wieder "geleert" werden, dass der Status auf "Frei" zurückwechselt? Wäre natürlich ziemlich cool, aber ich bin schon super zufrieden, so wie es jetzt ist. :)

Und wie viele Abfragen sind eigentlich gut? Die Rechner, auf denen die Tabelle verwendet wird, sind bestimmt schon 10 Jahre alt und pro Monat/Tabelle würden ungefähr 400 bis 500 Einträge erfolgen.

Gute Nacht.

 

Hi Nina,

der Code müsste dann so aussehen:

Code:

Sub Worksheet_Change(ByVal Target As Range)
    Dim rngBereich As Range
    Set rngBereich = Columns(2).SpecialCells(xlCellTypeAllValidation)
    If Target.Column = 4 Then
        If Target.Count = 1 Then
            If Not Intersect(Target.Offset(0, -2), rngBereich) Is Nothing Then
                Application.EnableEvents = False
                If Target <> "" Then
                    Target.Offset(0, -2) = "Erstellt"
                Else
                    Target.Offset(0, -2) = "Frei"
                    Target.Offset(0, 1).ClearContents
                End If
                Application.EnableEvents = True
            End If
        End If
    ElseIf Target.Column = 5 Then
        If Target.Count = 1 Then
            If Not Intersect(Target.Offset(0, -3), rngBereich) Is Nothing Then
                Application.EnableEvents = False
                If Target <> "" Then
                    If Target.Offset(0, -1) <> "" Then
                        Target.Offset(0, -3) = "Übergeben"
                    Else
                        MsgBox "Bitte erst Art.-Bezeichnung eintragen"
                        Target.ClearContents
                    End If
                Else
                    If Target.Offset(0, -1) <> "" Then
                        Target.Offset(0, -3) = "Erstellt"
                    Else
                        Target.Offset(0, -3) = "Frei"
                    End If
                End If
                Application.EnableEvents = True
            End If
        End If
    End If
    Set rngBereich = Nothing
End Sub

Der Code beeinträchtigt die Performance deiner Mappe in keinerlei Hinsicht, auch wenn noch mehr Abfragen hinzukämen, da er ja immer nur für jeweils 1 Zelle ausgeführt wird und keine langwierigen Schleifen o.ä. abgearbeitet werden müssen.


Eine generelle Sache ist mir jedoch bei deiner bedingten Formatierung aufgefallen:

1. die Formatierung für "Endkontrolle" und "Erstellt" ist identisch - falls das tatsächlich so sein soll, dann kannst du beide Bedingungen zu einer gemeinsamen zusammenfassen
2. der Bereich, auf die die bedingte Formatierung angewendet wird, ist bei dir total zerstückelt =$C$12:$C$46;$A$4:$A$27;$C$4:$J$27;$A$5:$J$10 - sicher ist das dadurch entstanden, dass du Zellen mal kopiert und in andere Bereiche eingefügt hast. Durch die Zerstückelung wird jedoch der Speicherbedarf deiner Mappe unnötig aufgebläht - ändere dies bei allen 4 Bedingungen einfach auf den Bereich, auf den sie insgesamte angewendet werden soll, also z.B. $A$4:$J$500
3. je mehr bedingte Formatierungen in der Mappe vorhanden sind, desto größer ist der Speicherbedarf. Ich weiß nun nicht, wie viele Tabellenblätter es letztendlich werden sollen, aber möglicherweise könnte das irgendwann mal zum Problem werden, falls es für jeden Monat ein eigenes sein sollte. Vielleicht solltest du dann besser auf die bedingte Formatierung komplett verzichten und stattdessen die Zellen färben, wenn in die Spalte 4 bzw. 5 etwas eingetragen bzw. gelöscht wird


Bis später,
Karin

 

Hey,

das mit dem Durcheinander in den Bedingten Formatierungen war mir gar nicht aufgefallen.
Habe ich dann jetzt "aufgeräumt" und schaut auch gleich viel besser aus. :)

Der Code funktioniert auch einwandfrei. :)

Darüber, ob die Formatierungen für "Erstellt" und "Endkontrolle" identisch bleiben sollen, bin ich noch unschlüssig, falls ja, werde ich es dann aber noch zusammenfassen. Mit =ODER($B4="Erstellt";$B4="Endkontrolle") richtig?

Es kommen in dieser Datei keine weiteren Tabellenblätter hinzu, sondern pro Monat wird eine eigene Datei verwendet (z.B. WA_Prüfliste_1215, WA_Prüfliste_0116,etc.).

Meintest du, dass man die gesamte Formatierung in den Codeabschnitt verlegen sollte?

Ich habe es jetzt geschafft, dass wenn Status "Frei" gewählt wird, die gesamte Zeile auf die Voreinstellung zurückgesetzt wird:

Code:

    If Target.Column = 2 Then
        If Cells(Target.Row, Target.Column) = "Frei" Then
            Target.Offset(0, 2).ClearContents
            Target.Offset(0, 3).ClearContents
            Target.Offset(0, 4) = "Abteilung"
            Target.Offset(0, 5) = "Nicht behoben"
            Target.Offset(0, 6).ClearContents
            Target.Offset(0, 7).ClearContents
            Target.Offset(0, 8) = "Standort"
        End If
    End If

Ist das in Ordnung so? Funktionieren tut es zu meiner Überraschung jedenfalls schon einmal :D
Und könnte man vielleicht noch eine Abfrage ("Auswahl "Frei" entfernt alle Einträge für ausgewählte Auftragsnummer" - "OK" - "Abbrechen") ausführen lassen?

Ich habe jetzt noch einmal die aktuelle Datei mit angehangen.

Großes Dankeschön, liebe Grüße und gute Nacht. :)

 

Hi,

deinen Code kann für das Leeren der Zellen man noch etwas zusammenfassen. Du solltest auch noch mittels Application.EnableEvents die Reaktion auf die Eingabe ab- und wieder einschalten, damit der Code nicht mehrfach durchlaufen wird.

Das Einbinden einer Löschabfrage ist etwas komplizierter, weil bei Beantwortung mittels "Nein" der vorherige Eintrag wieder aktiviert werden muss - dazu benötigst du dann noch das SelectionChange-Ereignis, mit dem du bei Klick in die Zelle den dort vorhandenen Inhalt auf eine prozedurübergreifende Variable schreiben musst, sodass du ihn dann wieder eintragen kannst.

Code:

Option Explicit
Dim rngBereich As Range
Dim varInhalt As Variant

Sub Worksheet_Change(ByVal Target As Range)
    Dim varAbfrage
    Set rngBereich = Columns(2).SpecialCells(xlCellTypeAllValidation)
    If Target.Column = 4 Then 'WENN Zelle in Zeile istGleich "Art.-Bezeichnung" DANN
        If Target.Count = 1 Then
            If Not Intersect(Target.Offset(0, -2), rngBereich) Is Nothing Then 'WENN
                Application.EnableEvents = False
                If Target <> "" Then
                    Target.Offset(0, -2) = "Erstellt"
                Else
                    Target.Offset(0, -2) = "Frei"
                    Target.Offset(0, 1).ClearContents
                End If
                Application.EnableEvents = True
            End If
        End If
    ElseIf Target.Column = 5 Then
        If Target.Count = 1 Then
            If Not Intersect(Target.Offset(0, -3), rngBereich) Is Nothing Then
                Application.EnableEvents = False
                If Target <> "" Then
                    If Target.Offset(0, -1) <> "" Then
                        Target.Offset(0, -3) = "Übergeben"
                    Else
                        MsgBox "Bitte erst Art.-Bezeichnung eintragen"
                        Target.ClearContents
                    End If
                Else
                    If Target.Offset(0, -1) <> "" Then
                        Target.Offset(0, -3) = "Erstellt"
                    Else
                        Target.Offset(0, -3) = "Frei"
                    End If
                End If
                Application.EnableEvents = True
            End If
        End If
'WENN Auftragsstatus "Frei" DANN gesamte Zeile auf Ausgangsstellung setzen
    ElseIf Not Intersect(Target, rngBereich) Is Nothing Then
        If Target = "Frei" Then
            varAbfrage = MsgBox("Auswahl 'Frei' entfernt alle Einträge für ausgewählte Auftragsnummer", _
                vbYesNo + vbExclamation, "Löschhinweis")
            Application.EnableEvents = False
            If varAbfrage <> 7 Then
                Union(Target.Offset(0, 2), Target.Offset(0, 3), Target.Offset(0, 6), _
                    Target.Offset(0, 7)).ClearContents
                Target.Offset(0, 4) = "Abteilung"
                Target.Offset(0, 5) = "Nicht behoben"
                Target.Offset(0, 8) = "Standort"
            Else
                Target = varInhalt
            End If
            Application.EnableEvents = True
        End If
    End If
End Sub

' Zellinhalt in Spalte B merken. Erforderlich falls bei Löschabfrage Nein gewählt wird
Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    Set rngBereich = Columns(2).SpecialCells(xlCellTypeAllValidation)
    If Not Intersect(Target, rngBereich) Is Nothing Then
        If Target.Count = 1 Then varInhalt = Target
    End If
End Sub

Option Explicit sollte man generell in jedem Code-Modul verwenden, denn es aktiviert eine Prüfung, ob Variablen deklariert sind. Damit wird verhindert, dass Variablen bei ihrer Verwendung falsch geschrieben und dadurch falsche Ergebnisse erzielt werden. Man aktiviert diese Funktionalität im VBA-Editor unter Extras -> Optionen -> Editor: Variablendeklaration erforderlich




Bis später,
Karin

 

Hey,

das ist wirklich toll geworden und funktioniert super! Auf dem Rechner, wo es genutzt werden soll, hat es heute erst nicht geklappt, weil ich vbYesNo gegen vbOkCancel getauscht habe und nicht wusste, dass der Rückgabewert von 7 auf 2 geändert werden muss :)

Das mit den Variablen hatte ich gestern auch schon einmal versucht, hab es aber nicht hinbekommen.

Was mir jetzt noch aufgefallen ist, ist, dass sobald ich die Tabelle erweitern, mehr Zeilen hinzufügen möchte, es einen "Laufzeitfehler '13' Typen unverträglich" gibt. Wenn ich auf Debuggen klicke, markiert er "If Target = "Frei" Then". Kann man das noch unterbinden oder muss man damit leben, z.B. indem man von vorne rein 500 Zeilen erstellt?


Liebe Grüße.

 

Hi,

ändere den letzten Teil des Codes wie folgt:

Code:

'WENN Auftragsstatus "Frei" DANN gesamte Zeile auf Ausgangsstellung setzen
    ElseIf Target.Column = 2 Then
        If Not Intersect(Target, rngBereich) Is Nothing Then
            If Target = "Frei" Then
                varAbfrage = MsgBox("Auswahl 'Frei' entfernt alle Einträge für ausgewählte Auftragsnummer", _
                    vbYesNo + vbExclamation, "Löschhinweis")
                Application.EnableEvents = False
                If varAbfrage <> 7 Then
                    Union(Target.Offset(0, 2), Target.Offset(0, 3), Target.Offset(0, 6), _
                        Target.Offset(0, 7)).ClearContents
                    Target.Offset(0, 4) = "Abteilung"
                    Target.Offset(0, 5) = "Nicht behoben"
                    Target.Offset(0, 8) = "Standort"
                Else
                    Target = varInhalt
                End If
                Application.EnableEvents = True
            End If
        End If
    End If

Bis später,
Karin

 

Das hat's gelöst :)

Mehr fällt mir jetzt gerade eigentlich erstmal gar nicht ein, das ist eine tolle Datei geworden :)

Mal schauen, wie sie sich in der Praxis macht.

Ich danke dir vielmals für deine Zeit und die super Hilfe!

Liebe Grüße.

 

Hallo und frohes Neues Jahr :)

Ich bin's nochmal, wegen der selben Tabelle.

Könntest du dir vielleicht bei Gelegenheit noch einmal den Makrobereich in meiner Datei anschauen und gucken, ob man den Code besser schreiben könnte oder ob es so geht? Ich habe die Tabelle noch um eine Spalte ("Warengruppe") erweitert und wollte es dort jetzt ebenfalls mit dem Hinweisfenster und der automatischen Statusänderung einbinden.

Funktioniert auch irgendwie, allerdings, wenn ich WarengruppenNr., Artikelbezeichnung und Auftragnehmer angegeben habe, dann zuerst die WarengruppenNr., dann den Auftragnehmer und als letztes die Artikelbezeichnung lösche, dann bleibt der Status auf "Erstellt", wobei ich ihn dann natürlich gerne auf "Frei" hätte.

Ansonsten funktioniert alles glaube ich, wie ich es haben möchte.
Dass der Status nach Eingabe der WarengruppenNr. noch nicht auf "Erstellt" wechselt, ist auch so gewollt.

Ich habe die aktuelle Datei mit angehangen.


Danke und liebe Grüße. :)

 

Hi Nina,

also wenn ich das richtig verstanden habe, dann müsstest du diesen Code ergänzen:

Code:

    ElseIf Target.Column = 4 Then 'Column 4 = Spalte D ("WG")
        If Not Intersect(Target.Offset(0, -1), rngBereich) Is Nothing Then
            If Target = "" Then
                varAbfrage = MsgBox("Löschen entfernt alle Einträge für ausgewählte Auftragsnummer", _
                    vbOKCancel + vbExclamation, "Löschhinweis")
                Application.EnableEvents = False
                If varAbfrage <> 2 Then 'WENN Löschabfrage mit "OK" beantwortet wird, DANN
                    Union(Target.Offset(0, 1), Target.Offset(0, 2), Target.Offset(0, 5), _
                        Target.Offset(0, 6)).ClearContents 'Zellen "Art.-Bezeichnung","Auftragnehmer","Anmerkung" und "Barcode(s) leeren
                    Target.Offset(0, -2) = "Datum" 'Zelle "Datum" auf "Datum" setzen
                    Target.Offset(0, -1) = "Frei"
                    Target.Offset(0, 3) = "Abteilung" 'Zelle "Abteilung" auf "Abteilung" setzen
                    Target.Offset(0, 4) = "Nicht behoben" 'Zelle "Mängel" auf "Nicht behoben" setzen
                    Target.Offset(0, 7) = "Standort" 'Zelle "Standort" auf "Standort" setzen
                Else
                    Target = varInhalt
                End If
                Application.EnableEvents = True
            End If
        End If

Bis später,
Karin

 

Hallo Karin,

vielen Dank für deine schnelle Antwort. :)

Das war es allerdings nicht, was ich gemeint hatte, sondern, wenn man die WarengruppenNr. und dann die Artikelbezeichnung eintippt und anschließend zuerst die WarengruppenNr. löscht, danach die Artikelbezeichnung, dann bleibt der Status auf "Erstellt", sollte aber auf "Frei" springen.

Also genau so, wie wenn man zuerst die Artikelbezeichnung löscht und anschließend die WarengruppenNr.


P.S.: Ich habe die bedingten Formatierungen jetzt auch (um die Hälfte) auf 5 Stück reduzieren können, mit der selben Wirkung :)
Z.B. "Erstellt" und "Endkontrolle" zusammengefasst, wie du gesagt hattest.

Liebe Grüße.

 

Hi Nina,

ich kann das nicht nachvollziehen - wenn in Spalte D der Zellinhalt gelöscht wird, dann wird die gesamte Zeile in den Urzustand zurückgesetzt.

Bis später,
Karin

 

Hey :)

entschuldige bitte das Missverständnis, das war nicht meine Absicht, allerdings möchte ich keine Löschabfrage in der "WG"-Spalte.

Wenn du in der Datei, die ich angehangen habe eine Warengruppennummer vergibst, danach die Art.-Bezeichnung einträgst, dann erst die Warengruppennummer löscht und anschließend die Art.-Bezeichnung, dann bleibt der Status auf "Erstellt", soll aber auf "Frei" wechseln, weil dann ja weder WG, noch Art.-Bezeichnung oder Arbeitnehmer eingetragen sind. (Umgekehrt geht es ja - also wenn du zuerst die Art.-Bezeichnung löscht und die Warengruppe noch vermerkt ist, wechselt er auf "Frei" - wie gewünscht.)

Sorry nochmal und lieben Gruß. :)