Office: (Office 365) Zeilen gruppieren und zugehörige Spalte aufteilen

C1: =LAMBDA(ab;o;LET(
a;INDEX(ab;;1);
b;INDEX(ab;;2);
c;EINDEUTIG(a);
d;SCAN(1;a=VSTAPELN(0;WEGLASSEN(a;-1));LAMBDA(y;z;(y+1)*z))+1;
e;SCAN(1;d<VSTAPELN(0;WEGLASSEN(d;-1));LAMBDA(y;z;y+z));
f;MAX(d);
g;MAX(e);
h;REST(SEQUENZ(f*g)-1;f)+1;
i;GANZZAHL(SEQUENZ(f*g;;f)/f);
k;WENNFEHLER(WEGLASSEN(SORTIEREN(HSTAPELN(EINDEUTIG(VSTAPELN(HSTAPELN(d;e);HSTAPELN(h;i)));b);2);;2);"");
m;INDEX(k;SEQUENZ(g;f));
n;NACHZEILE(m;LAMBDA(a;TEXTVERKETTEN(";";;a)));
HSTAPELN(c;WAHL(o;m;n))))(A1:B50000;1)

benötigt tatsächlich nur 1 bis 2 Sekunden, da es nur einen Sort gibt und außer den beiden einmaligen SCAN keine Datenanalyse. Aber: Bei einem Ergebnis von irgendwo mehr als 5000, auf jeden Fall aber 10000 Kategorien der Spalte A, gibt es #ÜBERLAUF! Und bei einem Ergebnis von irgendwo mehr als 2200 Zeilen (mit ca. 223 zusammenfassenden Kategorien) treten inhaltlich Fehler auf (z.B. Zuviel-Zuordnungen), ohne Fehlermeldung. Also nochmal:

Für die Bildung der Spalten A:B: (sortierte Ausgangsdaten (A1:B50000;1)), Excel 365 (2211-15806.20000)
A1: =SORTIEREN(ZUFALLSMATRIX(50000;1;1;10000;1)) ergibt die o.g. Funktion #ÜBERLAUF!
A1: =SORTIEREN(ZUFALLSMATRIX(50000;1;1;5000;1)) ist die o.g. Funktion technisch scheinbar funktionierend, inhaltlich jedoch falsch

Nebenbemerkung: Unverändert jeweils
B1: ="text"&ZUFALLSMATRIX(50000;1;1;15;1)

Gehe ich in der Lambda-Funktion auf die Argumente (A1:B2200;1), klappt es dann auch inhaltlich korrekt (2200 Ausgangsdaten, mit ca. 223 Kategorien und ca. einem häufigsten Auftreten von B:B von 18 Mal.

Überraschung bei XLWeb: (A1:B50000;1) bei =SORTIEREN(ZUFALLSMATRIX(50000;1;1;5000;1)) inhaltlich korrekt und in 1 Sekunde! Möglicherweise muss ich XL365 noch einmal frisch starten ... ob es dann auch geht? Nein. Selbst bei frischem Eingeben in eine neue Tabelle kommt es inhaltlich zu Fehlern.

Doku der Schritte:
C1: =LAMBDA(ab;o;LET( --- Übergabe des Bereichs A:B und 1 (Zellen) oder 2 (Verkettung in 1 Zelle)
a;INDEX(ab;;1); --- Isoliere Spalte A
b;INDEX(ab;;2); --- Isoliere Spalte B
c;EINDEUTIG(a); --- Baue die Kategorien (Vorspalte für die Flatterdaten)
d;SCAN(1;a=VSTAPELN(0;WEGLASSEN(a;-1));LAMBDA(y;z;(y+1)*z))+1; --- Zähle A jeweils von 1 bis n
e;SCAN(1;d<VSTAPELN(0;WEGLASSEN(d;-1));LAMBDA(y;z;y+z)); --- Zähle wechselndes A als +1
f;MAX(d); --- Ermittle die Breite der Ausgabe neben der Vorspalte
g;MAX(e); --- Ermittle die Höhe der Ausgabe
h;REST(SEQUENZ(f*g)-1;f)+1; --- Baue die Zahlen 1 bis n g-mal untereinander
i;GANZZAHL(SEQUENZ(f*g;;f)/f); --- Kopiere ab 1 jede Ganzzahl h-mal untereinander
k;WENNFEHLER(WEGLASSEN(SORTIEREN(HSTAPELN(EINDEUTIG(VSTAPELN(HSTAPELN(d;e);HSTAPELN(h;i)));b);2);;2);"");
--- Setze d und e nebeneinander sowie h und i ebenso und hänge letzteres unter ersteres. Lösche die Duplikate und setze a daneben. Lösche nun die anderen beiden Spalten außer a und ersetze #NV durch "".
m;INDEX(k;SEQUENZ(g;f)); --- kürzere Variante als MATRIXERSTELLEN! Die Spalte k wird als gewünschte Matrix gebaut
n;NACHZEILE(m;LAMBDA(a;TEXTVERKETTEN(";";;a))); --- die Matrix wird zeilenweise verkettet
HSTAPELN(c;WAHL(o;m;n))))(A1:B50000;1) --- Die Vorspalte wird vorgehängt und dann entweder m oder n daneben