Office: Zellen verknüpfen

Helfe beim Thema Zellen verknüpfen in Microsoft Excel Hilfe um das Problem gemeinsam zu lösen; Hallo zusammen, könnt ihr mir bitte weiterhelfen? Ich würde gerne eine Zelle vom Tabellenblatt 1 mit der Zelle vom Tabellenblatt 2 verknüpfen.... Dieses Thema im Forum "Microsoft Excel Hilfe" wurde erstellt von Marcus1040, 9. September 2022.

  1. Marcus1040 Neuer User

    Zellen verknüpfen


    Hallo zusammen,

    könnt ihr mir bitte weiterhelfen?
    Ich würde gerne eine Zelle vom Tabellenblatt 1 mit der Zelle vom Tabellenblatt 2 verknüpfen.
    Hierbei soll sich beim Eintrag in der Zelle 1, von der Tabelle 1, der Wert in der Tabelle 2, Zelle 1 automatisch ersetzen und genau so andersrum. Quasi soll der Wert immer gleich sein, egal in welcher Zelle ich einen Eintrag tätige. Vielen Dank im Voraus.
     
    Marcus1040, 9. September 2022
    #1
  2. Exl121150 Erfahrener User
    Hallo Marcus,

    diese Anforderung an Excel ist mit Arbeitsblatt-Funktionen nicht erfüllbar, denn das läuft präzise auf eine Zirkelbezug hinaus.

    Aber mit einer Programmierung in VBA ist es durchaus möglich, nur müsste man dazu genauere Angaben bekommen, wie die Arbeitsblätter heißen und um welche Zellen es sich in diesen handelt.

    Darüber hinaus ergibt sich hier eine grundsätzliche Frage: Wozu soll das gut sein, eine Verdopplung der Daten?
     
    Exl121150, 9. September 2022
    #2
  3. Marcus1040 Neuer User
    Hi Anton,

    das klingt gut.
    Arbeitsblatt 1 = BMA, für alle Zellen der Spalte T:T
    Arbeitsblatt 2 = KFM, für alle Zellen der Spalte W:W

    In dem jeweiligen Tabellenblatt soll von nur einer Person gearbeitet werden.
    Vielen Dank schon mal.
    Grüße Marcus
     
    Marcus1040, 12. September 2022
    #3
  4. Exl121150 Erfahrener User

    Zellen verknüpfen

    Hallo,

    in der beiliegenden Excel-Arbeitsmappe habe ich dir im Codemodul der Arbeitsmappe ein Makro eingefügt, das auf Datenänderungen in den Arbeitsblättern BMA bzw. KFM reagiert, sofern diese Datenänderung in den Spalten T bzw. W stattfand.

    Es können einzelne Zellen geändert werden, wobei die Änderung in der entsprechenden Zelle des anderen Arbeitsblattes ebenfalls erfolgt. Es können auch mehrere Zellen (Zellbereich) gleichzeitig geändert werden, sofern sie in 1 Spalte liegen.
    Allerdings sind Bereiche, die sich mit besagten Spalten überlappen (also nicht bloß enthalten sind), nicht erlaubt - ein Meldungsfenster ist die Folge.
    Das Makro sieht wie folgt aus:
    Code:
    Option Explicit
    
    Private Sub Workbook_SheetChange(ByVal Sh As Object, ByVal Target As Range)
      Dim WsAkt As Worksheet, RgAkt As Range
      Dim WsAlt As Worksheet, RgAlt As Range
     
      'Überprüfen des Sh-Arbeitsblattes:
      'Falls Sh nicht "BMA" bzw. "KFM", dann exit
      'Festlegen der Spalten T bzw. W
      Set WsAkt = Sh
      If WsAkt.Name = "BMA" Then
         Set WsAlt = Worksheets("KFM")
         Set RgAkt = WsAkt.Range("T:T"): Set RgAlt = WsAlt.Range("W:W")
      ElseIf WsAkt.Name = "KFM" Then
         Set WsAlt = Worksheets("BMA")
         Set RgAkt = WsAkt.Range("W:W"): Set RgAlt = WsAlt.Range("T:T")
      Else
         Exit Sub
      End If
     
      'Überprüfen des Target-Bereiches:
      'Falls nicht im RgAkt bzw. nicht einspaltig, dann exit (eventuell Meldung)
      If Intersect(Target, RgAkt) Is Nothing Then Exit Sub
      If Target.Columns.Count > 1 Then
         MsgBox Prompt:="Geänderter Bereich: " & Target.Address & vbNewLine & _
                        "Nur 1 Spalte ist erlaubt!", _
                Buttons:=vbCritical, Title:="Unerlaubter Bereich"
         Exit Sub
      End If
     
      On Error GoTo WsShChange         'Falls im Folgenden ein Fehler auftritt
      Application.EnableEvents = False 'Deaktivieren Excel-Events
     
      RgAkt.Copy Destination:=RgAlt    'Kopieren Quellspalte in Zielspalte
      Target.Range("A1").Select        'Auswahl-Bereich auf 1 Zelle schrumpfen
    
    WsShChange:
      Application.EnableEvents = True  'Reaktivieren Excel-Events
    End Sub
    
     
    Zuletzt bearbeitet: 12. September 2022
    Exl121150, 12. September 2022
    #4
  5. Marcus1040 Neuer User
    Hi Anton,

    ich hätte doch noch mal einen Änderungswunsch.
    In T soll es erst in der dritten Spalte losgehen und in W in der zweiten.
    Könntest du das noch mal anpassen?

    Grüße Marcus
     
    Marcus1040, 15. September 2022
    #5
  6. Exl121150 Erfahrener User
    Hallo,

    du meinst wohl Zeile statt Spalte (zumindest wenn man nach dem allgem. Sprachgebrauch im Deutschen geht).

    Aber dann ergibt sich ein grundsätzliches Problem: Wenn in Spalte W bereits in der 2. Zeile (also ab Zelle W2) etwas eingegeben werden darf, das dann natürlich in Zelle T2 erscheint, dort aber erst ab der 3. Zeile etwas eingegeben werden darf. Was soll da dann mit Zelle T2 passieren?
     
    Exl121150, 16. September 2022
    #6
  7. Marcus1040 Neuer User
    Hi, sorry verwechselt.
    Dann ab W3 und T3
     
    Marcus1040, 26. September 2022
    #7
  8. Exl121150 Erfahrener User

    Zellen verknüpfen

    Hallo,

    ich habe folgende VBA-Zeile eingefügt:
    If Target.Row < 3 Then Exit Sub

    Geänderte Datei liegt bei.
     
    Exl121150, 26. September 2022
    #8
  9. Marcus1040 Neuer User
    Hi Anton,

    funktioniert super. Vielen Dank.
     
    Marcus1040, 27. September 2022
    #9
