Office: (Office 2010) Zählenwenns mit Ausschlusskriterien

Hallo Zusammen!

Ich bin neu hier und hätte eine Frage:

Ich habe eine Excel-Tabelle und verwende die Zählenwenns-Funktion. In Spalte D stehen die Namen der sechs größten Abteilungen, in Spalte I-J steht vereinzelt ein "teilgenommen". Ich kann mir für jede der sechs Abteilungen von Excel zählen lassen wie viele teilgenommen es gibt. klappt wunderbar.
ABER: immer wieder kommt es vor dass in Spalte D eine andere (kleine) Abteilung steht. Diese möchte ich nicht alle einzeln zählen, sondern alle diese kleinen zusammen. Nun wäre es einfacher, die sechs Großen auszuschließen, da es doch viele Kleine sind.

Gibt es eine Möglichkeit, anzeigen zu lassen, wie viele "teilgenommen" es gibt, die nicht in diese sechs großen Abteilungen gehören.
Also quasi: zähle alle teilgenommen in Spalte I-J, wenn in Spalte D NICHT vorkommt ... (und dann halt die sechs Abteilungen)?

Ich hoffe ich konnte das verständlich erklären.

Danke schon mal im Voraus

:)

 

Hallo Annie,

mit einer Beispieldatei kann man Dir viel leichter helfen, denn nun muss ich ein bischen im Nebel rumstochern.
Wenn Du bei ZÄHLENWENNS ein Ausschlusskriterium hast kannst Du das ganz einfach mit "blabla" ausschließen. Und da ein Ausschlusskrierium keine ODER-Bedingung darstellt sondern eine UND-Bedingung ist, kannst Du das "beliebig" oft in der Formel wiederholen.
Das Suchen von "teilgenommen" in 2 verschiedenen Spalten ist da schon schwerer, da dies eine ODER-Bedingung darstellt.

So könnte Deine Formellösung dann aussehen:

PHP:

         =ZÄHLENWENNS(I3:I18;"teilgenommen";D3:D18;"<>Abt1";D3:D18;"<>Abt2";D3:D18;"<>Abt3";D3:D18;"<>Abt4";D3:D18;"<>Abt5";D3:D18;"<>Abt6")
+ZÄHLENWENNS(J3:J18;"teigenommenl";D3:D18;"<>Abt1";D3:D18;"<>Abt2";D3:D18;"<>Abt3";D3:D18;"<>Abt4";D3:D18;"<>Abt5";D3:D18;"<>Abt6")


 

Hallo Annie,

oder wenn Du nicht mit 2 ZÄHLENWENNS arbeiten möchtest, kannst Du das auch mit SUMMENPRODUKT in einer Formel lösen:

PHP:

         =SUMMENPRODUKT((I3:J18="teilgenommen")*(D3:D18<>"Abt1")*(D3:D18<>"Abt2")*(D3:D18<>"Abt3")*(D3:D18<>"Abt4")*(D3:D18<>"Abt5")*(D3:D18<>"Abt6"))


 

Angenommen, ich habe in

A:A die möglichen Werte 1 und 2
B:B die möglichen Werte C und D

und möchte nur das zählen, was NICHT gleichzeitig 1 und C ist, dann:

=ANZAHL2(A:A)-ZÄHLENWENNS(A:A;1;B:B;"C")

+------+------+
|**C1**|**D1**|
+------+------+
|**C2**|**D2**|
+------+------+

Rot kommt also weg!

Das entspricht dann einem "ODER(2;"D")" (keine Formel!) bzw. hier

=ZÄHLENWENN(
I3:J18;"teilgenommen")-SUMMENPRODUKT(((
I3:I18="teilgenommen")+(
J3:J18="teilgenommen"))*("Abt"&SPALTE($A1:$F1)=D3:D18))

 

Vielen Dank für eure Antworten!

Ingo - die Formel mit dem Summenprodukt ist genau das was ich gesucht habe - funktioniert super!!

Perfekt, vielen herzlichen Dank

LG Annie