Office: wieder einmal ein Verknüpfung

Hallo liebe Excel-Freunde,

ich zerbreche mir gerade den Kopf, wie ich aus einer Tabelle die Daten auslesen kann. Um die Beschreibung nicht auf das Äußerste auszureizen, habe ich die Daten in eine Mappe gepackt.

Im möchte nun Folgendes wissen, wenn ich in der Zelle K3 einen Wert habe und in der Zelle K4 den Selbstbehalt ausgewählt habe, dann muss in der Zeile K5 der passende Sparbetrag herauskommen.
Der Betrag K3 wird jedoch zuerst in eine der drei passenden Kategorien eingeteilt werden,
bis 20000, zwischen 20000 und 100T und ab 100T.

Index, Vergleich, Sverweis - habe vieles probiert doch nicht zum Erfolg gekommen. Habe schon schwierigere gelöst, doch jetzt stehe ich da und kann nicht anders ;)

Mit dankbaren Grüßen

Alexej

 

Ich hab es dann doch fertig gekriegt. Herzlichen Dank für das Zuhören:

=WENN(K3<20000;INDEX(A3:F3;VERGLEICH(K4;A2:F2;0));"nicht möglich")

für die erste Stufe und den Rest mache ich bestimmt selbst.

Danke vielmals und bis zum nächsten mal

Liebe Grüße

Ag.man

 

Ach, da fällt mir ja gleich noch was ein. Wie kann ich eigentlich in einer Formel z.B.
=Wenn(A2<1000>8000) darstellen,

Ist es überhaupt möglich, dass ich zwei Bedingungen stellen kann oder muss den mühsamen Weg über zwei Wenn-Bedingungen gehen.
Wenn(A2<1000>8000)

Danke für die Hilfe

Ag.man

 

Hallo Alex -

Immer wenn Du in Deiner Anfrage die Zeichen < und > verwendest, solltest Du von dem Abschicken die folgende Option aktivieren:

• [x] HTML in diesem Beitrag deaktivieren

da die Forumssoftware sonst den Beitrag so zerpflückt, daß er unleserlich wird.

Mit Ungleichungs-Ketten à la x < y < z kann Excel meines Wissens nichts anfangen bzw. versteht sie falsch.

Um zum Beispiel festzustellen, ob eine bestimmte Zahl zum Intervall 11 ... 17 gehört, kannst Du so eine Formel nehmen:
=WENN(UND(A1>=11;A1<=17);"ja";"nein")
oder etwas kürzer:
=WENN((A1>=11)*(A1<=17);"ja";"nein")

 

Hallo Krino,

Deine wertvolle Tipps werde ich gewiss beherzigen.
Eine andere Frage:
Gibt es einen Ersatzbefehl für wennfehler aus der 2007-er Version für 2003-er???
Mit ISTFEHLER funktioniert es doch noch nicht so rrrrrrrrrichtig.

Mit besten Grüßen

Ag.man

 

Hallo!

Einen adäquaten Ersatz für WENNFEHLER gibt es vorher leider noch nicht.
Im Allgemeinen gilt

=WENNFEHLER(DeineFormel;"Fehler")
entspricht
=WENN(ISTFEHLER(DeineFormel);"Fehler";DeineFormel)

Da sich dadurch die ursprüngliche Formellänge aber in etwa verdoppelt, wird es oft recht unübersichtlich.
Meist (abhängig von der Formel) gibt es auch einen kürzeren Weg um Fehler abzufangen.

 

Hallo Schatzi,

das Problem ist dabei, dass ich genauso vorgegangen bin mit Istfehler, dabei kann ich leider diese Formel nicht aus der 2007-er in die 2003-er konvertieren, da soviele Schachtelungsebenen nicht verarbeitet werden können.

