Office: (Office 2016) Wenn Zellenfarbe ungleich XY, dann entfärben

Hallo,
da man mir hier bei meinem letzten Problem so super geholfen hat, versuche ich noch mal mein Glück :-)

In einer Tabelle, die ich nicht selbst erstellt habe, werden Textinhalte über ein Dropdown ausgewählt. Über "Bedingte Formatierung" werden je nach Textinhalt die Hintergrundfarbe und auch die Schriftfarbe in der jeweiligen Zelle geändert.

Ich möchte nun die Tabelle dahingehend bearbeiten, dass nur Zellen mit der Hintergrundfarbe 33 (blau) und der Schriftfarbe 1 (schwarz) unverändert bleiben.
Alle Zellen mit anderen Farben (oder ohne Farbe) sollen die Hintergrundfarbe 2 (weiß) und die Schriftfarbe 1 (schwarz) bekommen.

Es ist mir dabei egal, ob die bedingten Formatierungen der anderen Zellen (oder auch aller Zellen) entfernt oder überschrieben werden, hauptsache, die blauen Zellen (Farbe 33) mit der schwarzen Schrift (Farbe 1) behalten ihre Farbe und die anderen Zellen sind weiß und haben eine schwarze Schrift.

Da ich auf die Gestaltung der Dropdowns keinen Einfluss habe und sich die Textinhalte auch ändern können, ist für mich nur die Farbcodierung wichtig. Ich habe anhand von Youtube-Videos schon selbst mit der bedingten Formatierung experimentiert, aber es scheint, als sei ich immer auf die Inhalte der Zellen angewiesen und könne nicht mit der Farbe arbeiten.

Liebe Grüße

PS: Ich kann die fragliche Tabelle leider nicht hochladen. Wenn dennoch eine erforderlich ist, müsste ich versuchen, etwas ähnliches nachzubasteln. Ich hoffe aber, die Problemstellung wird anhand meiner Beschreibung.deutliche.

 

Hi,

ich nehme an, die blaue Farbe wird auch durch eine bedingte Formatierung realisiert? Dann solltest du den gesamten Bereich markieren und alle nicht gewünschten bedingten Formatierungen löschen: Bedingte Formatierung -> Regeln bearbeiten... -> "falsche" Regel markieren -> Löschen. Und das für jede weitere "falsche" Regel wiederholen.

Wenn du etwas anderes meinst, dann solltest du auf jeden Fall eine Beispielmappe bereitstellen.

---

 

Hi,
das ist zwar eine herrlich pragmatische Idee :-) aber es handelt sich um 61 Regeln und man kann sie nicht blockweise markieren. Ich müsste also alle paar Tage jede Regel einzeln löschen.

Ich habe mal eine Beispielmappe erstellt.
Wie gesagt, ich möchte irgend wie die Farben von Hintergrund und Schrift auslesen, nicht den Text. Der kann leider variieren.

 

Hi,

mit folgendem Code kann man die Formatierungen löschen, die nicht der eingetragenen Bedingung "blau-schwarz" entsprechen:

Code:

Sub Formartierung()
    Dim rngZelle As Range
    Dim intZaehler As Integer
    ' Schleife über jede Zelle des benutzten Bereichs
    For Each rngZelle In ActiveSheet.UsedRange
        ' laufende Zelle hat mindestens 1 bedingte Formatierung
        If rngZelle.FormatConditions.Count > 0 Then
            ' Schleife über alle Bedingungen
            For intZaehler = rngZelle.FormatConditions.Count To 1 Step -1
                ' Formel der Bedingung enthält nicht "blau-schwarz"
                If InStr(rngZelle.FormatConditions(intZaehler).Formula1, "blau-schwarz") = 0 Then
                    ' Bedingung löschen
                    rngZelle.FormatConditions(intZaehler).Delete
                End If
            Next intZaehler
        End If
    Next rngZelle
End Sub

Es wird nur die bedingte Formatierung belassen, die in ihrer Formel "blau-schwarz" enthält.

---

 

Danke für die Mühe !
Das Problem ist, dass ich dann immer die Namen der jeweiligen bedingten Formatierungen kennen muss. Und auch die ändern sich.
Es verhält sich so. Von einer zentralen Stelle wird eine riesige Excel-Tabelle erstellt, in der verschiedene Kurse für Hunderte von Gruppen eingetragen werden. Meine Abteilung ist zuständig für alle Kurse, die mit einer blauen Hintergrundfarbe und schwarzer Schrift angezeigt werden. Die Textbezeichnung in diesen Kursen kann ständig variiren und auch die Namen der bedingten Formatierungen. Das einzige was an dieser Tabelle für mich fix ist, ist die Farbe. Und durch eine Funktion würde ich gerne die Tabelle entfärben, damit nur noch die für mich relevante Farbe übrig bleibt.
Kann natürlich sein, dass Excel eine derartige Funktion gar nicht vorsieht. Dann bin ich wohl zweiter Sieger ;-)

 

Weshalb nicht gleich mit den kompletten Informationen rausrücken?

Code:

Sub Formartierung()
    Dim rngZelle As Range
    Dim blnLoeschen As Boolean
    Dim intZaehler As Integer
    ' Schleife über jede Zelle des benutzten Bereichs
    For Each rngZelle In ActiveSheet.UsedRange
        ' laufende Zelle hat mindestens 1 bedingte Formatierung
        If rngZelle.FormatConditions.Count > 0 Then
            ' Schleife über alle Bedingungen
            For intZaehler = rngZelle.FormatConditions.Count To 1 Step -1
                ' Hintergundfarbe der Bedingung ist hellblau 15773696
                If rngZelle.FormatConditions(intZaehler).Interior.Color = 15773696 Then
                    ' Font-Farbe ist nicht schwarz
                    If rngZelle.FormatConditions(intZaehler).Font.Color <> 0 Then
                        blnLoeschen = True
                    End If
                Else
                    blnLoeschen = True
                End If
                ' Bedingung löschen
                If blnLoeschen Then rngZelle.FormatConditions(intZaehler).Delete
                blnLoeschen = False
            Next intZaehler
        End If
    Next rngZelle
End Sub

Es werden alle Bedinungen gelöscht, die nicht Füllfarbe 15773696 und Schriftfarbe 0 entsprechen.

Übrigens: Zellfarbe und Hintergrundfarbe, die durch Bedingente Formatierung erzeugt wird, sind nicht dasselbe.

---

 

@Beverly : Du bist meine Heldin ! Das Makro hat zwar über eine Stunde (!) benötigt, durch die Tabelle zu laufen, aber am Ende war das Ergebnis genau das Gewünschte. Vielen Dank und eine schöne Woche :-)