Office: Zeilen tauschen mit Makro

basti182 · 22. Juni 2013

Hallo,

ich suche einen Makro-Code mit dem man aus einer Excel-Tabelle zwei Zeilen tauschen kann. Im Idealfalls soll gefragt werden "Welche Zeilen wollen Sie tauschen?", Eingabe der Ziffern und Ausführung des Makros.

Viele Grüße
Basti

:)

aloys78 · 24. Juni 2013

Hallo Basti,

unter der Annahme, dass die Zellen einer Spalte jeweils gleich formatiert sind, folgender Code-Vorschlag:

Code:

Option Explicit

Sub Zeilen_tauschen()
Dim strMeldung As String, strTitel As String
Dim strVorschlag As String, strAntwort As String
Dim temp
Dim r1 As Long
Dim r2 As Long
Dim c1 As Long
Dim c2 As Long
Dim c As Long

'Dialog
strTitel = "Zeilen vertauschen"
strMeldung = "Bitte erste Zeilen-Nr eingeben !"
strVorschlag = ""
strAntwort = Application.InputBox(strMeldung, strTitel, strVorschlag, Type:=1)
If strAntwort = False Then Exit Sub
r1 = strAntwort
strMeldung = "Bitte die zweite Zeilen-Nr eingeben !"
strAntwort = Application.InputBox(strMeldung, strTitel, strVorschlag, Type:=1)
If strAntwort = False Then Exit Sub
r2 = strAntwort
If r1 = r2 Then Exit Sub

'maximal letzte belegte Zelle ermitteln
c1 = Cells(r1, Columns.Count).End(xlToLeft).Column
c2 = Cells(r2, Columns.Count).End(xlToLeft).Column
If c1 < c2 Then
c1 = c2
End If

'Zeilen vertauschen
For c = 1 To c1
temp = Cells(r1, c)
Cells(r1, c) = Cells(r2, c)
Cells(r2, c) = temp
Next c
End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Gruß
Aloys

aloys78 · 25. Juni 2013

Hallo Basti,

und hier noch eine etwas elegantere Möglichkeit:

Code:

Option Explicit

Sub Zeilen_tauschen()
Dim strMeldung As String, strTitel As String
Dim strVorschlag As String, strAntwort As String
Dim r1 As Long
Dim r2 As Long

'Dialog
strTitel = "Zeilen vertauschen"
strMeldung = "Bitte erste Zeilen-Nr eingeben !"
strVorschlag = ""
strAntwort = Application.InputBox(strMeldung, strTitel, strVorschlag, Type:=1)
If strAntwort = False Then Exit Sub
r1 = strAntwort
strMeldung = "Bitte die zweite Zeilen-Nr eingeben !"
strAntwort = Application.InputBox(strMeldung, strTitel, strVorschlag, Type:=1)
If strAntwort = False Then Exit Sub
If strAntwort < r1 Then
r2 = r1
r1 = strAntwort
Else
r2 = strAntwort
End If
If r1 = r2 Then Exit Sub

'Zeilen vertauschen
Application.ScreenUpdating = False
Rows(r1).Cut
Rows(r2).Insert Shift:=xlShiftDown
Rows(r2).Cut
Rows(r1).Insert Shift:=xlShiftDown
Application.CutCopyMode = False
Application.ScreenUpdating = True
End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Gruß
Aloys

AliceD · 9. Dezember 2018

ist zwar schon etwas her ^^ aber kann man da noch dran was verfeinern?
So dass er nicht die ganze Zeile tauscht, sondern nur "D" und "E" zB...
und muss es die Zeilen Nummer sein, die man angibt, oder kann man das auch auf etwas anderes lenken?
Danke.

MisterBurns · 9. Dezember 2018

Da wirst du schon ein etwas konkreteres Beispiel liefern müssen.
Und zur zweiten Frage: Du kannst dir die Eingabe der ersten (zu verschiebenden) Zeilennummer sparen, indem du einfach die aktuell ausgewählte Zeile abfragst. Dann muss halt der User tatsächlich aktiv die Zeile auswählen, die verschoben werden soll. Die Zielzeile wirst du dennoch irgendwo eingeben müssen. Ob das nun eine Zelle, ein Textfeld oder eben eine Inputbox ist, ist egal.

AliceD · 10. Dezember 2018

etwas konkretes? steht doch da.
Den Code aus #3 find ich echt super, nur das er
NUR "D" und "E" tauschen sollte und nicht die ganze Zeile.

ich weiß nicht ob man mit rows immer die ganze Zeile oder Spalte anspricht, oder
ob man da auch Einschränkungen machen kann... Das ist ja meine Frage.

bzw. bin ich mir ja fast sicher, dass rows immer ganze Spalten oder Zerilen anspricht, sollte man dann doch lieber
Range nehmen, aber wie kann man das mit Variablen aus der Abfrage machen?

AliceD · 10. Dezember 2018

hab das mal versucht und den unteren Bereich geändert:

'Zeilen vertauschen
Application.ScreenUpdating = False
Range("Dr1:Fr1").Cut
Range("Dr2:Fr2").Insert Shift:=xlShiftDown
Range("Dr2:Fr2").Cut
Range("Dr1:Fr1").Insert Shift:=xlShiftDown
Application.CutCopyMode = False
Application.ScreenUpdating = True
End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

interessanter Weise kommt keine Fehlermeldung, es passiert aber auch nix

AliceD · 10. Dezember 2018

ok mit cells funktioniert es.

erpe · 10. Dezember 2018

zw. bin ich mir ja fast sicher, dass rows immer ganze Spalten oder Zerilen anspricht, sollte man dann doch lieber
Range nehmen, aber wie kann man das mit Variablen aus der Abfrage machen?
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Du solltest dich wirklich mal mit den Basics befassen!
Was sind Rows?
Was sind ganze Spalten?
Und was sind Zerilen?

Letztendlich sind diese Hinweise wieder kostenlos und auch umsonst für dich.

MisterBurns · 10. Dezember 2018

Du bist dir also fast sicher, dass man mit dem englischen Wort "Rows" Spalten ansprechen kann? Sehr interessant.
Auch ich empfehle dir dringend, dass du dir mal VBA Grundlagen zu Gemüte führst. Das würde dir eine Menge Fragen ersparen...
Visual Basic für Applikationen - Das VBA-Tutorial
Online - Excel Programmierung VBA Makro: Grundlagen

Und dass bei deinem Code "nix passiert" kann ich nicht nachvollziehen.

AliceD · 10. Dezember 2018

ich dachte man könnte das evtl eingrenzen... mein Gott.

Office: Zeilen tauschen mit Makro

Zeilen tauschen mit Makro

Zeilen tauschen mit Makro

Zeilen tauschen mit Makro

Zeilen tauschen mit Makro

Zeilen tauschen mit Makro - Similar Threads - Zeilen tauschen Makro

VBA in einer Zeile zu lang

Wenn ein Wert ein einer Spalte, dann komplette Zeile im anderen Blatt untereinander einfügen.

Buchsatz mit Word: untere Zeile der Seiten immer auf der gleichen Höhe

leere Zelle in Zeile finden

VBA: Platzhalter ersetzen und evtl. leere Zeile einfügen

Tausch von Zeile/Spalte bei Pivot Chart

Zeilen und Spalten tauschen