Office: (Office 2010) Zeilen und Spalten mit VBA ausblenden wenn Wert 0 in bestimmten Zellen

Hallo Excel Kolleginnen und Kollegen,

ich habe mehrere Excel-Tabellen mit gleichem Layout aber nicht immer die gleichen Spalten und Zeilen befüllt, möchte nun mit VBA und Makro mir die Zeilen und Spalten pro Tabelle aus- bzw. einblenden. Die Zeilen hab ich schon mal soweit, nun will ich in diesem Makro auch noch die Spalten ausblenden, die Spalte H soll immer ausgeblendet werden, K bis P und S bis X nur wenn in der jeweiligen Spalte in Zeile 15 der Wert 0 enthalten ist soll die Spalte ausgeblendet werden. Mit einem einfach Makro sollen dann Zeilen und Spalten wieder alle eingeblendet werden. Hier mal meine beiden Codes für die Zeilen, der dann erweitert auch gleich die Spalten enthalten soll, damit ich nur immer ein Button drücken muss, ist das möglich. Und bitte nicht täuschen lassen ich bin kein VBA User, also bitte genaue Beschreibung wie und wo ich die Änderungen einfügen muss.
Gleich mal Vielen Dank für Eurer Hilfe im Voraus!!!

Public Sub AusblendenZeilen()

Dim lngRow As Long
Dim ws As Worksheet

With Application
.Calculation = xlCalculationManual
.EnableEvents = False
.ScreenUpdating = False
End With

For Each ws In ActiveWindow.SelectedSheets

With ws

For lngRow = 17 To 46
.Rows(lngRow).Hidden = .Cells(lngRow, 25).Value = 0
Next lngRow
For lngRow = 54 To 67
.Rows(lngRow).Hidden = .Cells(lngRow, 25).Value = 0
Next lngRow
For lngRow = 75 To 104
.Rows(lngRow).Hidden = .Cells(lngRow, 25).Value = 0
Next lngRow
For lngRow = 126 To 139
.Rows(lngRow).Hidden = .Cells(lngRow, 25).Value = 0
Next lngRow
End With
Next ws

With Application
.Calculation = xlCalculationAutomatic
.EnableEvents = True
.ScreenUpdating = True
End With
End Sub

Sub EinblendenZeilen()
Range("n17 : n139").EntireRow.Hidden = False
End Sub

 

Hi,

versuche es mal so (ungetestet):

Code:

Option Explicit
Dim ws As Worksheet

Public Sub Ausblenden()
    Dim lngRow As Long
    Dim intSpalte As Integer
    Dim intCalculation As Integer
    With Application
        intCalculation = .Calculation
        .Calculation = xlCalculationManual
        .EnableEvents = False
        .ScreenUpdating = False
    End With
    For Each ws In ActiveWindow.SelectedSheets
        With ws
            For lngRow = 17 To 46
                .Rows(lngRow).Hidden = .Cells(lngRow, 25).Value = 0
            Next lngRow
            For lngRow = 54 To 67
                .Rows(lngRow).Hidden = .Cells(lngRow, 25).Value = 0
            Next lngRow
            For lngRow = 75 To 104
                .Rows(lngRow).Hidden = .Cells(lngRow, 25).Value = 0
            Next lngRow
            For lngRow = 126 To 139
                .Rows(lngRow).Hidden = .Cells(lngRow, 25).Value = 0
            Next lngRow
            .Columns("H").Hidden = True
            For intSpalte = 11 To 24
                .Columns(intSpalte).Hidden = .Cells(15, intSpalte) = 0
                If intSpalte = 16 Then intSpalte = 18
            Next intSpalte
        End With
    Next ws
    With Application
        .Calculation = intCalculation
        .EnableEvents = True
        .ScreenUpdating = True
    End With
End Sub

Sub Einblenden()
    For Each ws In ActiveWindow.SelectedSheets
        ws.Rows.Hidden = False
        ws.Columns.Hidden = False
    Next ws
End Sub

Hinweis: ich würde am Ende die Berechnung nicht generell auf automatisch setzen, denn falls ein Benutzer standardmäßig z.B. manuell eingestellt hat, wird er sich wundern, wenn die Berechnung plötzlich auf automatisch steht. Stattdessen würde ich zu Beginn prüfen, welche Einstellung vorhanden ist und auf diese dann wieder zurücksetzen.

Bis später,
Karin

 

Hallo Karin,

danke ist perfekt.

Was verstehst du mit "automatisch"? Hab ich das in meinem Makro hinterlegt?
Wie gesagt bin nicht so gut im VBA Bereich.

LG Richard ;)

 

Hi Richard,

zu Beginn deines Makros setzt du ja die Berechnung auf manuell mit .Calculation = xlCalculationManual - das ist völlig korrekt, wenn du die Berechnung ausschalten möchtest um eine Codeauführung zu beschleunigen. Am Ende des Code setzt du sie dann mit .Calculation = xlCalculationAutomatic auf automatisch, ohne aber zu wissen, wie die Berechnung tatsächlich eingestellt war, ehe du sie auf manuell stellst.
Bei meinem Code dagegen wird zu Beginn zuerst die Einstellung der Berechnung ausgelesen und auf eine Variable geschrieben, und dann auf manuell gesetzt

Code:

        [COLOR=#0000ff][I]intCalculation = .Calculation[/I][/COLOR]
        .Calculation = xlCalculationManual

und am Ende wird sie wieder in den Ursprungszustand gesetzt, welcher nicht unbedingt auf automatisch eingestellt gewesen sein muss:

Code:

        .Calculation = [COLOR=#0000ff][I]intCalculation[/I][/COLOR]

Falls nur du selbst die Mappe verwendest und die Berechnung bei dir grundsätzlich auf automatisch gestellt ist, wirst du da keinen Unterschied merken, aber falls andere Benutzer der Mappe (oder in anderen Projekten die du programmierst) eine andere Einstellung der Berechnung (z.B. manuell) bevorzugen, würde sie in deinem Fall am Ende eben auf automatisch und nicht in den Ausgangszustand zurückgesetzt. Meine Vorgehensweis ist einfach eine Vorsichtsmaßnahme, um den Ausgangszustand für die Berechnung wiederherzustellen - weiter nichts. :)

Bis später,
Karin

 

Hallo Krain,

Vielen lieben Dank für die tolle Erklärung und hab deinen Code eingebaut, es arbeiten mehr Personen darauf und auch ich schalte die automatische Berechnung teilweise aus, da ich sonst immer Probleme mit Excel habe bei mehreren offenen Arbeitsmappen.

LG Richard