Office: (Office 365) Zeile ausblenden anhand bestimmter Werte

Hi Beverly,

Danke für deine bisherige Hilfe!

Dass man die 2 durch 4 ersetzen muss, habe ich mir zwar gedacht, war mir aber nicht sicher. In meiner Arbeitsdatei habe ich die Anpassung vorgenommen. Da die Datei recht umfangreich ist, braucht der Button "leider" recht lange. Aber es tut

Aber in meiner Arbeitsdatei möchte ich noch 2 weitere Togglebuttons einsetzen:

ToggleButton2 (Bewertung)
Es sollen alle Zeilen, die in Spalte E kein "x" enthalten aus-/eingeblendet werden - aus 4 wird dann 5 .
Aber beim Rest bin ich natürlich überfordert.

ToggleButton3 (Baugruppen)
Im Sheet "Übersicht" ist eine Tabelle, die als Übersicht aller Baugruppen dient. Die Tabelle ist als Tabelle formatiert. In der Tabelle habe ich 3 Bereiche erstellt (Formeln -> Definierte Namen -> Namens-Manager). Nun möchte ich mittels ToggleButton3 erreichen, dass nur die Zeilen eingeblendet werden, welche die Baugruppen aus Sheet Übersicht enthalten. Als Beispiel hierfür siehe die entsprechende Bedingte Formatierung.

Die angefügte Beispieldatei entspricht soweit meiner Arbeitsdatei - Aufbau, Formeln, Bedingte Formatierung.

Dankeschön!

 

Hi Nicoletta,

für den ToggleButton2 muss man einfach prüfen, ob die Spalte 5 in der laufenden Zeile keinen Eintrag enthält:

Code:

Private Sub ToggleButton2_Click()
    Dim lngZeile As Long
    Dim lngLetzte As Long
    lngLetzte = IIf(IsEmpty(Cells(Rows.Count, 1)), Cells(Rows.Count, 1).End(xlUp).Row, Rows.Count)
    If ToggleButton2 Then
        ToggleButton2.Caption = "Bewertung" & vbLf & "Einblenden"
        For lngZeile = lngLetzte To 2 Step -1
            ' Spalte 5 (E) enthält keinen Eintrag
            If Cells(lngZeile, 5) = "" Then Cells(lngZeile, 5).EntireRow.Hidden = True
        Next lngZeile
    Else
        ToggleButton2.Caption = "Bewertung" & vbLf & "Ausblenden"
        Rows.Hidden = False
    End If
End Sub

Was den ToggleButton3 betrifft: kann es vorkommen, dass die Baugruppe in Spalte F mehrfach vorkommen kann?

---

 

Hallo Beverly,

danke für den Code für ToggleButton2!

Zu deiner Frage bzgl. ToggleButton3:
Die Namen der Baugruppen, die hier abgefragt werden sollen, sind (theoretisch) eindeutig.

Wobei es hier "nur" wichtig ist, dass eben anhand dem Inhalt der Zeilen im Blatt Übersicht geprüft wird.
Sprich: Teile-Nr. in A2 gehört zu Typ in B2 usw.

Ich hoffe, ich hab's einigermaßen verständlich erklärt ...

 

Noch eine bescheuerte Frage:
Kann ein VBA-Code auch (ohne Aufwand) mit einem "normalen" Formelement, z.B. einem Rechteck, verknüpft werden?

 

Hi Nicoletta,

für ToggleButton3:

Code:

Private Sub ToggleButton3_Click()
    Dim rngSuche As Range
    Dim lngZeile As Long
    Dim lngLetzte As Long
    lngLetzte = IIf(IsEmpty(Cells(Rows.Count, 1)), Cells(Rows.Count, 1).End(xlUp).Row, Rows.Count)
    If ToggleButton3 Then
        ToggleButton3.Caption = "Baugruppen" & vbLf & "Einblenden"
        For lngZeile = lngLetzte To 2 Step -1
            Set rngSuche = Worksheets("Übersicht").ListObjects("Tabelle1").DataBodyRange.Columns(2).Find(Cells(lngZeile, 6), lookat:=xlWhole)
            If rngSuche Is Nothing Then Cells(lngZeile, 6).EntireRow.Hidden = True
        Next lngZeile
    Else
        ToggleButton3.Caption = "Baugruppen" & vbLf & "Ausblenden"
        Rows.Hidden = False
    End If
End Sub

Aber wie schon im vorhergehenden Beitrag darauf hingewiesen: der Begriff in Spalte F darf nur einmal vorhanden sein, sonst wird er nicht erfasst.

Nochmal zu ToggleButton2 - da ist mir noch eine einfachere Variante eignefallen:

Code:

Private Sub ToggleButton2_Click()
    Dim lngZeile As Long
    Dim lngLetzte As Long
    lngLetzte = IIf(IsEmpty(Cells(Rows.Count, 1)), Cells(Rows.Count, 1).End(xlUp).Row, Rows.Count)
    If ToggleButton2 Then
        ToggleButton2.Caption = "Bewertung" & vbLf & "Einblenden"
        If Application.CountA(Range(Cells(1, 5), Cells(lngLetzte, 5))) < lngLetzte Then _
            Range(Cells(1, 5), Cells(lngLetzte, 5)).SpecialCells(xlCellTypeBlanks).EntireRow.Hidden = True
    Else
        ToggleButton2.Caption = "Bewertung" & vbLf & "Ausblenden"
        Rows.Hidden = False
    End If
End Sub

Es geht nämlich auch ohne Schleife - einfach prüfen, ob leere Zellen vorhanden sind und wenn ja, diese mittels Zelltyp "Leer" diese auf einen Ritt ausblenden.

Zu deiner Frage im letzten Beitrag: schreibe das Makro in ein Standardmodul, mache dann einen Rechtsklick auf das Element -> "Makro zuweisen..." und dann das betreffende Makro auswählen.

---