Office: Zeilen einer Zelle in mehrere Zellen aufteilen. Wie???

Hallo,
ich habe mehrere Zellen, in denen verschiedene Angaben durch einen Umbruch getrennt sind. Ich möchte die Angaben aus einer Zelle in 2 aufteilen. Lässt sich das mit VBA lösen?
_________________
mustera1 | musterb1 |
mustera2 | musterb2 |
musterc1 | musterd1 |
musterc2 | musterd2 |

Vielen Dank für eure Hilfe.

 

Hallo!

Das lässt sich auch ohne VBA lösen:
Die erste Zeile erhältst du mit

=LINKS(A1;FINDEN(ZEICHEN(10);A1)-1)

Die zweite Zeile erhältst du mit

=RECHTS(A1;LÄNGE(A1)-FINDEN(ZEICHEN(10);A1))

 

Danke für die schnelle Antwort!!
Geht das auch mit mehr als 2 Spalten; gibt es neben "rechts" & "links" weitere Befehle? und mich würde noch interessieren, wie man die Codezahl eines Zeichens herausbekommt.

 

Hallo!

Bei mehr als einem Zeilenumbruch wird's etwas kniffliger...
Die zweite Zeile erhältst du mit

=TEIL($A1;FINDEN("#";WECHSELN($A1;ZEICHEN(10);"#";1))+1;FINDEN("#";WECHSELN($A1;ZEICHEN(10);"#";2))-FINDEN("#";WECHSELN($A1;ZEICHEN(10);"#";1))-1)

Die dritte Zeile erhältst du mit

=TEIL($A1;FINDEN("#";WECHSELN($A1;ZEICHEN(10);"#";2))+1;FINDEN("#";WECHSELN($A1;ZEICHEN(10);"#";3))-FINDEN("#";WECHSELN($A1;ZEICHEN(10);"#";2))-1)

usw.

 

vielen Dank für deine Hilfe Schatzi!!!

 

Ich habe doch noch ein Problem: diese Befehle funktionieren nur, wenn in diesem Beispiel 4 Zeilen in der Zelle sind. Ich schaffe es jedoch nicht die vierte/bzw. letzte Zeile auszulesen. Ich bekomme immer die Fehlermeldung #WERT ausgespuckt.
Vielleicht hast du noch einen Lösungsvorschlag für mich?!?

Danke im Voraus

 

Hallo!

Die letzte Zeile geht z.B. so:

=RECHTS(A1;LÄNGE(A1)-FINDEN("#";WECHSELN(A1;ZEICHEN(10);"#";LÄNGE(A1)-LÄNGE(WECHSELN(A1;ZEICHEN(10);"")))))

Bei all diesen Formeln musst du darauf achten, dass an KEINER Stelle deiner Texte eine Raute (#) auftaucht! Sonst musst du diesen Platzhalter durch einen anderen ersetzen.