Office: (Office 365) Wochentag Differenz

Ich benötige für eine Zwischenkalkulation die Tage zwischen zwei Tagen. Dabei geht es nicht um ein Datum, sondern um die Tage von Montag bis Sonntag.

Beispiel in einer Tabelle steht in
A1 Montag; in B1 Sonntag dann soll in C1 das Ergebnis 7 sein
A2 Montag; in B2 Freitag dann soll in C2 das Ergebnis 5 sein
A3 Samstag; in B3 Sonntag dann soll in C3 das Ergebnis 2 sein
A4 Sonntag; in B4 Freitag dann soll in C4 das Ergebnis 6 sein

Die Tage in A und B wähle ich aus einer Liste (Dropdown aus)

Gibt es da eine Lösung z.B. über WOCHENTAGE oder sowas?

 

Hallo Robert,

wenn du für deine Auswahlliste nicht Text(?) verwendest, sondern richtige DATEN (Plural v. Datum) von Mo bis So, dann kannst du damit rechnen. (Excel ist doch ein Rechenknecht!) (s. Mappe)

Gruß Sigi

 

Vielen Dank, da habe ich wirklich auf dem Schlauch gestanden. So einfach kann es sein

 

Hallo Robert,

wenn Du Deine Wochentage zur Definition Deiner Dropdownzellen in einer Hilfsspalte hast (nachfolgend z.B. in H1:H7), dann mit folgender Formel, die Du nach unten kopierst und bei Bedarf noch mit WENNFEHLER() klammerst.

Arbeitsblatt mit dem Namen 'Tabelle2'
	A	B	C	D	E	F	G	H
1	von	bis	Tage					Wochentage
2	Montag	Sonntag	7					Montag
3	Montag	Freitag	5					Dienstag
4	Samstag	Sonntag	2					Mittwoch
5	Sonntag	Freitag	6					Donnerstag
6	Samstag	Freitag	7					Freitag
7								Samstag
8								Sonntag
9
10

Zelle	Formel
C2	=VERGLEICH(B2;$H:$H;0)-VERGLEICH(A2;$H:$H;0)+(VERGLEICH(B2;$H:$H;0)<VERGLEICH(A2;$H:$H;0))*7+1

Zelle	Gültigkeitstyp	Operator	Wert1	Wert2
A2	Liste		=$H$2:$H$8
B2	Liste		=$H$2:$H$8

Verwendete Systemkomponenten: [Windows (32-bit) NT 6.02] MS Excel 2010

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

 

Hi,

Sigi hat zwar recht, aber mit etwas aufwand bekommt man auch das Rechnen mit Texten hin...

Code:

=LET(a;A1;b;B1;x;{"So";"Mo";"Di";"Mi";"Do";"Fr";"Sa"};y;{1;2;3;4;5;6;7};aa;XVERWEIS(a;x;y;;1;1);bb;XVERWEIS(b;x;y;;1;1);bb-aa+(aa>bb)*7+1)

 

=LET(x;"MoDiMiDoFrSaSo";(SUCHEN(B1;TEIL(x&x;SUCHEN(A1;x&x);99))+1)/2)

wenn Mo statt Montag usw.

 

Hallo,

und dieser Formel ist es egal, ob "So" oder "Sonntag", ..., "Sa" oder "Samstag":
=LET(w;LAMBDA(t;(SUCHEN(LINKS(t;2);"MoDiMiDoFrSaSo")+1)/2);REST(w(B1)-w(A1);7)+1)