Office: (Office 2007) word dokument aus access füllen; Fehler 6028

ble · 7. Juli 2014

Halllo,

ich mochte das Dokument test aus access füllen
Code:

Private Sub Befehl8_Click()

Dim wordobj As Object, worddoc As Object
Dim VORLAGE As String

Set wordobj = CreateObject("Word.Application")
VORLAGE = aktVerz() & "\test.doc"

Set worddoc = wordobj.Documents.Add(Template:=VORLAGE)

worddoc.Bookmarks("verj").Range = Me!Text6 & ""
worddoc.Bookmarks("Text11").Range = Me!Text9 & ""
'worddoc.Bookmarks("Aktenz").Range = Me!Aktenz & ""

worddoc.Parent.ChangeFileOpenDirectory aktVerz

wordobj.Visible = True
Set worddoc = Nothing
Set wordobj = Nothing

On Error GoTo 0
Exit Sub
End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Ich erhalte die Fehlermeldung:
Laufzeitfehler 6028: Bereich kann nicht nicht gelöscht werden.
Der Debugger markiert gelb:
Code:

worddoc.Bookmarks("verj").Range = Me!Text6 & ""
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Vielen Dank für die Unterstützung.

:)

maikek · 9. Juli 2014

Moin,
vielleicht hilft dir dieser Link weiter:
http://word.mvps.org/faqs/macrosvba/...AtBookmark.htm
maike

haklesoft · 9. Juli 2014

ein paar Anmerkungen:

- Documents.Add öffnet in Word ein neues Dokument auf Basis der Vorlage. Dein Test.doc ist aber ein Dokument und keine Vorlage (*.dot). Dokumente öffnen mit Documents.Open

- aktVerz ist vermutlich eine Pfad-Variable. Du benutzt bei der Zuweisung aber aktVerz().

- wenn man Bookmarks anspricht ist es ratsam, die vorher mit Bookmarks.Exist("verj") zu checken.

- prüfen, ob Me!Text6 & "" einen gültigen String liefert

- warum On Error Goto 0, wenn gar kein On Error gesetzt ist? Auch Exit Sub ist hier entbehrlich.

- Ist das Document vielleicht schon einmal geöffnet und Du arbeitest auf einer schreibgeschützten Kopie?

Anne Berg · 9. Juli 2014

Hi,

versuche es mal hiermit: Code:

worddoc.Bookmarks("verj").Range.Text = Me!Text6 & ""
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Das gilt natürlich auch für alle anderen Zuweisungen.

ble · 9. Juli 2014

Vielen Dank für die Tipps.
Mit dem Code
Code:

Function aktVerz() As String
aktVerz = Application.CurrentProject.Path
End Function

Private Sub Text2_AfterUpdate()

If Not IsNull(Me!Text0) Then
Me.Text6 = DateAdd("d", [Text4], [Text0] - 1)
Me.Text9 = Me.Text6
End If

End Sub

Private Sub Befehl8_Click()

Dim wordobj As Object, worddoc As Object
Dim VORLAGE As String

Set wordobj = CreateObject("Word.Application")
VORLAGE = aktVerz() & "\azf.dotx"

Set worddoc = wordobj.Documents.Add(Template:=VORLAGE)

worddoc.Bookmarks("verj").Range.Text = Me!Text6 & ""

worddoc.Bookmarks("abc").Range.Text = Me!Text9 & ""

worddoc.Parent.ChangeFileOpenDirectory aktVerz

wordobj.Visible = True
Set worddoc = Nothing
Set wordobj = Nothing

End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

wird mir ein neues Dokument geöffnet.
Auch wird das Feld verj korrekt befüllt.
Ich schaffe es aber nicht, in das zweite Textformularfeld den Wert zu schreiben.
Ich erhalte die Fehlermeldung:
Laufzeitfehler 6028: Bereich kann nicht nicht gelöscht werden.
Der Debugger markiert
Code:

worddoc.Bookmarks("abc").Range.Text = Me!Text9 & ""
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

ble · 10. Juli 2014

a) Wenn ich über Einfügen -> Textmarke gehe, funktioniert der Code.

b) Gehe ich über Entwicklertools, Steuerelemente, Vorversionen Textformularfeld, dann kommt der aufgeführte Fehler.
*frown.gif*
Ich habe meine word-Vorlage von 2003 in 2007 konvertiert und dann ein Steuerelement eingefügt, das durchaus ähnlich aussah.

Vielen Dank für die Unterstützung.

Noch zwei Fragen:

wie kann ich eine Textmarke - siehe a) - sichtbar machen?

wie kann ich das erstellte Dokument (über die Vorlage) schützen, so dass nur ein Formular ausfüllbar ist?
Code:

ActiveDocument.Protect Type:=wdAllowOnlyFormFields
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

