Office: Zeilen durch mehrere Tabellen weiterleiten

Hallo euch allen!

Bin recht neu auf dem Gebiet Excel und hab ein (für mich) kniffliges Problem an dem ich mir schon den ganzen Tag die Zähne ausbeisse :-(

Habe eine Excel Datei mit insgesammt 6 Tabellen

Gesamt / Bearbeitung / Termin / Absage / Zusage / Kunde

In Gesamt befinden sich insgesammt 400 Zeilen. Die Idee ist nun folgende:

Ich möchte das Excel mir die jeweilige Zeile die ich bearbeite, jeh nach dem was ich in lezte Zelle reinschreibe an eine beliebige der folgenden Tabellen weiterleitet.

Das sieht nun z.B. so aus: In der Tabelle Gesamt ist F die erste freie Zelle. Wenn ich dort nun "Bearbeitung" eintrage müsste die ganze Zeile in die Tabelle "Bearbeitung" verschoben werden. Dort würde ich z.B. "Absage" reinschreiben und die Zeile müsste in die Tabelle "Absage" flutschen ....

Fällt es hier vielleicht jemandem leichter als mir auf eine Lösung zu kommen?

Beste Grusse!

 

Flutschen tut da wohl nur was per VBA. Ohne das jetzt großartig testen zu können, aber so in der Richtung müßte es gehen:

a) In jedem Blatt, wo was verschoben werden soll, muß die Änderung verfollgt werden. Entsprechend muß in den VBA-Source der Blätter:

Code:

Option Explicit

Private Sub Worksheet_Change(ByVal Target As Range)

    Zeile_verschieben ActiveSheet, Target

End Sub

b) Ob und wohin verschoben wird, erledigt dann diese Routine, die in einem globalen Modul sitzt:

Code:

Option Explicit

Public Sub Zeile_verschieben(s1 As Worksheet, c1 As Range)

    Dim s2 As Worksheet

    If ((c1.Cells.Count = 1) And (c1.Column = 6)) Then
        Select Case c1.Value
            Case "":
                Set s2 = Nothing
            Case "B":
                Set s2 = Worksheets("in Bearbeitung")
            Case "A":
                Set s2 = Worksheets("Absage erhalten")
            ' ...
            Case Else
                Set s2 = Nothing
                MsgBox "Doh!"
        End Select
        If (Not s2 Is Nothing) Then
            s1.Rows(c1.Row).Cut Destination:=s2.Rows(s2.Cells(65536, 1).End(xlUp).Row + 1)
        End If
    End If

End Sub

Hier wird zuerst überprüft, ob die Änderung nur in einer Zelle und in Spalte F stattgefunden hat. Wenn ja, wird der Reihe nach auf gültige Werte überprüft und darüber das Ziel-Blatt bestimmt. Und dann wird die aktuelle Zeile komplett in das Zielblatt verschoben, und zwar ans Ende der dortigen Liste.

Wie gesagt, völlig ungetestet, aber müßte eigentlich so klappen...

Gruß, Michael

 

Erst mal viele Dank

Also mal schauen ob ich das richtig verstanden hab...

Teil a) kommt in jedes Blatt rein

Teil b) muss ebenfalls in jedes Blatt aber jeweils an das Blatt in folgenden Stellen angepasst werden:

Case "B":
Set s2 = Worksheets("in Bearbeitung")
Case "A":
Set s2 = Worksheets("Absage erhalten")

richtig so?

 

yep

nope

Teil b) kommt in ein eigenes Modul (Menü "Einfügen - Modul"). Damit ist der Kram von allen "Blatt"-Modulen aus sichtbar und muß nicht in jedem Blatt wiederholt werden.

Code:

an das Blatt in folgenden Stellen angepasst werden:

yep

Direkt hinter dem CASE steht jeweils, was Du als Eingabe in der Zelle erwartest und hinter SET steht dann das Blatt, auf das die Zeile verschoben werden soll.

Ob Du eine Warnmeldung ("Doh!") haben möchtest, wenn eine unerwartete / falsche Eingabe erfolgt, kannst Du im CASE ELSE entscheiden.

Gruß, Michael