Office: Zeile mit genauem Datum ODER nachstgrößerem Datum finden

Hi,

habe nochmal ein ähnliches Problem mit z.B. folgender Tabelle:

A B
31.08.1990 #N/A N/A
29.09.1990 #N/A N/A
31.10.1990 88,61
30.11.1990 99,25
31.12.1990 97,33

Ich möchte nun z.B. zu einem vorgegeben Datum (Input-Feld) den Zeilen-Index bekommen, in dem genau dieses Datum vorhanden ist oder das nächstgrößere Datum. Habe das schon mit Vergleich() und Parameter '-1' probiert, leider geht das nicht, weil die Zeitreihe aufsteigend sortiert ist.

Beispiel:

Gesucht wird der 29.9.1990
ergebnis: 2

Gesucht wird der 31.10.1990
Ergebnis: 3

Gesucht wird der 15.10.1990
Ergebnis: 3

vg
chess

 

Hallo!

	A	B	C	D	E	F	G
1	31.08.1990					29.09.1990	2
2	29.09.1990					31.10.1990	3
3	31.10.1990					15.10.1990	3
4	30.11.1990
5	31.12.1990
6

Zelle	Formel
G1	{=MIN(WENN(A$1:A$99>=F1;ZEILE($1:$99)))}
G2	{=MIN(WENN(A$1:A$99>=F2;ZEILE($1:$99)))}
G3	{=MIN(WENN(A$1:A$99>=F3;ZEILE($1:$99)))}

Achtung, Matrixformel enthalten!Die geschweiften Klammern{} werden nicht eingegeben.Verlassen Sie den Zelleneditor mit Strg+Shift + Enter, statt Enter alleine.

 

vielen dank!

 

hi, oder ohne array-formel(n)..:

Arbeitsblatt mit dem Namen 'Tabelle2'
	A	F	G
1	31.08.1990	29.09.1990	2
2	29.09.1990	31.10.1990	3
3	31.10.1990	15.10.1990	3
4	30.11.1990
5	31.12.1990

Zelle	Formel
G1	=VERGLEICH(KGRÖSSTE(A:A;ZÄHLENWENN(A:A;">="&F1));A:A;0)

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

 

Hallo hiob!

Alternativen sind immer prima! Insbesondere dann, wenn sie matrixfrei funktionieren.
Aus Spaß und aus Langeweile habe ich hier allerdings mal Rechenzeiten für 1 Mio. Daten verglichen:

Daten:
ZUFALLSZAHL() und aufsteigend sortiert in A1:A999999
0,5 in F1

{=MIN(WENN(A$1:A$99>=F1;ZEILE($1:$99)))} (meine)
=VERGLEICH(KGRÖSSTE(A:A;ZÄHLENWENN(A:A;">="&F1));A:A;0) (deine)
=VERGLEICH(KGRÖSSTE(A1:A999999;ZÄHLENWENN(A1:A999999;">="&F1));A1:A999999;0) (nur für Spaß)
=VERGLEICH(C3;A1:A999999)+(ZÄHLENWENN(A1:A999999;C3)=0) (von excelformeln.de)


Ergebnis:
Alle Formeln rechnen gleich schnell! Die Unterschiede sind marginal und sie wechseln auch immer mal wieder, aber ich poste sie trotzdem mal:

	C	D	E
1	0,5	499668	1,968750
2	0,5	499668	1,953125
3	0,5	499668	1,968750
4	0,5	499668	1,960938

Zelle	Formel
D1	{=MIN(WENN(A1:A999999>=C1;ZEILE(1:999999)))}
D2	=VERGLEICH(KGRÖSSTE(A1:A999999;ZÄHLENWENN(A1:A999999;">="&C2));A1:A999999;)
D3	=VERGLEICH(C3;A1:A999999)+(ZÄHLENWENN(A1:A999999;C3)=0)
D4	=VERGLEICH(KGRÖSSTE(A:A;ZÄHLENWENN(A:A;">="&C2));A:A;)

Achtung, Matrixformel enthalten!Die geschweiften Klammern{} werden nicht eingegeben.Verlassen Sie den Zelleneditor mit Strg+Shift + Enter, statt Enter alleine.

 

respekt... ;-)