Office: (Office 2016) Word Dokument wird in Excel nicht als Serienbriefhauptdokument erkannt

Hallo liebe Community,
Ich versuche gerade aus Excel heraus per VBA einen Serienbrief zu generieren. Den Serienbrief in Word habe ich vorab mit dem Serienbrief Assistenten erstellt und gespeichert. Wenn ich die Word Datei öffne, werden auch sofort die Daten gezogen. Die Serienbriefgenerierung soll aber in Excel gestartet werden und am Ende soll eine PDF Datei erzeugt und gespeichert werden Dafür habe ich folgenden VBA Code in Excel verwendet:

Code:

Sub Test()

    Dim wordfilepath As String
    wordfilepath = "C:\Users\schub\Desktop\Neuer Ordner\Listen\Creator\Quittung1.docx"
  
    Dim wd As Object
    Dim wdocSource As Object
  
    On Error Resume Next
    Set wd = GetObject(, "Word.Application")
    If wd Is Nothing Then
        Set wd = CreateObject("Word.Application")
    End If
    On Error GoTo 0

    Set wdocSource = wd.Documents.Open(wordfilepath)
  
    ' Ausführen des Serienbriefes
    wdocSource.MailMerge.Execute
  
    ' Anpassen des pdffilepath mit einem zusätzlichen Kriterium aus einer bestimmten Excel-Zelle
    Dim zusatzkriterium As String
    zusatzkriterium = ThisWorkbook.Sheets("DatenQuittung").Range("E2").Value
  
    pdffilepath = "C:\Users\schub\Desktop\Quittung1_" & zusatzkriterium & ".pdf"
  
    ' Exportieren als PDF
    wdocSource.ExportAsFixedFormat pdffilepath, 17

    ' Schließen des Word-Dokuments
    wdocSource.Close SaveChanges:=False
    Set wdocSource = Nothing
    wd.Quit
    Set wd = Nothing

    ' Aktualisieren der Excel-Benutzeroberfläche und beenden der Excel-Anwendung
    Application.ScreenUpdating = True
    ThisWorkbook.Saved = True
    Application.Quit

    Exit Sub

ErrorHandler:
    ' Fehlerbehandlungsroutine hier hinzufügen
    MsgBox "Ein Fehler ist aufgetreten, bitte wende dich an den Administrator!: " & Err.Description
    Application.ScreenUpdating = True

End Sub

Bei dem Befehl "wdocSource.MailMerge.Execute" kommt es nun allerdings zu einem Fehler. Die Fehlermeldung lautet: "Diese Methode oder Eigenschaft ist nicht verfügbar, weil das Dokument kein Seriendruck-Hauptdokument ist". Meine Annahme war nun, dass ich das Word Dokument durch das Anbinden an die Excel Datenquelle zum Hauptdokument gemacht habe. Ich habe die Tabelle also ganz normal über den Serienbriefassistenten verbunden und gespeichert. Weiß jemand, wo mein Fehler liegt? Hier ein Video vom Ablauf.
Herzlichen Dank für Hilfe.

 

Hallo,

warum startest du die Serienbrieffunktion nicht von Word aus, so wie es vorgesehen ist?

 

Hallo Klaus Dieter, es ist eben in meinem Fall so vorgesehen. Excel simuliert sozusagen eine Art Programm, von dem aus alle Funktionen gestartet werden sollen. Ich habe jetzt noch folgenden Code ausprobiert und dieser liefert mir auch, was ich brauche. Nur leider werde ich von Word am Ende immer zur Speicherung des Word Dokumentes aufgefordert, obwohl ich das doch eigentlich mit "WordDoc.Close SaveChanges:=False" unterbunden habe. Irgendwas ist eben immer. Habe ich etwas übersehen? Hier der Code:

Code:

Sub SerienbriefAlsPDFSpeichern()
    Dim WordApp As Object
    Dim WordDoc As Object
    Dim SaveFolder As String
    Dim SaveFileName As String
    
    ' Pfad und Dateinamen für das PDF festlegen
    SaveFolder = "C:\Users\schub\Desktop\Neuer Ordner"
    SaveFileName = "Dein_Serienbrief_" & ThisWorkbook.Sheets("Datenbasis").Range("D2").Value & ".pdf"
    
    ' Öffne Word im Hintergrund
    Set WordApp = CreateObject("Word.Application")
    WordApp.Visible = False ' Word im Hintergrund öffnen
    
    ' Öffne den vorhandenen Serienbrief in Word
    Set WordDoc = WordApp.Documents.Open("C:\Users\schub\Desktop\Neuer Ordner\Mustermann.docx")
    
    ' Aktualisiere den Serienbrief mit Daten aus Excel
    With WordDoc.MailMerge
        .MainDocumentType = wdFormLetters
        .OpenDataSource Name:=ThisWorkbook.FullName, _
                        AddToRecentFiles:=False, _
                        LinkToSource:=False, _
                        Connection:="Provider=Microsoft.ACE.OLEDB.12.0;Mode=Read;Extended Properties=""Excel 12.0 XML;HDR=YES"";", _
                        SQLStatement:="SELECT * FROM [Datenbasis$]"
        .Destination = wdSendToNewDocument
        .Execute Pause:=False
    End With
    
    ' Speichere den Serienbrief als PDF
    WordApp.ActiveDocument.ExportAsFixedFormat OutputFileName:=SaveFolder & "\" & SaveFileName, ExportFormat:=wdExportFormatPDF
    
    ' Word-Dokument schließen und Word beenden
    WordDoc.Close SaveChanges:=False
    WordApp.Quit
    
    ' Aufräumen
    Set WordDoc = Nothing
    Set WordApp = Nothing
    
    MsgBox "Serienbrief wurde als PDF gespeichert.", vbInformation
End Sub

Herzlichen Dank

 

Hat sich erledigt, das Thema kann geschlossen werden. Im Endeffekt war das hier noch nicht richtig:

Code:

 ' Word-Dokument schließen und Word beenden
    WordDoc.Close SaveChanges:=False
    WordApp.Quit

Richtig war dann das hier:

Code:

 ' Word-Dokument schließen und Word beenden
    WordApp.Quit SaveChanges:=False

Trotzdem Danke.

 

Hallo schubste,

es gibt doch die Eigenschaft: WordDoc.Saved = True
damit wird Word mitgeteilt, das daß Dokument als gespeichert angesehen wird.

Gruß von Luschi
aus klein-Paris