Office: Zeilen die leer sind ein-/ausblenden

Hallo

Folgendes Probleeeem: ich möchte auf einer Seite per VBA (mittels Button)
Zeilen ein-/ausblenden die leer sind.
Es handelt sich um die Zellen A5 bis A24
Das sieht dann z.B. so aus:
Zelle A5 = mit Text gefüllt > Zeile nicht ausblenden
Zelle A6 = mit Text gefüllt > Zeile nicht ausblednen
Zelle A7 = leer > Zeile ausblenden
Zelle A8= mit Text gefüllt > Zeile nicht ausblenden
Zelle A9 = leer > Zeile ausblenden
Zelle A10 = leer > Zeile ausblenden
.....
.....
Zelle A22 = mit Text gefüllt > Zeile nicht ausblenden
Zelle A23 = leer > NICHT Zeile ausblenden
Zelle A24 = leer > NICHT Zeile ausblenden

Nun sollen alle Zeilen im Bereich A5 - A24 die leer sind ausgeblendet werden,
außer die, nach der letzten Zeile in der sich noch Text befindet.

Das Einblenden sollte natürlich auch möglich sein.

Kann mir da jemand helfen ?

Nette Grüße
Torsten

:)

 

Hallo torsten,

benutze Autofilter.

 

Hi Torsten,

versuche es mal so:

Code:

 

Hallo Torsten,

Sub ausblenden()
Dim lngLast As Long, rngHide As Range

lngLast = Evaluate("MAX(IF(A5:A24<>"""",ROW(5:24)))")

If lngLast = 0 Then lngLast = 24

On Error Resume Next
Set rngHide = Range("A5:A" & lngLast).SpecialCells(xlCellTypeBlanks)
On Error GoTo 0

If Not rngHide Is Nothing Then rngHide.EntireRow.Hidden = True

Set rngHide = Nothing
End Sub

Sub einblenden()
Range("A5:A24").EntireRow.Hidden = False
End Sub





« Gruß Sepp »

 

Vielen Dank für Eure Antworten *top

@Karin
Bei Deinem Code bekomme ich leider einen Laufzeitfehler
("Objektvariable oder With-Blockvariable nicht festgelegt")

@Sepp
Funktioniert wunderbar - genau so habe ich es mir vorgestellt.

Könnte mir ggf. noch jemand schreiben wie der Code abgeändert/ergänzt werden muss,
um ihn über mehrere Blätter (Blatt1, Blatt4 und Blatt5) anwenden zu können ?
Ursprünglich sollte er nur auf ein Blatt angewendet werden.

Ich bin einfach zu blöde einen Code über mehrere Blätter anzuwenden. *weinen

Nette Grüße
Torsten

 

Hallo Thorsten,

' **********************************************************************
' Modul: Tabelle3 Typ: Element der Mappe(Sheet, Workbook, ...)
' **********************************************************************

Option Explicit

Const cstrSheets As String = "Blatt1;Blatt4;Blatt5"

Sub ausblenden()
Dim lngLast As Long, rngHide As Range
Dim vntSheets As Variant, lngIndex As Long

vntSheets = Split(cstrSheets, ";")
For lngIndex = 0 To UBound(vntSheets)
Set rngHide = Nothing
With Sheets(vntSheets(lngIndex))
lngLast = Evaluate("MAX(IF('" & .Name & "'!A5:A24<>"""",ROW(5:24)))")

If lngLast = 0 Then lngLast = 24

On Error Resume Next
Set rngHide = .Range("A5:A" & lngLast).SpecialCells(xlCellTypeBlanks)
On Error GoTo 0

If Not rngHide Is Nothing Then rngHide.EntireRow.Hidden = True
End With
Next

Set rngHide = Nothing
End Sub

Sub einblenden()
Dim vntSheets As Variant, lngIndex As Long

vntSheets = Split(cstrSheets, ";")
For lngIndex = 0 To UBound(vntSheets)
Sheets(vntSheets(lngIndex)).Range("A5:A24").EntireRow.Hidden = False
Next

End Sub





« Gruß Sepp »

 

Hi Torsten,

in welche Zeile kommt der Fehler? Das kann ich leider nicht nachvollziehen - bei mir läuft der Code korrekt.

 

Hallo

Ich bitte um Entschuldigung, dass ich mich erst jetzt melde !
@Karin
Sorry - war mein Fehler. Ich hatte einen falschen Zellbezug angegeben.
Der Code funktioniert (allerdings ohne die Zeilen nach dem letzten Text stehen zu lassen)
Trotzdessen - vielen Dank !

@Sepp
Funktioniert tadellos !!! Vielen Dank !

Es ist nicht wichtig, aber ich frage trotzdem:
der Code funktioniert einwandfrei, wenn die Zelle "wirklich" leer ist.

Gibt es eine Möglichkeit, den Code so zu "wandeln", dass er auch funktioniert,
wenn die Zelle zwar auf "" (Anführungszeichen > für "Leer") eingestellt ist, sich in Ihr aber noch eine Formel befindet ?

