Office: Zeilen eines Tabellenblattes in ein anderes übernehmen

Hallo mal wieder!

Ich soll in meiner Firma eine Tabelle erstellen, in der für jeden Beschäftigten die Arbeitszeiten erfasst sind:

Gesamt - Mehrarbeit - Mehrarbeit abgebaut - Gesamt neu - Abteilung

Darüber hinaus brauch ich dann in weiteren Tabellenblättern genau diese Werte wieder - allerdings nur für die einzelnen Abteilungen, damit man das getrennt vorlegen kann.

Ist es nun möglich, automatisiert zu sagen, dass man eine Zeile automatisch in das jeweils richtige Tabellenblatt übernehmen will?

Hoffe mal, dafür gibts eine Lösung!

Liebe Grüße

Maudell

 

Hallo,

klar geht das.

Die Ausgangstabelle:

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D	E
1	Gesamt	Mehrarbeit	abgebaut	Neu	Abteilung
2	1	M1	A1	N1	Abt1
3	2	M2	A2	N2	Abt2
4	3	M3	A3	N3	Abt1
5	4	M4	A4	N4	Abt3
6	5	M5	A5	N5	Abt3
7	6	M6	A6	N6	Abt1

Die Tabelle für die Abteilung1:

Arbeitsblatt mit dem Namen 'Abteilung1'
	A	B	C	D	E	F
1	Abt1	Gesamt	Mehrarbeit	abgebaut	Neu	Abteilung
2		1	M1	A1	N1	Abt1
3		3	M3	A3	N3	Abt1
4		6	M6	A6	N6	Abt1

Zelle	Formel
B2	{=WENN(SUMME((Tabelle1!$E$2:$E$20=$A$1)*1)<ZEILE(Tabelle1!$A1);"";INDIREKT("Tabelle1!A"&KKLEINSTE(WENN((Tabelle1!$E$2:$E$20=$A$1);ZEILE(Tabelle1!$2:$20));ZEILE(Tabelle1!$A1))))}
C2	{=WENN(SUMME((Tabelle1!$E$2:$E$20=$A$1)*1)<ZEILE(Tabelle1!$A1);"";INDIREKT("Tabelle1!B"&KKLEINSTE(WENN((Tabelle1!$E$2:$E$20=$A$1);ZEILE(Tabelle1!$2:$20));ZEILE(Tabelle1!$A1))))}
D2	{=WENN(SUMME((Tabelle1!$E$2:$E$20=$A$1)*1)<ZEILE(Tabelle1!$A1);"";INDIREKT("Tabelle1!C"&KKLEINSTE(WENN((Tabelle1!$E$2:$E$20=$A$1);ZEILE(Tabelle1!$2:$20));ZEILE(Tabelle1!$A1))))}
E2	{=WENN(SUMME((Tabelle1!$E$2:$E$20=$A$1)*1)<ZEILE(Tabelle1!$A1);"";INDIREKT("Tabelle1!D"&KKLEINSTE(WENN((Tabelle1!$E$2:$E$20=$A$1);ZEILE(Tabelle1!$2:$20));ZEILE(Tabelle1!$A1))))}
F2	{=WENN(SUMME((Tabelle1!$E$2:$E$20=$A$1)*1)<ZEILE(Tabelle1!$A1);"";INDIREKT("Tabelle1!E"&KKLEINSTE(WENN((Tabelle1!$E$2:$E$20=$A$1);ZEILE(Tabelle1!$2:$20));ZEILE(Tabelle1!$A1))))}

<table><tr><td>Achtung, Matrixformel enthalten!</td></tr><tr><td><span>Die geschweiften Klammern{} werden </span><span>nicht</span><span> eingegeben.</span></td></tr><tr><td><span>Verlassen Sie den Zelleneditor mit </span><span>Strg+Shift + Enter</span><span>, statt Enter alleine.</span></td></tr></table>[/parsehtml]

Wenn du hier in A1 jetzt Abt3 einträgst dann sieht das ganze so aus:

Arbeitsblatt mit dem Namen 'Abteilung1'
	A	B	C	D	E	F
1	Abt3	Gesamt	Mehrarbeit	abgebaut	Neu	Abteilung
2		4	M4	A4	N4	Abt3
3		5	M5	A5	N5	Abt3

Du kannst das Tabellenblatt einfach kopieren und in A1 die Abteilung eintragen und du erhälst die entsprechende Auswertung.

Hilft dir das weiter?