Office: Werte aus Spalte in einer Zeile mit Komma zusammenfassen

kryox · 4. Mai 2015

Hallo zusammen,

ich habe in der Spalte i diverse Werte eingetragen (teilweise auch doppelt).

Beispiel:
i1 = Hans
i2 = Hans
i3 = Hugo
i4 = Günther
i5 = Günther
i6 = Hans
i7 = Detlef

nun würde ich die Werte gerne via Makro wie folgt ausgeben:

Hans, Hugo, Günther, Detlef

Die doppelten einträge quasi entfernen und alles mit einem Komma trennen.
nach dem letzten Wert fällt das Komma im Idealfall weg.

Ist das möglich?

Vielen Dank & grüße
kryox

:)

xlph · 5. Mai 2015

Hallo,

UDF-Lösung:

Code:

Public Function VerkettenXlph(Bereich As Range, Optional Unikate As Boolean, Optional Trennzeichen As String = ";") As String
Dim Item As Variant
Dim Daten As Variant
Dim Ergebnis As String

With Bereich
Set Bereich = Intersect(.Worksheet.UsedRange, .Cells)
End With

If Not IsArray(Bereich.Value) Then
If Not IsEmpty(Bereich.Value) Then _
Ergebnis = vbTab & Bereich.Value
Else
For Each Item In Bereich.Value
If Not IsEmpty(Item) Then
If Unikate Then
If InStr(Ergebnis & vbTab, vbTab & Item & vbTab) = 0 Then _
Ergebnis = Ergebnis & vbTab & Item
Else
Ergebnis = Ergebnis & vbTab & Item
End If
End If
Next
End If
VerkettenXlph = Replace(Mid$(Ergebnis, 2), vbTab, Trennzeichen)
End Function
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Bsp-Aufruf in Zelle:
=VerkettenXlph(E3:E9;WAHR;", ")

kryox · 5. Mai 2015

Hallo xlph,

vielen Dank für deine mühe erstmal *Smilie

wäre es noch möglich, das auf einen gefilterten bereich anzuwenden?
meine Liste hat ca. 400 zeilen, wenn ich mit =VerkettenXlph(I9:I400;WAHR;", ") die Werte aufrufe, bekomme ich die Werte von allen 400 zeilen angezeigt.

Vielen Dank & grüße

xlph · 5. Mai 2015

Code:

Public Function VerkettenXlph(Bereich As Range, Optional Unikate As Boolean, _
Optional NurSichtbareWerte As Boolean, _
Optional Trennzeichen As String = ";") As String
Dim Daten() As Variant
Dim Ergebnis As String
Dim I As Long
Dim Wert As Variant

With Bereich.Columns(1)
Set Bereich = Intersect(.Worksheet.UsedRange, .Cells)
End With

With Bereich
If NurSichtbareWerte Then

For I = 1 To .Rows.Count
If Not Bereich(I).EntireRow.Hidden Then
Wert = Bereich(I).Value
If Not IsEmpty(Wert) Then
If Unikate Then
If InStr(Ergebnis & vbTab, vbTab & Wert & vbTab) = 0 Then _
Ergebnis = Ergebnis & vbTab & Wert
Else
Ergebnis = Ergebnis & vbTab & Wert
End If
End If
End If
Next

Else

Daten() = .Value
For I = LBound(Daten) To UBound(Daten)
Wert = Daten(I, 1)
If Not IsEmpty(Wert) Then
If Unikate Then
If InStr(Ergebnis & vbTab, vbTab & Wert & vbTab) = 0 Then _
Ergebnis = Ergebnis & vbTab & Wert
Else
Ergebnis = Ergebnis & vbTab & Wert
End If
End If
Next

End If

End With

If Len(Ergebnis) > 0 Then VerkettenXlph = Replace(Mid$(Ergebnis, 2), vbTab, Trennzeichen)
End Function
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Bsp-Aufruf in Zelle:
=VerkettenXlph(I9:I400;WAHR;WAHR;", ")

HS(V) · 6. Mai 2015

Oder:
Code:

Function SortVerketten(Myrange As Range) As String
Dim cl As Range
With CreateObject("System.Collections.ArrayList")
For Each cl In Myrange
If Not cl = "" And Not cl.EntireRow.Hidden And Not .contains(cl.Value) Then .Add cl.Value
Next
.Sort
SortVerketten = Join(.toarray, ", ")
End With
End Function
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Füge irgendwo die Teilergebnis Formel in eine Zelle.
Wenn Du jetzt den Filter benutzt wird die Funktion "Sortlist" aktualisiert.

PHP:

=TEILERGEBNIS(3;I1:I14)

Office: Werte aus Spalte in einer Zeile mit Komma zusammenfassen

Werte aus Spalte in einer Zeile mit Komma zusammenfassen

Werte aus Spalte in einer Zeile mit Komma zusammenfassen

Werte aus Spalte in einer Zeile mit Komma zusammenfassen

Werte aus Spalte in einer Zeile mit Komma zusammenfassen - Similar Threads - Werte Spalte Zeile

Zeilen Nummern gleicher Werte einer Spalte ausgebenn

Wert aus Zeile in Spalte suchen und bei Übereinstimmung Text aus andere Zeile anzeigen

Letzter Wert in Zeile - abhängig von Inhalt einer Spalte

Wenn gleiche Werte in einer Spalte, dann Inhalte aus Zeile in eine neue Spalte schreiben

Spalte mit nur eindeutigen Werten, aber ohne leere Zeilen

Werte aus Spalte(n) in einer Zeile, abhänging der Spaltenüberschrift, ggf. mit Komma zusammenfassen

Wechselnd nach x Zeilen Werte aus zwei Spalten nehmen