Office: (Office 2010) Zellinhalt als Wert einfügen (VBA)

Hallo zusammen,

ich habe wieder einmal ein kleines Makro-Problem, bei dem ihr mir sicher helfen könnt.

Ich habe schon im Netz geschaut, aber alle dort vorgeschlagenen Lösungen wollen bei mir nicht so richtig funktionieren … vielleicht steht bei mir auch nur jemand auf dem Schlauch …

Ich möchte eine Zelle kopieren und deren Inhalt als Wert in eine andere Zelle oder einen anderen Bereich einfügen.

Also Zelle über „Strg + C“ kopieren, eine andere Zelle (oder Bereich) markieren, Makro ausführen, fertig

Ich habe dafür das Makro so angelegt:

Sub Werte_einfügen()
Selection.PasteSpecial Paste:=xlPasteValues, operation:=xlNone
End Sub

Leider erscheint bei mir da immer:

Laufzeitfehler „1004“
Die PasteSpecial-Methode des Range-Objektes konnte nicht ausgeführt werden.

Mit dieser Meldung kann ich nicht wirklich etwas anfangen.

Kann mir jemand sagen, was ich falsche mache?

VG Micha

 

Hi Micha,

vom Prinzip her so:

Code:

Sub Werte_kopieren_einfügen()
    Range("C2:E5").Copy
    Range("F25").PasteSpecial Paste:=xlValues
End Sub

Kopiert wird C2:E5 und eingefügt werden die Werte ab F25.

---

 

Hallo Micha,

du wirst wahrscheinlich das Makro mittels Tastenkombination Alt+F8 ausgewählt und ausgeführt haben
oder was dasselbe ist mittels Button "Makros" aus den Entwicklertools.

Das bewirkt leider, dass die zuvor ausgeführte Kopie in die Zwischenablage verloren geht. Du siehst das auch, dass der Laufrahmen um den Quellbereich verschwindet. In der weiteren Folge hat Excel nichts mehr, was es im Zielbereich einfügen könnte und bringt die etwas irreführende Fehlermeldung.

Um keinen Quellbereich im Makro angeben zu müssen, gibt es 3 Möglichkeiten:
1) Du drückst die Tastenkombination Alt+F11 (VBA-Editor) und dann dort die Taste F5 mit anschließendem Button "Ausführen"
oder
2) Du legst im Arbeitsblatt eine Schaltfläche an und verknüpfst diese mit deinem Makro. Dann kannst du die Schaltfläche anklicken, um die Zwischenablage an beliebig vielen Zielorten des Arbeitsblattes einzufügen.
oder
3) Die Symbolleiste für den Schnellzugriff anpassen, sprich erweitern um den Makro-Befehl "Werte_einfügen".

 

Vielen Dank für Eure Antwort ...

@ Karin: Dein Vorschlag ist ist nicht, dass was ich mir vorgestellt habe. Vielleicht habe ich mich etwas umständlich ausgedrückt.

* Ich möchte einen beliebigen Wert kopieren (beispielsweise schreibe ich in B1 den Wert 10)
* Dann möchte ich einen beliebigen Bereich markieren (beispielsweise B2:B5)
* Dann ein Makro ausführen, was mir den Wert (der sich sicherlich gerade in der Zwischenablage befindet) nimmt und in den gerade markierten Bereich als Wert einfügt (am Ende soll also im Bereich B2:B5 der Wert 10 stehen)

@ Anton: Ich hatte vor, das Makro mittels Schaltfläche in der gleichen Arbeitsmappe zu starten. Bedeutet das, das funktioniert nur nicht, weil ich auf "Makros ausführen" gegangen bin. Wenn ich das über eine Schaltfläche starte klappt es?
- Kann es leider nur gerade nicht starten, da ich vom Tablet aus schreibe -

VG Micha

 

Hallo,

