Office: (Office 2007) Wort in Zelle suchen und andere Farbe zuweisen

fawn · 25. Mai 2006

Hallo Forum,

ich möchte einzelne Wörter, die in den Zellen einer Tabelle verteilt sind und in Sätzen vorkommen, anders einfärben als den Rest des Satzes.

Über suchen & ersetzen färbt mir Excel aber leider bei der Suche nach dem Wort nicht nur das einzelne Wort anders ein, sondern den gesamten Text der Zelle.

Gibt es da Abhilfe?

Besten Dank!

fawn

:)

jinx · 27. Mai 2006

Moin, fawn,

das geht meines Wissens nur manuell und Stück für Stück oder durch VBA mit einer Schleife und der Nutzung von InStr. Ein Ansatz dazu:

Code:

Option Explicit

Sub SchriftFarbigUndHochgesetzt()
Dim lngFound As Long
Dim rngCell As Range
Const strSearch As String = "libris"
Application.ScreenUpdating = False
For Each rngCell In ActiveSheet.UsedRange
lngFound = 1
Do While InStr(lngFound, rngCell.Value, strSearch) > 0
With rngCell.Characters(InStr(lngFound, rngCell.Value, strSearch), Len(strSearch))
' .Font.Superscript = True
.Font.ColorIndex = 5
End With
lngFound = InStr(lngFound, rngCell.Value, strSearch) + 1
Loop
Next rngCell
Application.ScreenUpdating = True
End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

fawn · 28. Mai 2006

Hallo jinx!

Super, vielen Dank für Deine Hilfe, hat bestens geklappt!

Hast ja sogar schon die Zeile mit dem "Zeichen hochgestellt" auskommentiert, mitdenkender Weise.

Besten Dank nochmals!

Fawn

phylax · 19. November 2011

*Smilie Moin moin,
besteht auch die Möglichkeit "nur" eine ausgewählte Spalte zu durchsuchen?
Bzw. was Mus angepasst werden?
Ansonsten ist Makro einfach Spitze.

Danke.

CitizenX · 20. November 2011

Hi,

hier mal eine andere Variante

Code:

Option Explicit

Sub Suchwortfärben()
Dim strText As String, intFound As Integer
Dim Zelle As Range
Dim Regex As Object, iItems, myItems

strText = InputBox("Bitte Suchwort eingeben", "Suchtext eingabe")
If Trim(strText) = vbNullString Then Exit Sub
Set Regex = CreateObject("Vbscript.Regexp")

With Regex
.Global = True
.IgnoreCase = True
.Pattern = strText
On Error GoTo ErrExit
For Each Zelle In Columns(Selection.Column).SpecialCells(xlCellTypeConstants)
Set iItems = .Execute(Zelle)
For Each myItems In iItems
With Zelle.Characters(myItems.firstIndex + 1, myItems.Length)
.Font.Superscript = True
.Font.ColorIndex = 5
End With
Next
Next

End With
ErrExit:
Set Regex = Nothing
End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Das Suchwort wird in der ausgewählten Spalte markiert.

Office: (Office 2007) Wort in Zelle suchen und andere Farbe zuweisen

Wort in Zelle suchen und andere Farbe zuweisen

Wort in Zelle suchen und andere Farbe zuweisen

Wort in Zelle suchen und andere Farbe zuweisen

Wort in Zelle suchen und andere Farbe zuweisen - Similar Threads - Wort Zelle Farbe

Zelle Nach Wörtern durchsuchen und zurückgeben?

Excel Summe bilden wenn bestimmtes Wort und Zahl in eine Zelle vorhanden

Wort aus Index aus Text in Zelle auslesen

Wenn Zellen bestimmtes Wort enthalten dann...

Makro für Tabellenwechsel bei bestimmen Wort in Zelle.

Häufigkeiten von Wörtern in einer Zelle

Ein Wort in Zelle Farbe ändern