Der Hintergrund ist folgender: Blatt2 bezieht seine Informationen von Blatt1 (Blatt3 aus Blatt2 ....usw.);
Wird in Blatt1 etwas in Bspw. Zelle A5 gelöscht, wird auf Blatt2 in der gleichen Zelle
die Formel "=wenn(blatt1!A5="";"";blatt1!A5)" ausgeführt.
Die Zelle in Blatt2 ist also nicht "wirklich" "leer" (sichtbar leer schon, aber nicht für Excel).
Also "xlCellTypeBlanks" funktioniert dort nur teilweise (auf Blatt1, wo etwas gelöscht wurde schon,
nur nicht auf den Folgeblättern, in denen zwar "sichtbar" auch nichts ist,
sich aber Formlen befinden) !

Idee ? Wäre sehr nett (auch wenn es völlig unwichtig erscheint *biggrin.gif* ) !

Nette Grüße
Torsten

 

Hallo Thorsten,

das Blatt mit den "echten" Leerzellen mus als erstes angeführt werden!

' **********************************************************************
' Modul: Modul3 Typ: Allgemeines Modul
' **********************************************************************

Option Explicit

Const cstrSheets As String = "Tabelle1;Tabelle3;Tabelle4"

Sub ausblenden()
Dim lngLast As Long, rngHide As Range
Dim vntSheets As Variant, lngIndex As Long

vntSheets = Split(cstrSheets, ";")
For lngIndex = 0 To UBound(vntSheets)
If rngHide Is Nothing Then
With Sheets(vntSheets(lngIndex))
lngLast = Evaluate("MAX(IF('" & .Name & "'!A5:A24<>"""",ROW(5:24)))")

If lngLast = 0 Then lngLast = 24

On Error Resume Next
Set rngHide = .Range("A5:A" & lngLast).SpecialCells(xlCellTypeBlanks)
On Error GoTo 0
End With
End If
If Not rngHide Is Nothing Then Sheets(vntSheets(lngIndex)).Range(rngHide.Address).EntireRow.Hidden = True
Next

Set rngHide = Nothing
End Sub

Sub einblenden()
Dim vntSheets As Variant, lngIndex As Long

vntSheets = Split(cstrSheets, ";")
For lngIndex = 0 To UBound(vntSheets)
Sheets(vntSheets(lngIndex)).Range("A5:A24").EntireRow.Hidden = False
Next

End Sub





« Gruß Sepp »

 

Taaaaaaaadellos ! Vielen, vielen Dank !!!!!!

Nette Grüße und noch ein schönes Wochenende
Torsten

 

Ich glaube, dass ich jetzt unverschämt werde .....
und es macht ÜBERHAUPT NICHTS, wenn niemand (konstruktiv) antwortet.

Besteht "ggf. evtl. vielleicht" die Möglichkeit, die Zeilen, die ausgeblendet wurden
auch wieder (und NUR die zuvor ausgeblendeten - alle anderen sollen "unberührt" bleiben)
einzublenden ?

..... ich werde NIE WIEDER eine solch dreiste Frage stellen !

Nette Grüße
Torsten

 

Hallo Torsten,

das ist nicht unverschämt, du brauchst dich also nicht entschuldigen.

Nimm den Code von "ausblenden" und schreib statt .Hidden = True einfach .Hidden = False




« Gruß Sepp »

 

Das kann ich nicht nachvollzeihen - in der hochgeladenen Mappe werden die letzten Zeilen korrekt nicht berücksichtigt und bleiben eingeblendet. Wenn das in deiner Originaldatei nicht der Fall ist, dann hast du 1. andere Bedingungen und/oder 2. hast du den Code nicht korrekt an deine Bedingungen angepasst.

 

Hallo, bin neu hier und habe ein ähnliches Problem :

in einer Arbeitsmappe sind zwei Tabellenblätter, wobei auf Blatt 2 sich alle Zellen auf die gleiche Zelle auf Blatt 1 beziehen (praktisch gespiegelt).
Nun sollen aber alle Zeilen auf Blatt 2 wo die Zelle in Spalte D leer ist (die jedoch die Formel "Bezug auf Blatt 1" enthält) automatisch ausgeblendet werden. Wenn jedoch auf Blatt 1 in eine Zelle der Spalte D geschrieben wird soll die Zeile auf Blatt 2 automatisch eingeblendet werden.
Hintergrund ist der, dass auf Blatt 1 eine Art Auslieferungskalender ist, der ständig im Büro aktualisiert wird. Blatt 2 dient auf einem zweiten Monitor in einem anderen Raum als Anzeige, wo jedoch nur die jeweils 10 nächsten Auslieferungen angezeigt werden. Dort sollen also die noch freien Auslieferungstermine zwecks Übersichtlichkeit nicht angezeigt werden.Falls ein Termin auf einem freien Slot dazwischen geschoben wird muss die ausgeblendete Zeile deshalb wieder automatisch eingeblendet werden.
Das geht aber wahrscheinlich nur mit einem Makro, oder ?
Gibt es jemanden der mir da helfen kann.

Besten Dank im Voraus sagt

Wolfgang: