Office: Zellwert in Abhängigkeit eines anderen Zellwertes tauschen

Hallo,
ich habe eine Excel Tabelle, bei der in Spalte A bestimmte Ausdrücke stehen (Bsp. Verschiedene) in Spalte B in der gleichen Zeile dazugehörige Produktbezeichnungen (Bsp. Azic).
Ich möchte jetzt nach allen Zeilen suchen in denen z.B. "Verschiedene" steht und den Inhalt der Zelle in A mit dem Inhalt der Zelle B in der jeweiligen Zeile überschreiben.
Am günstigsten wäre ein Array, bei dem man verschiedene Ausdrücke in Spalte A definieren kann, bei dem dann das obige durchgeführt werden soll.

Kann mir bitte jemand helfen?
Danke und schönes WE.
Alexander

 

Hallo Alexander,

mit etwas mehr Informationen gerne.

 

Ich lade mal eine Beispiel Datei hoch, dann wird das vielleicht verständlicher.
Dies ist ein Ausschnitt der Originaltabelle, die größer ist und auch weitere Begriffe enthält, die entsprechend bearbeitet werden sollen.
Im orange markierten Bereich stehen in Spalte A die zu suchenden Begriffe. In den Zeilen in denen "Kombinationen" in Spalte A steht, soll der Begriff Kombinationen mit dem Begriff getauscht werden der in der entsprechenden Zeile in Spalte B steht.
Ich hoffe, ich konnte es einigermaßen erklären, was ich möchte.

 

So soll die Zeile nach Bearbeitung aussehen. In derselben Zeile.

 

Klasse Datei ophne Daten.

 

Ich verstehe nicht, bei mir sind die Daten da? Oder was meinst du genau? Ich habe die Test Datei herunter geladen und sehe 34 Zeilen mit 3 Spalten....

 

Die Datei Aussehen beschreibt nur optisch wie die Zeile 1 nach Bearbeitung aussehen soll. So wie in Zeile B. Vielleicht als Bild besser verständlich.

 

Gut dann habe ich es wohl falsch verstanden das Daten bearbeitet werde sollen. Leere Zellen sind keine Daten fürr mich.
Ich bin dann raus da Aufgabe falsch verstanden.

Gruß Hajo

 

Danke dir trotzdem

 

Hallo,

ich habe dir folgendes VBA-Makro in ein allgemeines Code-Modul gespeichert:

Code:

Option Explicit

Public Sub TauschenAB()
  Dim Ws As Worksheet
  Dim rngABC As Range, rngZl As Range
  Dim zwi As Variant, SuchWert As Variant
 
  'Zu suchender Wert aus Spalte A eingeben
  SuchWert = InputBox(Prompt:="Suchbegriff aus Spalte A", Title:="Tauschbegriff eingeben", Default:="Kombinationen")
 
  'Falls es ein Leerwert ist oder auf Button "Abbrechen" geklickt wurde:
  If Len(SuchWert) = 0 Then Exit Sub
 
  Set Ws = ActiveSheet
  Set rngABC = Ws.Range("A1").CurrentRegion  'Zelle A1 muss im Bereich enthalten sein -- sonst anpassen!!
 
  For Each rngZl In rngABC.Rows              'Für alle Zeilen des Bereiches tue Folgendes:
    With rngZl
      If .Cells(1).Value = SuchWert Then  'Falls in Spalte A der Suchwert steht:
        zwi = .Cells(1).Value             'Speichere diesen zwischen
        .Cells(1).Value = .Cells(2).Value 'Speichere den Wert aus Spalte B in Spalte A
        .Cells(2).Value = zwi             'Speichere zwischengepeicherten Wert in Spalte B
      End If
    End With
  Next rngZl

End Sub

Ferner habe ich dir einen blauen Button "Spalten A+B tauschen" eingefügt und diesen mit dem obigen Makro verknüpft.

Betätigst du den Button, erscheint eine InputBox. In dieser wird bereits der Suchbegriff "Kombinationen" vorgeschlagen. Diesen kannst du auch übertippen und durch einen anderen Begriff ersetzen.
Mit Klick auf Button "OK" wird die Suche in Spalte A durchgeführt und die Vertauschungen ausgeführt.
Mit Klick auf Button "Abbrechen" wird das Makro sofort beendet.

Das Makro setzt voraus, dass die Zelle A1 im fraglichen Suchbereich enthalten ist. Sonst müsstest du diese Zelle anpassen und durch eine im Bereich enthaltene Zelle ersetzen.

Modifizierte Datei samt Makro liegt bei.

 

Prima, danke Dir funktioniert bestens.
Schönes WE
Alexander