Office: Werten in B eine ID in A zufügen

Hallo liebe excel Gemeinde,

ich bin neu hier. nachdem ich das Forum durchsucht habe, konnte ich trotzdem keine Lösung für meine Frage finden.

Ich habe in Spalte B einer Adressdatei Firmennamen stehen.
Jetzt möchte ich jeder Firma eine Nummer zuweisen. Da es Kontakte sind, sind manche Firmennamen doppelt und sollen dementsprechend die gleiche ID/Nummer bekommen.
Hat da jemand die Formel für?

Vielen Dank,
Nils

 

Hallo,

sowas?

	A	B	C	D	E	F	G	H
1	ID	Firmenname					F1	1
2	1	F1					F2	2
3	2	F2					F3	3
4	3	F3					F4	4
5	4	F4					F5	5
6	1	F1
7	2	F2

Zelle	Formel
A2	=SVERWEIS(B2;$G$1:$H$5;2;0)

In Spalte G und H habe ich eine Matrix aufgebaut die der Firma eine entsprechende ID zuweist und auf diese Matrix kannst du dann mit dem Sverweis zugreifen.

 

Hallo Peter,

vielen Dank für die schnelle Antwort, das ist sehr nett.

Allerdings habe ich etwa 6000 Firmennamen, natürlich kann ich erst die doppelten raussuchen, löschen und die dann in G kopieren und in H fortlaufend Nummerieren, zur Not und das wäre schonmal besser als von Hand, besser wäre aber, wenn die direkt durch nummeriert werden, damit ich mir diese Schritte sparen kann.
Gibt es da noch eine andere Möglichkeit?

Gruss,
Nils

 

Hallo!

Für eine fortlaufende Nummerierung könnte auch sowas gehen:

	A	B
1	ID	Name
2	1	aaa
3	2	bbb
4	3	ccc
5	2	bbb
6	4	ddd
7	1	aaa
8	5	eee
9	1	aaa

Zelle	Formel
A2	=WENN(ZÄHLENWENN(B$1:B1;B2);INDEX(A:A;VERGLEICH(B2;B:B;));MAX(A$1:A1)+1)
A3	=WENN(ZÄHLENWENN(B$1:B2;B3);INDEX(A:A;VERGLEICH(B3;B:B;));MAX(A$1:A2)+1)
A4	=WENN(ZÄHLENWENN(B$1:B3;B4);INDEX(A:A;VERGLEICH(B4;B:B;));MAX(A$1:A3)+1)
A5	=WENN(ZÄHLENWENN(B$1:B4;B5);INDEX(A:A;VERGLEICH(B5;B:B;));MAX(A$1:A4)+1)
A6	=WENN(ZÄHLENWENN(B$1:B5;B6);INDEX(A:A;VERGLEICH(B6;B:B;));MAX(A$1:A5)+1)
A7	=WENN(ZÄHLENWENN(B$1:B6;B7);INDEX(A:A;VERGLEICH(B7;B:B;));MAX(A$1:A6)+1)
A8	=WENN(ZÄHLENWENN(B$1:B7;B8);INDEX(A:A;VERGLEICH(B8;B:B;));MAX(A$1:A7)+1)
A9	=WENN(ZÄHLENWENN(B$1:B8;B9);INDEX(A:A;VERGLEICH(B9;B:B;));MAX(A$1:A8)+1)