Office: zählen INTERVAL_COUNT: Intervalle (optional nach Kriterium) zählen

Helfe beim Thema zählen INTERVAL_COUNT: Intervalle (optional nach Kriterium) zählen in Microsoft Excel Tutorials um das Problem gemeinsam zu lösen; Als INTERVAL_COUNT sei folgende Formel benannt: =LAMBDA(Bereich;LET( xx;Bereich; y;ZEILEN(xx); x;WENN(SPALTEN(xx)=3;xx;HSTAPELN(SEQUENZ(y;;1;0);xx));... Dieses Thema im Forum "Microsoft Excel Tutorials" wurde erstellt von lupo1, 18. Mai 2023.

  1. lupo1
    lupo1 Tutorial Guru

    zählen INTERVAL_COUNT: Intervalle (optional nach Kriterium) zählen


    Als INTERVAL_COUNT sei folgende Formel benannt:

    =LAMBDA(Bereich;LET(
    xx;Bereich;
    y;ZEILEN(xx);
    x;WENN(SPALTEN(xx)=3;xx;HSTAPELN(SEQUENZ(y;;1;0);xx));
    a;INDEX(x;;1);
    b;INDEX(x;;2);
    c;INDEX(x;;3);
    f;SORTIEREN(EINDEUTIG(VSTAPELN(HSTAPELN(a;b);HSTAPELN(a;c)));{1.2});
    h;WEGLASSEN(INDEX(f;;2);-1);
    i;WEGLASSEN(INDEX(f;;2);1);
    j;NACHZEILE(MATRIXERSTELLEN(ZEILEN(h);y;LAMBDA(z;s;(INDEX(f;z;1)=INDEX(a;s))*MAX(;MIN(INDEX(i;z);INDEX(c;s))-MAX(INDEX(h;z);INDEX(b;s)))));LAMBDA(x;SUMME(x)))/(i-h);
    HSTAPELN(f;VSTAPELN(j;0))))


    Gegeben sei A1:C8:
    (DatumZeiten oder andere Zahlen ebenfalls möglich; jedoch: C >= B nötig)

    A 05:34 13:01
    A 07:35 11:01
    C 08:28 10:01
    A 10:45 17:24
    B 07:58 15:25
    A 09:59 13:25
    B 10:52 12:25
    B 12:09 19:48

    1) =INTERVAL_COUNT(A1:C8) ergibt:

    A 05:34 1
    A 07:35 2
    A 09:59 3
    A 10:45 4
    A 11:01 3
    A 13:01 2
    A 13:25 1
    A 17:24 0
    B 07:58 1
    B 10:52 2
    B 12:09 3
    B 12:25 2
    B 15:25 1
    B 19:48 0
    C 08:28 1
    C 10:01 0

    2) Abwandlung ohne das Kriterium in A: =INTERVAL_COUNT(B1:C8) ergibt:

    1 05:34 1
    1 07:35 2
    1 07:58 3
    1 08:28 4
    1 09:59 5
    1 10:01 4
    1 10:45 5
    1 10:52 6
    1 11:01 5
    1 12:09 6
    1 12:25 5
    1 13:01 4
    1 13:25 3
    1 15:25 2
    1 17:24 1
    1 19:48 0

    Die 1 ist ein Platzhalter, damit man nicht immer Zeiten und Anzahlen neu formatieren muss, nur weil das Ergebnis in anderen Spalten erscheint.

    =INTERVAL_COUNT() erwartet also einen 3-spaltigen (mit Kriterium) oder 2-spaltigen (ohne Kriterium) Bereich.
    ________________________________________-
    Die erweiterte Fassung kann auch gewichtend summieren:

    =LAMBDA(Range;[Weighed];LET(
    xx;Range;
    w;Weighed;
    i;LAMBDA(a;b;[c];INDEX(a;b;c));
    y;ZEILEN(xx);
    m;SEQUENZ(y;;1;0);
    x;WENN(SPALTEN(xx)>2+w;xx;HSTAPELN(m;xx;m));
    a;i(x;;1);
    b;i(x;;2);
    c;i(x;;3);
    d;WENN(w;i(x;;4);m);
    f;SORTIEREN(EINDEUTIG(VSTAPELN(HSTAPELN(a;b);HSTAPELN(a;c)));{1.2});
    h;WEGLASSEN(i(f;;2);-1);
    j;WEGLASSEN(i(f;;2);1);
    k;LAMBDA(e;NACHZEILE(MATRIXERSTELLEN(ZEILEN(h);y;LAMBDA(z;s;(i(f;z;1)=i(a;s))*WENN(e;i(d;s);1)*MAX(;MIN(i(j;z);i(c;s))-MAX(i(h;z);i(b;s)))));LAMBDA(x;SUMME(x)))/(j-h));
    HSTAPELN(f;VSTAPELN(k(0);0);VSTAPELN(k(1);0))))


    Ausgangsdaten A1:D8:
    A 05:34 06:00 1
    A 07:35 11:01 2,1
    C 08:28 10:01 1,001
    A 10:45 17:24 1,01
    B 07:58 15:25 1,1
    A 09:59 13:25 1,001
    B 10:52 12:25 1,01
    B 12:09 19:48 1

    a) =INTERVAL_COUNT(A1:D8;1) Variante 1) gewichtet
    b) =INTERVAL_COUNT(A1:D8;0) oder =INTERVAL_COUNT(A1:D8) oder =INTERVAL_COUNT(A1:C8) Variante 1)
    c) =INTERVAL_COUNT(B1:D8;1) Variante 2) gewichtet
    d) =INTERVAL_COUNT(B1:C8) Variante 2)

    a) sieht dann so aus:

    A 05:34:00 1 1
    A 06:00:00 0 0
    A 07:35:00 1 2,1
    A 09:59:00 2 3,101
    A 10:45:00 3 4,111
    A 11:01:00 2 2,011
    A 13:25:00 1 1,01
    A 17:24:00 0 0
    B 07:58:00 1 1,1
    B 10:52:00 2 2,11
    B 12:09:00 3 3,11
    B 12:25:00 2 2,1
    B 15:25:00 1 1
    B 19:48:00 0 0
    C 08:28:00 1 1,001
    C 10:01:00 0 0
     
    Zuletzt bearbeitet: 18. Mai 2023
    lupo1, 18. Mai 2023
    #1