führt zu einer Fehlermeldung 424, Objekt erforderlich

haklesoft · 10. Juli 2014

Direkt in Word springst Du mit "Gehe zu..." an eine Textmarke. Die Auflistung zeigt Dir, welche es gibt. In VBA überprüfst Du eine Textmarke mit Bookmarks.Exists()

Wieso willst Du ActiveDocument benutzen, wenn Du doch in Deinem Code mit worddoc arbeitest.

ble · 10. Juli 2014

Hallo,

die Vorlage azf muss ich am Anfang ungeschützt lassen, damit ich zwei Felder aus access heraus füllen kann.
Es sind noch weitere Textformularfelder vorhanden, die ich händisch füllen will.
Wenn ich die Vorlage sperre, kann ich im Dokument, das auf Basis der Vorlage geöffnet wird bequem mit Hilfe der Tabtaste füllen.

ble · 10. Juli 2014

Folendes funktioniert:

Ins Accessformular

Code:

Function aktVerz() As String
aktVerz = Application.CurrentProject.Path
End Function

Private Sub Befehl8_Click()

Dim wordobj As Object, worddoc As Object
Dim VORLAGE As String

Set wordobj = CreateObject("Word.Application")
VORLAGE = aktVerz() & "\azf.docm"

Set worddoc = wordobj.Documents.Add(Template:=VORLAGE)

worddoc.Bookmarks("Feld1").Range.Text = Me!Text6 & ""

worddoc.Bookmarks("Feld2").Range.Text = Me!Text9 & ""

worddoc.Application.Run MacroName:="Schuetzen"

worddoc.Parent.ChangeFileOpenDirectory aktVerz

wordobj.Visible = True
Set worddoc = Nothing
Set wordobj = Nothing

End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Makro in die Vorlage azf.dotm
Code:

Sub Schuetzen()
ActiveDocument.Protect Type:=wdAllowOnlyFormFields, _
NoReset:=True, Password:=""
End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Schöner wäre es natürlich, wenn sich der code nur im Access-Formular befände.

Vielen Dank für die Tipps und Anregungen.

Bitte beachtet, dass ich die Namen der Textfelder geändert habe.
Das ist zwar unübersichtlich, aber ich bin froh, dass ich einen laufenden Code präsentieren kann und früchte mich davor, ihn anzupassen.

haklesoft · 10. Juli 2014

Mein Vorschlag für Deine Access-Routine mit Formularschutz Code:

Private Sub Befehl8_Click()
Dim wordobj As Object, worddoc As Object
Dim VORLAGE As String

Set wordobj = CreateObject("Word.Application")

'VORLAGE = aktVerz() & "\azf.docm" 'besser NICHT mit einem Dokument als Vorlage arbeiten!
VORLAGE = aktVerz & "\azf.dotx" 'wenn in der Vorlage keine Makros sind, oder alternativ
'VORLAGE = aktVerz & "\azf.dotm" 'wenn in der Vorlage Makros benötigt werden

Set worddoc = wordobj.Documents.Add(Template:=VORLAGE)

With worddoc
'ggf. Formularschutz deaktivieren
If .ProtectionType = 2 Then 'wdAllowOnlyFormFields
.Unprotect Password:=""
End If

If .Bookmarks.Exists("Feld1") = True Then .Bookmarks("Feld1").Range.Text = Me!Text6 & ""

If .Bookmarks.Exists("Feld2") = True Then .Bookmarks("Feld2").Range.Text = Me!Text9 & ""

'Formularschutz einschalten
If .ProtectionType = -1 Then 'wdNoProtection
.Protect Type:=2, NoReset:=True, Password:=""
End If

.Parent.ChangeFileOpenDirectory aktVerz
End With

wordobj.Visible = True

Set worddoc = Nothing
Set wordobj = Nothing

End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

In der Vorlage brauchst Du dann naürlich kein Schutz-Makro mehr und kannst die Vorlage ggf. als .dotx speichern.

ble · 10. Juli 2014

1a; passt, wackelt und hat Luft, um es in der Zimmerersprache zusagen;
Vielen Dank!

Office: (Office 2007) word dokument aus access füllen; Fehler 6028

word dokument aus access füllen; Fehler 6028

word dokument aus access füllen; Fehler 6028

word dokument aus access füllen; Fehler 6028

word dokument aus access füllen; Fehler 6028

word dokument aus access füllen; Fehler 6028 - Similar Threads - word dokument access

Word-Dokument über Access erstellen und bearbeiten

Word Dokument aus Access füllen

Mit Access mehrere Word-Dokumente nach bestimmten Zeichenfolgen durchsuchen

Exportieren von Access-Daten in ein Word-Dokument

Access Tabelle in Word-Dokument

Word Dokument aus Formular erstellen mit Tabelleneinträgen

Access Datenbank in Word Dokument