Office: Zellen kopieren - kleine Hilfestellung

Moinsen Allerseits!
Ich habe bei einem "versiertem Excel-Mensch" folgenden Code gefunden:

Zellbereich kopieren

(Auf diesem Weg danke für die umfangreichen Tipps und Beispiele Herr Ziplies!)

So,
nun kopiert der Code die Zelle komplett, mit den darin befindlichen Formeln...
Der Code den ich benötige soll allerdings nur den Zellinhalt bzw. die Werte aus diesen Zellen kopieren,
also nur das was die Formel selbst vor dem kopieren ermittelt hat...

Da ich in VBA so ziemlich nichts kann und froh bin das ich es selbst geschafft hab die Bezüge auf meinen Krempel zu ändern, wäre ich über eine kleine Hilfestellung eurerseits sehr, sehr, sehr froh...

Zu der oben verlinkten Datei hier auch nochmal der Code "zu Fuss":

Code:

Option Explicit                 ' Variablendefinition erforderlich

Private Sub Worksheet_Change(ByVal Target As Range)
    '**************************************************
    '* H. Ziplies                                     *
    '* 27.08.06                                       *
    '* erstellt von [email]HajoZiplies@web.de[/email]                *
    '* [url]http://Hajo-Excel.de/[/url]                          *
    '**************************************************
    Dim RaBereich As Range, RaZelle As Range            ' Variable für Bereich und aktuelle Zelle
    Dim LoLetzte As Long                                            ' Variable für letzte Zeile
    Set RaBereich = Range("Z:Z")                               ' Bereich der Wirksamkeit
    Set RaBereich = Intersect(RaBereich, Range(Target.Address))     ' geänderte Zellen, die im überwachten Bereich liegen, auf die Variable schreiben
    If Not RaBereich Is Nothing Then                           ' falls Variable belegt Prozedur ausführen
        For Each RaZelle In RaBereich                           ' Schleife über alle veränderten Zellen im üerwachten Bereich
            If UCase(RaZelle) = "R1T" Then                     ' zum Vergleich Eingabe in Großbuchstaben umwandeln
                With Worksheets("Tabelle1")
                    LoLetzte = .UsedRange.SpecialCells(xlCellTypeLastCell).Row + 1          ' letzte Zeile in Tabellle2 feststellen + 1
                    Range("P" & RaZelle.Row & ":Y" & RaZelle.Row).Copy .Cells(LoLetzte, 1)  ' Zellbereich kopieren
                End With
            End If
        Next RaZelle
    End If
    Set RaBereich = Nothing                                    ' Variable leeren
End Sub

MfG,
Ijoohn

 

Code:

Option Explicit                                                 ' Variablendefinition erforderlich

Private Sub Worksheet_Change(ByVal Target As Range)
    '**************************************************
    '* H. Ziplies                                     *
    '* 26.06.10                                       *
    '* erstellt von [email]HajoZiplies@web.de[/email]                *
    '* [url]http://Hajo-Excel.de/[/url]                          *
    '**************************************************
    Dim RaBereich As Range, RaZelle As Range                    ' Variable für Bereich und aktuelle Zelle
    Dim LoLetzte As Long                                        ' Variable für letzte Zeile
    Set RaBereich = Range("Z:Z")                                ' Bereich der Wirksamkeit
    Set RaBereich = Intersect(RaBereich, Range(Target.Address)) ' geänderte Zellen, die im überwachten Bereich liegen, auf die Variable schreiben
    If Not RaBereich Is Nothing Then                            ' falls Variable belegt Prozedur ausführen
        For Each RaZelle In RaBereich                           ' Schleife über alle veränderten Zellen im üerwachten Bereich
            If UCase(RaZelle) = "R1T" Then                      ' zum Vergleich Eingabe in Großbuchstaben umwandeln
                With Worksheets("Tabelle1")
                    LoLetzte = .UsedRange.SpecialCells(xlCellTypeLastCell).Row + 1      ' letzte Zeile in Tabellle2 feststellen + 1
                    Range("P" & RaZelle.Row & ":Y" & RaZelle.Row).Copy
                    .Cells(LoLetzte, 1).PasteSpecial Paste:=xlValues                    ' Werte
                End With
            End If
        Next RaZelle
        Application.CutCopyMode = False
    End If
    Set RaBereich = Nothing                                                             ' Variable leeren
End Sub