Thema:

zählen INTERVAL_COUNT: Intervalle (optional nach Kriterium) zählen

Die Seite wird geladen...
  1. zählen INTERVAL_COUNT: Intervalle (optional nach Kriterium) zählen - Similar Threads - zählen INTERVAL_COUNT Intervalle

  2. Excel Summe bilden wenn bestimmtes Wort und Zahl in eine Zelle vorhanden

    in Microsoft Excel Hilfe
    Excel Summe bilden wenn bestimmtes Wort und Zahl in eine Zelle vorhanden: Hallo liebe Gemeinde, ich habe ein Problem. Ich möchte eine Summe bilden, wenn ein bestimmtes Wort in der Zelle vorhanden ist (die Zahl für die Summe ist ebenfalls in dieser Zelle): jede Zeile...
  3. Ergänzung einer Zahl um eine Maßeinheit

    in Microsoft Excel Hilfe
    Ergänzung einer Zahl um eine Maßeinheit: Hallo, man kann eine Zahl z.B. durch ein Währungszeichen ergänzen und mit der Zahl rechnen. Ist es möglich, eine Zahl so auch um den Text Stk (für Stück) zu ergänzen? Falls nicht, wie kann ich in...
  4. Stückelung mehrerer Zahlen zu einer Zielzahl

    in Microsoft Excel Hilfe
    Stückelung mehrerer Zahlen zu einer Zielzahl: Hallo an alle! Ich stehe vor folgendem Problem:. Ich habe eine Zielzahl und einen Pool aus 3 oder 4 weiteren Zahlen Das Ziel ist, dass aus dem Pool die Zahlen so addiert werden, dass man so...
  5. Filtern nach größter Zahl

    in Microsoft Excel Hilfe
    Filtern nach größter Zahl: Hallo zusammen, ich habe ein kleines Problem mit meiner Excel. Sie ist beispielhaft angehängt. Folgende Funktionen sollen erfüllt werden: In Spalte A und B stehen entweder Werte der Form AB1.1-x...
  6. 1050 Zahlen mit einem Wort wiedergeben

    in Microsoft Excel Hilfe
    1050 Zahlen mit einem Wort wiedergeben: Hallo zusammen, ich habe eine Liste, wo ich 1050 Artikelnummern mit der Endung -ENTWICKLUNG beschreiben muss in Excel. Nun möchte ich nicht alle 1050 einzeln mit Copy & paste füllen und hatte...
  7. Summieren farbiger Zahlen anhand des Farbcodes ohne VBA

    in Microsoft Excel Hilfe
    Summieren farbiger Zahlen anhand des Farbcodes ohne VBA: Hallo liebes Forum, welche Formel muss ich eingeben, wenn ich farbige Ziffern (z.B. rot = Farbcode 3; grün = 4) addieren möchte. Danke im voraus für die schnelle Antwort Gruß mfkathie
  8. DATEDIF Ergebnis

    in Microsoft Excel Hilfe
    DATEDIF Ergebnis: Hallo, ich bitte um Hilfe bei DATEDIF z. B. =DATEDIF(Anfangsdatum;Enddatum;"Y") ergibt zB. 8 in derZelle. Ich möchte aber, dass in einer Zelle 8 Jahre steht. Was muss hier hinter "Y" noch...
  1. Diese Seite verwendet Cookies, um Inhalte zu personalisieren, diese deiner Erfahrung anzupassen und dich nach der Registrierung angemeldet zu halten.
    Auf dieser Website werden Cookies für die Zugriffsanalyse und Anzeigenmessung verwendet.
    Wenn du dich weiterhin auf dieser Seite aufhältst, akzeptierst du unseren Einsatz von Cookies.
    Information ausblenden