Office: Zeitleiste

Hallo, ich habe im Access folgendes Problem: ich habe in einer Tabelle Zeitpunkt 1 und Zeitpunkt 2. Ich möchte die Differenz ermitteln und bei einer fest definierten Pause (zum Beispiel 30 Minuten von 12:00 bis 12:30) soll diese Zeit abgezogen werden

 

Hallo,

folgende Formel müsste funktionieren, wobei die beiden Tabellenfelder [Zeitpunkt1] bzw. [Zeitpunkt2] heißen und die Uhrzeit in [Zeitpunkt2] die spätere ist:
[Zeitpunkt2]-[Zeitpunkt1]-1/24/2
Dabei bedeutet der zusätzliche Abzug von 1/24/2 genau die halbe Stunde für die Mittagspause.

Zur Erklärung:
In allen Office-Programmen gilt Folgendes bei der Datums/Uhrzeitrechnung:
Die Zeiteinheit ist 1 Tag, wobei somit jeder Tag eine feste Ganzzahl zugewiesen bekommt, beginnend bei einem bestimmten Tag (meist 31.12.1899=Tag 1; manchmal ist es auch 01.01.1900 zB. im Excel-Arbeitsblatt).
Die Uhrzeiten innerhalb eines Tages werden als Bruchteile von 1 (=Tag) ausgedrückt, wobei, wie allgemein bekannt ist, gilt:
1 Tag = 24 Stunden = 1440 Minuten = 86400 Sekunden.
Somit wird die Uhrzeit 06:00:00 Uhr = 6/24 = 1/4 = 0,25 Tage
und die Uhrzeit 07:00:00 Uhr = 7/24 = 0,2916666... Tage
und die Differenz 07:00:00-06:00:00 = 7/24-6/24 = 1/24 (= 1 Stunde) = 0,041666... Tage

Die Formatierung, die in einem Datums/Uhrzeitfeld definiert ist, bewirkt, dass diese Tageszählung mit ihren Nachkommastellen in das gewünschte Anzeigeformat umgerechnet wird, obwohl intern weiterhin die vorhin beschriebene Tages/Uhrzeitzählung gespeichert bleibt.

 

danke für die Antwort, glaube aber, das ich mich falsch ausgedrückt habe.
Folgende Beispiele; Prämisse Mittagspause von 11:30 bis 12:00 Uhr

Zeitpunkt 1: 11:00
Zeitpunkt 2: 12:15
Ergebnis: 45 Minuten oder 0:45

Zeitpunkt 1: 11:00
Zeitpunkt 2: 11:45
Ergebnis: 30 Minuten oder 0:30

Besten Dank im voraus

 

Hallo,

in einem allgem. Codemodul folgendes VBA-Makro abspeichern:

Code:

Public Function NettoArbZeit(ArbZAnf As Date, ArbZEnd As Date, PausAnf As Date, PausEnd As Date) As Long
  Dim Zeit As Double
  Zeit = ArbZEnd - ArbZAnf
  If Zeit < 0 Then Zeit = Zeit + 1#
  If (ArbZEnd >= PausAnf) And (PausEnd >= ArbZAnf) Then
    Zeit = Zeit - IIf(ArbZEnd < PausEnd, ArbZEnd, PausEnd) + IIf(PausAnf > ArbZAnf, PausAnf, ArbZAnf)
  End If
  NettoArbZeit = Zeit * 24 * 60
End Function

dann kann in den Formeln folgende benutzerdefinierte Funktion verwendet werden:
NettoArbZeit(Arbeitszeitanfang;Arbeitszeitende;Pausenanfang;Pausenende)
wobei die 4 Argumente Arbeitszeitanfang...Pausenende Uhrzeit-Werte darstellen (entweder aus Datum/Uhrzeit-Felder einer Tabelle oder als Uhrzeit-Direktkonstante zB. #12:15#).
Die Funktion liefert die Arbeitzeit in Minuten abzüglich einer eventuell enthaltenen Pausenzeit zurück:
Deine beiden Beispiele im letzten Posting:
NettoArbZeit(#11:00#;#12:15#;#11:30#;#12:00#) ergibt 45 Minuten
NettoArbZeit(#11:00#;#11:45#;#11:30#;#12:00#) ergibt 30 Minuten