Office: Zelle Formel ODER Wert

Hallo,

ich suche schon länger nach einer Möglichkeit wie man dieses Problem lösen kann, aber irgendwie will es nicht klappen! Ich will in einer Zelle entweder eine Formel haben (z.B.: WVERWEIS) oder einen Wert selber eingeben (z.B.: 215).

Quasi, wenn ein Wert vorgegeben ist einfach eintippen und wenn nicht soll er anhand der Formel einen berechnen. Problem ist natürlich, wenn es einen Wert gibt und ich tippe diesen ein, wird die Formel gelöscht.

Scheinbar kann sowas gar nicht funktionieren, aber vllt. kennt jemand ja die Lösung!

Danke für die Hilfe!

 

Hallo,

das hast Du richtig erkannt. Aber es gibt eine gewisse Ersatzlösung:
Angenommen, es wäre die Zelle A1, in der beides Platz finden sollte: die Formel bzw. der Wert. So kannst Du für die Werteingabe ein Ausweichquartier suchen, zB. die Zelle B1: dort gibst Du den Wert ein - oder aber Du lässt die Zelle B1 leer, falls Du keinen Wert hast.
In der Zelle A1 steht dann eine WENN-Formel, die abfragt, ob in Zelle B1 ein Wert enthalten ist: Wenn ja, wird dieser genommen, sonst wird alternativ eine Formel ausgewertet:
Formel in A1: =WENN(ISTLEER(B1);3*5+7/5;B1)
(Statt "3*5+7/5" musst Du natürlich Deine Formel einsetzen)

 

Hallo,

danke für die schnelle Hilfe! Ja daran habe ich auch schon gedacht, aber leider würde das sehr unübersichtlich aussehen, da es sehr viele Zellen gibt auf die das angewendet werden müsste.

Über VBA gibt es da auch keine Möglichkeit oder? Kenne mich mit VBA noch nicht so aus, aber meistens hilft das doch wenn sonst nichts mehr geht :D

Danke für die Hilfe!

 

Hallo,

in der beiliegenden Excel-Datei habe ich im Codemodul des Arbeitsblattes "Tabelle1" eine VBA-Ereignisbehandlung für das Datenänderungsereignis eingebaut (Programm "Worksheet_Change") und zwar für die beiden Zellen A1 und B3.

1) Sobald in einer dieser beiden Zellen die "Entf"-Taste gedrückt wird und dadurch ihre momentanen Werte entfernt werden, wird automatisch die entsprechende Formel in der jeweiligen Zelle platziert und anschließend berechnet.
Andernfalls kann ein Wert in die beiden Zellen eingegeben werden.
2) Da VBA wissen muss, um welche Formeln es sich handelt, sind diese in VBA im Ereignisbehandlungsprogramm "Worksheet_Change" abzuspeichern. Und zwar muss für jede Zelle, die diese Spezialbehandlung erhalten soll, eine eigene Programmzeile eingefügt werden, so wie sie bereits für die beiden Musterzellen vorhanden sind.
3) Ich habe reichlich erklärenden Kommentar in den Makros beigefügt.

Code:

Option Explicit
'
'Im Bereich "Target" des aktuellen Arbeitsblattes wurde ein Datenänderungsereignis ausgelöst:
'
Private Sub Worksheet_Change(ByVal Target As Range)
'
  'Falls "Target" aus mehr als einer Zelle besteht, brich die Makroausführung ab!
  If Target.Cells.Count > 1 Then Exit Sub
'
  'Führe für die Zellen "A1" und "B3" die folgenden Subprogramme aus:
  Berechnung_Eingabe ZielZelle:=Target, BetreffZelle:=Range("A1"), ZellFormel:="=3*F1+18/WURZEL(K1)"
  Berechnung_Eingabe ZielZelle:=Target, BetreffZelle:=Range("B3"), ZellFormel:="=3,2*F3+9/(K3+L3)"
  'Hier noch weitere Zeilen einfügen, falls noch weitere Zellen dieser Art vorhanden sind.
  '......
  '......
'
End Sub
'
'ZielZelle:    enthält die Zelle, in der das Datenänderungsereignis stattgefunden hat.
'BetreffZelle: enthält die Zellangabe, für die die folgende Formel berechnet werden soll.
'ZellFormel:   enthält die Formel (in der lokalen Formelsprache), die eventuell in
'              der BetreffZelle gespeichert und berechnet werden soll.
'
Private Sub Berechnung_Eingabe(ZielZelle As Range, BetreffZelle As Range, ZellFormel As String)
  'Falls die Ereigniszelle "ZielZelle" nicht gleich der "BetreffZelle" ist,
  'dann brich dieses Unterprogramm ab:
  If Application.Intersect(ZielZelle, BetreffZelle) Is Nothing Then Exit Sub
  'Falls die Ereigniszelle "ZielZelle" leer ist:
  If IsEmpty(ZielZelle.Value) Then
    'Verhindere, dass durch die nachfolgende Berechnung der Formel
    'weitere Ereignisse ausgelöst werden. Dadurch kann dann kein Endloszirkel beim
    'Aufruf von "Worksheet_Change" entstehen - ein solcher hätte schlussendlich
    'den Absturz des Makros zur Folge.
    Application.EnableEvents = False
    'Stelle die Formel (in der lokalen Excel-Sprache, zB. deutsch) in die Ereigniszelle
    ZielZelle.FormulaLocal = ZellFormel
    'Berechne die Formel dieser Zelle
    ZielZelle.Calculate
    'Ereignisbehandlung/verarbeitung wieder einschalten:
    Application.EnableEvents = True
  End If
End Sub

4) Erreichbar ist der Code aus dem Arbeitsblatt heraus durch die Tastenkombination Alt+F11. Mit dieser Tastenkombination gelangt man auch wieder ins Arbeitsblatt zurück.