Office: Zeile über Makro löschen lassen

Hallo zusammen,

ich hab ein kleines Makro-Problem ....
und zwar habe ich eine Tabelle mit verschiedenen Geschäften. Ich brauche aber nur die Geschäfte, die am Vortag abgeschlossen wurden.
Alle anderen sollen über ein Makro in der Tabelle gelöscht werden.

Habe folgendes geschrieben, was aber nicht funktioniert. Kann mir jemand weiterhelfen?
(Bin kein Experte, eher ein bastelnder Anfänger ohne Erfahrung) ;-))

Dim Hinweis, Titel, Datum
Dim i1 As Integer

Hinweis = "Bitte Vortages-Datum eingeben (JJJJMMTT)"
Titel = "Eingabe Datum"
Datum = InputBox(Hinweis, Titel)

i1 = 3

Do Until Worksheets("EQF").Cells(i1, 10) < Datum
If Worksheets("EQF").Cells(i1, 10) < Datum Then
Delete.Row
End If


i1 = i1 + 1
Loop

 

Hallo dobby110,

nachfolgend ein Vorschlag zur Lösung des Problems:

Code:

Public Sub Vortag_Geschäfte()
  Dim Hinweis$, Titel$, Datum$
  Dim Zeile As Integer, ErsteZeile As Integer, LetzteZeile As Integer
  Dim KritSpalte As Range, Tabelle As Range
  
' Inputbox-Anzeige mit Vortagesdatum-Vorbesetzung:
  Hinweis$ = "Bitte Vortages-Datum eingeben (JJJJMMTT)"
  Titel$ = "Eingabe Datum"
  Datum = InputBox(Hinweis$, Titel$, Format$(Now() - 1, "YYYYMMDD"))
  
  If Datum = "" Then Exit Sub  'falls Abbrechen-Schalter gedrückt wurde
  
' Die Tabelle der Daten soll also in Zeile 3 beginnen im Arbeitsblatt "EQF".
' In der Spalte 10 (also Spalte J) soll das Kriterium stehen
'    und zwar als Datum in der umgekehrten Schreibweise - ich nehme an
'    als Text und nicht als Zahl
  Set Tabelle = Worksheets("EQF").Range("A3").CurrentRegion
  
' Kriterienspalte = 10.Spalte des Bereiches "Tabelle"
  Set KritSpalte = Tabelle.Columns(10)
  
  ErsteZeile = 1
  LetzteZeile = Tabelle.Rows.Count
  
' Es muss bei der letzten Zeile der Tabelle begonnen werden,
'   zurückschreitend bis zur 1. Zeile der Tabelle:
' Überprüfen, ob in Spalte 10 das Vortagesdatum enthalten ist:
'   falls nicht: lösche die ganze Zeile
'   falls ja:    tue nichts
  With KritSpalte
      For Zeile = LetzteZeile To ErsteZeile Step -1
        If .Cells(Zeile, 1) <> Datum$ Then
          .Cells(Zeile, 1).EntireRow.Delete
        End If
      Next Zeile
  End With
  
End Sub

1) Ein VBA-Makro dieser Art sollte man in ein allgemeines Code-Modul eingeben. Dieses ist im VBA-Editor über das Menü "Einfügen > Modul" erreichbar.
2) Ein zentrales Problem, das in Deiner Beschreibung enthalten ist, ist ein etwas heimtückisches: Du durchläufst Deine Tabelle von der 1. Zeile bis zur letzten Zeile. Stellst Du fest, dass eine Zeile keine Vortageszeile ist, wird sie gelöscht. Dadurch werden von Excel alle nachfolgenden Zeilen um 1 Zeile nach vor gereiht. Gleichzeitig erhöhst Du aber am Ende der Schleife den Zeilenzähler um 1, sodass beim nächsten Schleifendurchlauf 1 Zeile ungetestet übergangen wird.
Indem man die Tabelle von der letzten Zeile bis zur 1. Zeile durchläuft (also in umgekehrter Richtung), umgeht man das Problem, das infolge der Löschung von Zeilen entsteht.