Thema:

Zellen verknüpfen

Die Seite wird geladen...
  1. Zellen verknüpfen - Similar Threads - Zellen verknüpfen

  2. Zellen Verknüpfung fehlerhaft

    in Microsoft Excel Hilfe
    Zellen Verknüpfung fehlerhaft: Guten Morgen liebe Community! Wie man auf dem Bild sehen kann, habe ich ein Problem mit dem Verknüpfen von einer Zelle in der gleichen Arbeitsmappe! Ich würde gerne die Tabelle TN-Liste1!$B6$ mit...
  3. Bild mit Text aus Zelle verknüpfen

    in Microsoft Excel Hilfe
    Bild mit Text aus Zelle verknüpfen: Guten Tag Ihr Lieben Ich würde gerne mal wieder auf Eure hochgeschätzte Hilfe zugreifen. Ich habe eine Datei in dem ich ALLE Puzzles (ca. 250 Stück ) meiner Frau eingegeben habe. Das habe ich im...
  4. Anzeigen von Verknüpfungen zwischen Zellen

    in Microsoft Excel Tutorials
    Anzeigen von Verknüpfungen zwischen Zellen: Anzeigen von Verknüpfungen zwischen Zellen Excel für Microsoft 365 Excel 2019 Excel 2016 Excel 2013 Office Business Mehr... Weniger...
  5. Bedingte Formatierung: UND-Verknüpfung einer leeren und einer nicht leeren Zelle

    in Microsoft Excel Hilfe
    Bedingte Formatierung: UND-Verknüpfung einer leeren und einer nicht leeren Zelle: Hallo meine Lieben Ich stehe auf dem Schlauch und brauche Hilfe. Vermutlich ist die Antwort für einen Aussenstehenden ganz simpel... Ich möchte eine Zeile einfärben (nur dann) wenn in dieser...
  6. Office 2019: Bedingte Formatierung, mehrere Zellen verknüpfen

    in Microsoft Excel Hilfe
    Office 2019: Bedingte Formatierung, mehrere Zellen verknüpfen: Hallo, ich habe ein kleines Problem und komme aktuell nicht weiter. Meine Excel Tabelle sieht wie folgt aus: 15 Spalten (A->O) 30 Zeilen (1->30) Ich möchte pro Zeile, die Spalte N (14) rot...
  7. mehrere Bilder zu 1 Zelle verknüpfen

    in Microsoft Excel Hilfe
    mehrere Bilder zu 1 Zelle verknüpfen: Liebe Forumsuser, ich stehe vor einem großen Problem: ich habe in einer Zelle einen Wert stehen, für den als "Beweis" ein oder mehrere Bilder mit dieser Zelle verknüpft werden sollen - und bei...
  8. Inhalt mehrerer Zellen mittels Matrixformel verknüpfen

    in Microsoft Excel Hilfe
    Inhalt mehrerer Zellen mittels Matrixformel verknüpfen: Hallo, ich habe zwei Tabellen. Die erste hat drei Spalten: A_Startdatum - B_Enddatum - C_Ereignis (Text) 03.04.2017 - 17.04.2017 - Beispielereignis1 02.11.2017 - 11.11.2017 - Beispielereignis2...
  1. Diese Seite verwendet Cookies, um Inhalte zu personalisieren, diese deiner Erfahrung anzupassen und dich nach der Registrierung angemeldet zu halten.
    Auf dieser Website werden Cookies für die Zugriffsanalyse und Anzeigenmessung verwendet.
    Wenn du dich weiterhin auf dieser Seite aufhältst, akzeptierst du unseren Einsatz von Cookies.
    Information ausblenden