=WENN(ISTFEHLER(WENN(Tabelle1!B2<=20000;SVERWEIS(Tabelle1!B10;Tabelle3!$R$4:$V$6;
VERGLEICH(Tabelle1!B11;Tabelle3!$R$3:$Y$3;0);FALSCH);WENN((Tabelle1!B2<=100000)*(Tabelle1!B2>20000);
SVERWEIS(Tabelle1!B10;Tabelle3!$R$7:$W$9;VERGLEICH(Tabelle1!B11;Tabelle3!$R$3:$Y$3;0);FALSCH);
WENN((Tabelle1!B2<=500000)*(Tabelle1!B2>100000);SVERWEIS(Tabelle1!B10;Tabelle3!$R$10:$X$12;VERGLEICH(Tabelle1!B11;Tabelle3!$R$3:$Y$3;0);FALSCH);
WENN((Tabelle1!B2<=2000000)*(Tabelle1!B2>500000);SVERWEIS(Tabelle1!B10;Tabelle3!$R$13:$Y$15;VERGLEICH(Tabelle1!B11;Tabelle3!$R$3:$Y$3;0);FALSCH);
WENN(Tabelle1!B2>2000000;SVERWEIS(Tabelle1!B10;Tabelle3!$R$16:$Y$18;VERGLEICH(Tabelle1!B11;Tabelle3!$R$3:$Y$3;0);FALSCH)))))));"nicht möglich"; WENN(Tabelle1!B2<=20000;SVERWEIS(Tabelle1!B10;Tabelle3!$R$4:$V$6;VERGLEICH(Tabelle1!B11;Tabelle3!$R$3:$Y$3;0);FALSCH);
WENN((Tabelle1!B2<=100000)*(Tabelle1!B2>20000);SVERWEIS(Tabelle1!B10;Tabelle3!$R$7:$W$9;VERGLEICH(Tabelle1!B11;Tabelle3!$R$3:$Y$3;0);FALSCH);
WENN((Tabelle1!B2<=500000)*(Tabelle1!B2>100000);
SVERWEIS(Tabelle1!B10;Tabelle3!$R$10:$X$12;VERGLEICH(Tabelle1!B11;Tabelle3!$R$3:$Y$3;0);FALSCH);
WENN((Tabelle1!B2<=2000000)*(Tabelle1!B2>500000);
SVERWEIS(Tabelle1!B10;Tabelle3!$R$13:$Y$15;VERGLEICH(Tabelle1!B11;Tabelle3!$R$3:$Y$3;0);FALSCH);
WENN(Tabelle1!B2>2000000;SVERWEIS(Tabelle1!B10;Tabelle3!$R$16:$Y$18;
VERGLEICH(Tabelle1!B11;Tabelle3!$R$3:$Y$3;0);FALSCH)))))))

Wie kann ich hier eine Lösung finden?

Vielen Dank im Voraus

Ag.man

 

Na, das ist doch mal eine hübsche übersichtliche Formel...

Ohne Gewähr, da ich deine Tabelle nicht zum Testen habe, teste mal diese Formel:

=WENN(ISTFEHLER(SVERWEIS(Tabelle1!B10;BEREICH.VERSCHIEBEN(Tabelle3!$R$1:$Y$3;3*((Tabelle1!B2>0)+(Tabelle1!B2>20000)+(Tabelle1!B2>100000)+(Tabelle1!B2>500000)+(Tabelle1!B2>2000000)););VERGLEICH(Tabelle1!B11;Tabelle3!$R$3:$Y$3;);));"nicht möglich";SVERWEIS(Tabelle1!B10;BEREICH.VERSCHIEBEN(Tabelle3!$R$1:$Y$3;3*((Tabelle1!B2>0)+(Tabelle1!B2>20000)+(Tabelle1!B2>100000)+(Tabelle1!B2>500000)+(Tabelle1!B2>2000000)););VERGLEICH(Tabelle1!B11;Tabelle3!$R$3:$Y$3;);))

 

O lieber Herr,

danke, dass es Schatzi gibt. Du hast aber noch andere Hobbys neben Excel und VBA oder?

Herzlichen Dank es funktioniert, aber ich muss mich noch direkter mit der Formel auseinander setzten.

Man o man und ich dachte, dass ich mich mit Excel auskenne.
Auf zum Atom!

Ag.man