1) Ja, das heißt es.
2) Du kannst es auch über eine zusätzlich angelegte Schaltfläche/Option in der Schnellzugriffsleiste ausführen - dann brauchst du keine extra Schaltfläche anzulegen im Arbeitsblatt (wie im folgenden Ausschnitt in der rechten unteren Ecke zu sehen):

 

@ Anton: Danke Dir ... ich teste das morgen mal auf Arbeit und sag bescheid, ob es geklappt hat

PS: Wie kriegst Du die Schnellzugriffleiste unter das Menüband?

 

Hi Micha,

2 Schaltflächen mit folgenden 2 Makros verknüpfen:

Code:

Sub Kopieren()
    Selection.Copy
End Sub

Sub Einfuegen()
    Selection.PasteSpecial Paste:=xlValues
End Sub

---

 

Hallo Micha

Die Schnellzugriffsleiste kann an 2 Stellen positioniert werden:
1) Über dem Menüband in der Excel-Kopfzeile, wo bei mir das Speichern-Icon zu sehen ist.
2) Unter dem Menüband, wie in meinem Fall.

Am einfachsten ist die Positionierung umzustellen, wenn du auf das DropDown-Symbol am Ende der Zugriffsleiste klickst, sodass die enthaltene Befehlsliste angezeigt wird. Dort gibt es dann den Befehl "Unter dem Menüband anzeigen", wenn sich die Leiste über dem Menüband befindet, bzw. den Befehl "Über dem Menüband anzeigen", wenn sich die Leiste unter dem Menüband befindet.

Falls bei dir die Schnellzugriffsleiste überhaupt nicht angezeigt wird, so kann man sie über die Excel-Optionen (Symbolleiste für den Schnellzugriff) einblenden:
Häkchen in der Checkbox "Symbolleiste für den Schnellzugriff anzeigen". Dort kann man ebenfalls die Positionierung angeben und ob die Befehlsbezeichnungen angezeigt werden sollen.

 

Hallo Anton,

ich habe es gerade getestet und es funktioniert.

Vielen Dank für Deine Hilfe

 

Moin!
Es gibt noch eine andere Möglichkeit:
Zuweisung einer Tastenkombination.
Ich habe (da ich das häufig brauche) ein Makro in der Personal.xlsb abgelegt und ihm die Tastenkombi Strg+Umschalt+W zugewiesen.

Code:

Sub FormelInWert()
'Shortcut Strg+Umschalt+W
Dim x As Range
If TypeName(Selection) = "Range" Then
  With Application
     .ScreenUpdating = False
     For Each x In .Selection.Areas
        If x.HasSpill Then
          With x.SpillParent.SpillingToRange
            .Copy: .PasteSpecial xlPasteValues
          End With
        Else
          x.Copy: x.PasteSpecial xlPasteValues
        End If
     Next
     .CutCopyMode = False
     .Goto ActiveCell
  End With
End If
End Sub

Beachte, dass der "Spill"-Block ausschließlich in Excel 365 und 2021 funktioniert.

Gruß Ralf

 

Hallo Ralf,

Danke für den Hinweis auf die .hasSpill / .SpillParent / .SpillingToRange - Properties des Range-Objektes. Man kann gespannt sein, wie die Eigenschaften ausschauen, wenn sie in die offizielle Hilfe zum Range-Objekt integriert werden
Range.SpillParent property (Excel) | Microsoft Docs
Für @msdd79 stellt es ja noch keine verwendbare Option dar (wegen Excel2010).

Aber abgesehen davon stellt das Ansprechen des Makros mit Tasten-ShortCuts (zB.: Strg+Umschalt+W) eine weitere Möglichkeit dar:
Er müsste im Codemodul "DieseArbeitsmappe" folgende 2 Makros einfügen:

Code:

Option Explicit
Private Sub Workbook_Open()
   'Shortcut Strg+Umschalt+W
  Application.OnKey "^+W", "Werte_einfügen"
End Sub

Private Sub Workbook_BeforeClose(Cancel As Boolean)
  'Shortcut Strg+Umschalt+W: Aufheben
  Application.OnKey "^+W"
End Sub