Office: Zählenwenns mit UND und ODER

Hi,

könnt ihr mir sagen, was ich falsch mache/ welchen Denkfehler ich habe?
Ich habe mir andere Foreneinträge durchgelesen - komme aber nicht drauf.
Ich habe den

• Namensbereich "requiredOrNot" in einer Spalte: "required" (oder andere Einträge)
• Namensbereich "level" in einer Spalte: für "A" oder "AA" (oder andere Einträge)
• Namensbereich "fulfilledOrNot" in einer Spalte: für "Yes" und "Yes, by default" (oder andere Einträge)

Ich möchte zählen:

• Wie viele Kriterien für level "A" oder "AA" UND "required" "Yes" oder "Yes, by default" haben. Momentan habe ich:

= ZÄHLENWENN(requiredOrNot; "required") + ZÄHLENWENNS(level; "A"; level; "AA") + ZÄHLENWENNS(fulfilledOrNot; "Yes";fulfilledOrNot; "Yes, by default")

• Wie viele Kriterien für level "A" und "AA" und "required" nicht erfüllt sind. Momentan habe ich:

= ZÄHLENWENN(requiredOrNot; "required") + ZÄHLENWENNS(level; "A"; level; "AA") - ZÄHLENWENNS(fulfilledOrNot; "No";fulfilledOrNot; "?")

Bye

Michael

 

Hola,
ZÄHLENWENNS(level; "A"; level; "AA")
das bedeutet, du suchst Zellen in denen "A" steht UND "AA".
Ungetestet:
=SUMME(ZÄHLENWENNS(requiredornot;"required";level;{"A"."AA"};fulfilledornot;{"yes"."yes, by default"}))
Gruß,
steve1da

 

Hi steve1da,

Danke!
Ich bin einen Schritt weiter - allerdings liefert es noch falsche Zahlen - sowohl für "Yes" als auch für "No".

Mit Trial & Error habe ich rausgefunden: Bei level MUSS mit . verknüpft werden - und bei fulfilledornot MUSS mit ; verknüpft werden! Siehe hier:

=SUMME(ZÄHLENWENNS(requiredOrNot;"required";level;{"A"."AA"};fulfilledOrNot;{"Yes";"Yes, by default"}))

Es klappt jetzt - aber ich würde mich freuen, wenn Du mir sagen könntest, WARUM dies so ist. Zum testen habe ich die Datei angehängt.

Ich habe Excel 365 Apps for Business, deutsche Systemeinstellungen, Version 2302

 

Hab ich grad keine Erklärung für. Wenn aber in F alles mit "yes" am Anfan gezählt werden soll, geht auch:
=SUMME(ZÄHLENWENNS(requiredOrNot;"required";level;{"A"."AA"};fulfilledOrNot;"yes*"))
Oder:
=SUMMENPRODUKT((E7:E102="required")*((D7:D102="a")+(D7:D102="aa"))*((F7:F102="yes")+(F7:F102="yes, by default")))

 

Hi,

umgekehrt würde es auch funktionieren. Also mit "." bei fullfilledornot und ";" bei level. Das liegt daran, dass Excel eine Tabellenkalkulation ist und Zeilen und Spalten kennt. Die Spalten werden bei einer Matrix-Darstellung mit "." getrennt und die Zeilen mit ";" (siehe dazu auch MatrixZuText() bei neueren Excel-Versionen. Und nur wenn deine Kombinationsmöglichkeiten alles abdecken, wird auch alles berücksichtigt. Daher muss die eine Oder-Bedingung in den Zeilen und die andere in den Spalten stecken. So dass alle vier (2*2) Möglichkeiten abgedeckt sind.

Du hast Glück, dass du - wie die Excel-Matrix - nur zwei Dimensionen hast, nämlich fullfilledornot und level. Hätte dein requiredornot auch noch mehrere Möglichkeiten, würde diese gekürzte Form nicht mehr funktionieren und du müsstest alle Möglichkeiten ausschreiben.

Du kannst dir vorstellen, dass das schnell sehr mühsam wird.

Bei aufwendigeren Konstellationen bietet sich SUMMENPRODUKT satt SUMME(ZÄHLENWENN()) an. Hier sind nämlich auch Oder-Verknüpfungen möglich. Im jetzigen Fall wäre das
=SUMMENPRODUKT((requiredOrNot="required")*((level="A")+(level="AA"))*(fulfilledOrNot="Yes")+(fulfilledOrNot="Yes, by default")))
Dabei entspricht ein *-Zeichen einem logischen UND und ein +-Zeichen einem logischen ODER, Klammern werden entsprechend der logischen Klammerung verwendet.

 

Hi Helmut,

ganz vielen Dank für die Erklärung!