Office: Werte unbekannter Spaltenanzahl dynamisch verketten

Hallo,

kann ich mit einer Formel in Spalte A die einzelnen Werte der Spalte B bis Spalte ??? dynamisch verketten und eine # zwischen die Werte schreiben? Problem ist, die mit Werten gefüllte Spaltenanzahl je Zeile ist immer unterschiedlich:

[TABLE="class: grid, width: 500"]
<tbody>[TR]
[TD][/TD]
[TD]A
[/TD]
[TD]B
[/TD]
[TD]C
[/TD]
[TD]D
[/TD]
[TD]E
[/TD]
[TD]...
[/TD]
[TD]X
[/TD]
[TD]Y
[/TD]
[TD]Z
[/TD]
[/TR]
[TR]
[TD]1
[/TD]
[TD]EinWert
[/TD]
[TD]Wert1
[/TD]
[TD]Wert2
[/TD]
[TD]Wert3
[/TD]
[TD]Wert4
[/TD]
[TD]Wert...
[/TD]
[TD]Wert99
[/TD]
[TD]Wert999
[/TD]
[TD]Wert?
[/TD]
[/TR]
[TR]
[TD]2
[/TD]
[TD]1#2#3#4
[/TD]
[TD]1
[/TD]
[TD]2
[/TD]
[TD]3
[/TD]
[TD]4
[/TD]
[TD][/TD]
[TD][/TD]
[TD][/TD]
[TD][/TD]
[/TR]
[TR]
[TD]3
[/TD]
[TD]2#3#4#5#6#7
[/TD]
[TD]2
[/TD]
[TD]3
[/TD]
[TD]4
[/TD]
[TD]5
[/TD]
[TD]6
[/TD]
[TD]7
[/TD]
[TD][/TD]
[TD][/TD]
[/TR]
[TR]
[TD]4
[/TD]
[TD]Hallo#Du
[/TD]
[TD]Hallo
[/TD]
[TD]Du
[/TD]
[TD][/TD]
[TD][/TD]
[TD][/TD]
[TD][/TD]
[TD][/TD]
[TD][/TD]
[/TR]
[TR]
[TD]5
[/TD]
[TD]92#ich#23#34
[/TD]
[TD][/TD]
[TD]92
[/TD]
[TD][/TD]
[TD]ich
[/TD]
[TD][/TD]
[TD]23
[/TD]
[TD][/TD]
[TD]34
[/TD]
[/TR]
[TR]
[TD]6
[/TD]
[TD]2
[/TD]
[TD]2
[/TD]
[TD][/TD]
[TD][/TD]
[TD][/TD]
[TD][/TD]
[TD][/TD]
[TD][/TD]
[TD][/TD]
[/TR]
[TR]
[TD]7
[/TD]
[TD]33
[/TD]
[TD][/TD]
[TD][/TD]
[TD]33
[/TD]
[TD][/TD]
[TD][/TD]
[TD][/TD]
[TD][/TD]
[TD][/TD]
[/TR]
</tbody>[/TABLE]

Danke für Hilfe,
LG, Mat

 

Hallo,

ich habe Dir folgende VBA-Funktion programmiert:

Code:

Function VerkettenRaute(Optional Bereich As Range = Nothing) As String
  Dim DieseZelle As Range, TestBereich As Range, Zelle As Range
  Dim S As String
  Application.Volatile True
  '
  'Ermittle die Zelle, in der diese Funktion steht:
  Set DieseZelle = Application.ThisCell
  
  If Bereich Is Nothing Then
    'Wenn kein "Bereich" festgelegt wurde, nimm die 100 Zellen,
    'die rechts von der Formelzelle liegen, als Testbereich und überprüfe
    'ihren Inhalt
    Set TestBereich = DieseZelle.Offset(0, 1).Resize(1, 100)
  Else
    'Wurde jedoch ein "Bereich" festgelegt, bringe diesen Bereich mit der
    'Zeile, in der die Formel liegt, zum Schnitt und überprüfe den Inhalt
    'dieses Testbereiches:
    Set TestBereich = Application.Intersect(Bereich, DieseZelle.EntireRow)
  End If
  '
  'Konstruiere den Rautenstring mit den Zellen des Testbereiches
  S$ = ""
  For Each Zelle In TestBereich.Cells
    If Not IsEmpty(Zelle) Then
      S$ = S$ & "#" & Zelle.Value
    End If
  Next Zelle
  VerkettenRaute = Mid$(S$, 2)
  '
End Function

Diese solltest Du in ein allgemeines Codemodul im VBA-Editor speichern.

Die Funktion "VerkettenRaute([Bereich])" kann in zweifacher Weise angewandt werden:
1) ohne Parameter:
=VerkettenRaute()
In dieser Gestalt verwendet die Funktion die nächsten 100 Zellen, die rechts von der Zelle liegen, in der die Formel steht, um aus dem Inhalt dieser 100 Zellen den rautegetrennten String zu erzeugen.
2) mit Bereichsparameter, zB.:
=VerkettenRaute(D:G)
In dieser Gestalt wird der angegebene Bereich (im Beispiel die Spalten D bis G) zum Schnitt gebracht mit der Zeile, in der die Formel steht, und dieser Zellbereich wird dann zum Ermitteln des rautegetrennten Strings verwendet.

 

Du bist genial! Diese Formel macht mich sehr glücklich, vielen herzlichen Dank!!! Wahnsinn, was "Ex(e)l" alles kann ;-)