Office: Werte auslesen, konvertieren und berechnen

Hallo, ich habe ein etwas komplexeres Problem (zumindest für mich).

Ich habe Mitarbeiter die an bestimmten Tagen arbeiten. Diese Tage werden in einer Excel-Tabelle mit einem großen A gekennzeichnet. An jedem dieser Tage machen sie eine Überstunde. An anderen Tagen können sie diese abfeiern. Diese Tage werden mit ÜS gekennzeichnet. Ich habe am Monatsende eine Liste wieviel Plus/Minus die Mitarbeiter haben. Da ich diese Liste aber immer nur Mitte des nächsten Monates bekomme habe ich immer einen schlechten Überblick und alles per Hand ausrechnen dauert ab einer best Mitarbeiterzahl echt ewig.

Was ich nun brauche ist eine Formel die mir aus einer Excel-Zeile ausliest wieviele A drinstehen (Wert 1 pro A), diesen mit allen ÜS verrechnen (Wert -7 pro ÜS) und das als Wert ausgibt. Diese Werte kann ich dann problemlos von meiner vorhandenen "Zeitkontenliste" abziehen bzw. dazurechnen.

Geht so etwas?

 

Hallo!

=ZÄHLENWENN(A1:Z1;"ÜS")
zählt alle "ÜS" im angegebenen Bereich.
Das muss dann nur noch mit minus 7 multipliziert werden, wenn ich dich richig verstehe.

 

Nicht ganz. Hab da glaub ich was mißverständlich geschrieben.

Es geht nicht um die Spalte A sondern um den Wert A

Also =ZÄHLENWENN(A1:Z1;"A") [für alle Werte in den Spalten A bis Z in Zeile 1] wenn ich das richtig umsetze. Jetzt müsste die Formel aber noch erweitert werden und alle ÜS gezählt werden. Dabei müsste ÜS aber den Wert -7 zugewiesen bekommen.

Bsp.: Mitarbeiter hat im Monat 20 Tage gearbeitet und 3 Tage Überstunden abgefeiert:
20 x A = 20
3 x ÜS = -21
Ergebnis -1

Danke für die schnelle Hilfe

 

Hallo!

Ich hatte gehofft, den letzten Schritt schaffst du selbst :mrgreen: :

=ZÄHLENWENN(A1:Z1;"A")-7*ZÄHLENWENN(A1:Z1;"ÜS")

 

Ah, danke. War etwas verwirrt. Kommt davon wenn man auf Arbeit 5 Sachen gleichzeitig machen muss/ will :shock:

 

So, klappt so ziemlich. Jetzt kommt die Erweiterung: Wie kann ich Excel den Unterschied zwischen Groß- und Kleinschreibung nahebringen?

Meine Formel sieht mittlerweile so aus:
=ZÄHLENWENN(E18:AH18;"A")+ZÄHLENWENN(E18:AH18;"(A")+ZÄHLENWENN(E18:AH18;"A)")+ZÄHLENWENN(E18:AH18;"(A)")-7*(ZÄHLENWENN(E18:AH18;"ÜS")+ZÄHLENWENN(E18:AH18;"üs"))

Der Unterschied zwischen ÜS und üs ist, daß üs geplanter Überstundenausgleich ist. So wie es jetzt läuft unterscheidet Excel aber nicht zwischen ÜS und üs sondern zählt es doppelt.

:?:

 

Hallo!

=ANZAHL(FINDEN("üs";E18:AH18))
und
=ANZAHL(FINDEN("ÜS";E18:AH18))

unterscheiden zwischen Groß- und Kleinschreibung.

Aber Achtung: Wenn du diese/n (Matrix-)Term/e in deiner Formel nutzt, dann musst du die Formeleingabe mit Strg+Shift+Enter abschließen!

 

Also dann

=ZÄHLENWENN(E18:AH18;"A")+ZÄHLENWENN(E18:AH18;"(A")+ZÄHLENWENN(E18:AH18;"A)")+ZÄHLENWENN(E18:AH18;"(A)")-(ANZAHL(FINDEN("üs";E18:AH18))+ANZAHL(FINDEN("ÜS";E18:AH18)))

Werds morgen mal ausprobieren. Feierabend winkt. Danke schonmal im Vorraus.

 

Hallo!

Irgenwo fehlt da noch die Multiplikation mit 7, aber das ist wahrscheinlich nur ein Tippfehler...

Es geht übrigens auch ohne Strg+Shift+Enter, wenn du eine etwas längere Variante nutzt:

=SUMMENPRODUKT(1*IDENTISCH(E18:AH18;"üs"))
macht das gleiche wie
=ANZAHL(FINDEN("üs";E18:AH18))

Ganz nach Gusto...

 

Merci. Funzt eigentlich schon ganz gut, nur:

=ZÄHLENWENN(E251:AH251;"A")+ZÄHLENWENN(E251:AH251;"(A")+ZÄHLENWENN(E251:AH251;"A)")+ZÄHLENWENN(E251:AH251;"(A)")-7*(ANZAHL(FINDEN("üs";E251:AH251))+ANZAHL(FINDEN("ÜS";E251:AH251))+ANZAHL(FINDEN("ÜS)";E251:AH251))+ANZAHL(FINDEN("(ÜS";E251:AH251))+ANZAHL(FINDEN("(ÜS)";E251:AH251)))

"(ÜS", "(ÜS)", "ÜS)" und "ÜS" ist eine weitere Ausdifferenzierung.

Ich habe einen Mitarbeiter der ein "A" hat, 2x "ÜS" und einmal "ÜS)". Laut Formel hat er jetzt -27, er müsste aber -20 haben? Mit den Klammern in der Formel passt nach meiner Zählung alles.

Warum Eigentlich STRG + Shift + Enter?

 

Hallo!

Dann verwende lieber die etwas längere Variante mit Summenprodukt und Identisch.
Damit müsste es funktionieren.

Erklärung: ANZAHL(FINDEN("ÜS"... zählt das Auftauchen von "ÜS". Dies ist natürlich sowohl in den Zellen mit "ÜS" als auch in den Zellen mit "ÜS)" der Fall. SUMMENPRODUKT(1*IDENTISCH... checkt den genauen Zellinhalt.

PS: Hier ist ein kleiner Einblick in die "Matrix"-Welt.