Office: (Office 2007) Zufallsgenerator für Turnierauslosung

Hergado · 3. November 2014

Hallo zusammen,

bin neu hier *Smilie und habe folgendes Problem:

Für ein privat veranstaltetes Fußballturnier (32 Teams in 8 Gruppen á 4 Teams) benötige ich eine Möglichkeit via Excel die Auslosung vorzunehmen.

Ich vermute, so wie ich es mir vorstelle, ist es nur mit Programmierung möglich:

- Es gibt 32 Teams, die in "Tabelle 1" in Spalte A untereinander stehen
- In "Tabelle 2" erstelle ich einen Gruppenbaum mit den 8 Gruppen.

- Nun möchte ich auf einen Button drücken und das erste zufällig generierte Team erscheint.
- Dann möchte ich wieder auf einen Button drücken und das zufällig generierte Team wird automatisch an eine zufällige Position in den Gruppenbaum eingefügt (zB in Gruppe D an 3. Stelle)
- Idealerweis wird das zuletzt zugeloste Team in der Tabelle farblich markiert.

Im Prinzip muss ich also 64 mal den Butto drücken bis die Tabelle gefüllt ist.

Ich habe mal eine Beispieltabelle angefügt und hoffe, dass meine Erklärungen verständlich sind.

Wenn jemand andere/besser Ideen hat, immer her damit *wink.gif*

Kann mir jemand helfen?

:)

aloys78 · 5. November 2014

Hallo,

aus meiner Sicht reicht es aus, den Button nur einmal zu drücken; das andere läuft dann automatisch ab.
Zuerst wird nach dem Zufallsprinzip die Reihenfolge der 32 Mannschaften festgelegt. In einem 2. Lauf werden dann die Teams auf zufällig ermittelte Plätze verteilt.

Gruß
Aloys

Hergado · 5. November 2014

Wie bereits gesagt; die Teams sollen einzeln gezogen und den Gruppen zugeordnet werden.

Man muss dazu wissen: Die Auslosung erfolgt "live" und so ist es spannender, ähnlich wie bei der Champions League Ausloung im Fernsehen.

aloys78 · 5. November 2014

Hallo,

anbei mein Vorschlag.
Mit dem Button in Tabelle 1 kann alles in Grundstellung gesetzt werden.

Gruß
Aloys

aloys78 · 5. November 2014

Hallo,

anbei eine neue Version, bei der neben kleinen Änderungen eine erweiterte Dokumentation enthalten ist.

Gruß
Aloys

Hergado · 5. November 2014

Hallo aloys,

vielen Dank! Gefällt mir sehr gut *wink.gif*

Nur, warum sind während der Auslosung manche Teams gelb hinterlegt und andere nicht?

aloys78 · 5. November 2014

Hallo,

Nur, warum sind während der Auslosung manche Teams gelb hinterlegt und andere nicht?
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Das liegt an deiner Aufgabenstellung:

Idealerweis wird das zuletzt zugeloste Team in der Tabelle farblich markiert.
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Und das habe ich so interpretiert, dass das zuletzt in eine Gruppe ausgeloste Team farbig zu markieren ist.

Aber - die Markierung zu entfernen, gehört zu den leichteren Übungen.

Gruß
Aloys

Hergado · 5. November 2014

Ok, sorry, dann habe ich mich falsch ausgedrückt.

Wenn das 1. Team einer Gruppe zugelost wird, soll es in der Gruppe markiert sein.

Wenn das 2. Team einer Gruppe zugelost wird, soll die Markierung vom 1. Team verschwinden und das 2. Team soll markiert sein.

Das ganze dient der Übersichtlichkeit. Wenn schon 23 Teams zugelost worden kann man so auf einen Blick erkennen wo genau das 24. Team hingelost wurde.

Vielen Dank jedenfalls schonmal für deine Mühe. Habe mir das ansonsten genau so vorgestellt wie du es gelöst hast!

aloys78 · 6. November 2014

Hallo,

Wenn schon 23 Teams zugelost worden kann man so auf einen Blick erkennen wo genau das 24. Team hingelost wurde
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Ich denke, der neue Code für Tabelle2 deckt jetzt auch diese Anforderung ab.

Gruß
Aloys
Code:

Option Explicit

'Version 3 vom 06.10.2014

Sub Teams_verteilen()
'===========================================================================
' Teams auf Gruppen verteilen
' - Teams nacheinander nach dem Zufallsprinzip auswählen, und
' - nach dem Zufallspronzip auf 8 Gruppen aufteilen
' - das jeweils aktuell ausgewählte Team wird farblich markiert
'
' Für Testzwecke sind Anzeigen verschiedener Werte in Tabelle2
' vorgesehen. Diese Anzeige wird über die Bedingte Kompilierung
' im VB Editot unter Extras / Eigenschaften von VBA-Projekt /
' Argumente für Bedingte Compilierung gesteuert.
' Test = 1 bedeutet Anzeige, Test = 0 keine Anzeige
'===========================================================================

Dim a1 As Integer 'Index Arrays
Dim s As Integer 'Startzeile
Dim z As Long 'Zeilen#
Dim sw As Boolean 'Schalter für das Einfärben des jeweils letzten Teams
Dim r As Long 'Zeilen# Zielposition
Dim c As Long 'Spalten Zielposition
Dim g As Integer 'Gruppen# (1 - 8)
Dim p As Integer 'Position in der Gruppe (1 - 4)
Dim i As Integer
Dim ws1 As Worksheet 'Tabelle1: enthält die Teams
Dim ws2 As Worksheet 'Tabelle2: enthält das Ergebnsi

'===========================================================================
' Tab-Blätter zuordnen
'===========================================================================
Set ws1 = Worksheets("Tabelle1") 'Teams
Set ws2 = Worksheets("Tabelle2") 'Ergebnis der Auslosung

'===========================================================================
' Aufbau der Arrays beim 1.Aufruf
' - Zufallsverteilung der Teams (lfd. Nr) in arr1 speichern
' - Zufallsverteilung auf die Gruppen über lfd. Nummer in arr2 speichern
' - für jedes Team in arr1 ergibt sich die Gruppenzuordnung aus
' der korrespondiierenden Position in arr2
'===========================================================================
If pAnz = 0 Then 'der erste Aufruf durch den CommandButton
Zufall fFeld:=arr1 'zufällige Reihenfolge der Teams in arr1 speichern

'Anzeige arr1 nur im Teststatus
#If Test = 1 Then
For i = 1 To UBound(arr1)
ws2.Cells(i, "L") = arr1(i)
Next i
#End If

Zufall fFeld:=arr2 'Zufallsverteilung auf die Gruppen festlegen

'Anzeige arr2 nur im Teststatus
#If Test = 1 Then
For i = 1 To UBound(arr2)
ws2.Cells(i, "M") = arr2(i)
Next i
#End If
End If

'===========================================================================
' Verarbeitung entsprechend Zyklus
' Für die Verteilung eines Teams gibt es 2 Zyklen entsprechend Auslösen
' des CommandButtons:
' Zyklus 1: Schalter pZykus=False
' - das nächtse Team wird über arr1 ausgewählt und in Tabelle1!B3
' angezeigt
' - pZyklus wird auf True gesetzt
' Zyklus 2: Schalter pZyklus=True
'===========================================================================
Select Case pZyklus
Case Is = False 'es ist ein Team auszuwählen
pAnz = pAnz + 1 'index für arr1 updaten
If pAnz > 32 Then Exit Sub 'alle Teams sind schon zugewiesen
ws2.Range("B3") = ws1.Cells(arr1(pAnz), "A") 'das ausgewählte Team wird angezeigt
pZyklus = True

Case Is = True 'das Team ist auf eine Gruppe zu verteilen
a1 = pAnz 'der aktuelle für arr1

'ermittle Gruppe und Position innerhalb der Gruppe
g = Int((arr2(a1) - 1) / 4) + 1 'Gruppen-Nr (1 - 8)
p = ((arr2(a1) - 1) Mod 4) + 1 'Position innerhalb der Gruppe (1 - 4)

'Berechnung der Ziel-Spalte
c = IIf(g < 5, g, g - 4) 'untere Gruppenreihe wie obere behandeln
c = c * 2 + 2 'Nr der Ziel-Spalte

'Berechnung der Ziel-Zeile
r = IIf(g < 5, 2, 9) 'Increment für untere und obere Gruppenreihe festlegen
r = r + p 'Zeilen# in Ziel-Gruppe

'Team in Gruppe einfügen
With ws2
.Cells(r, c) = .Range("B3") 'Name des Teams

'Markiere den aktuellen Zugang, lösche vorhergehende Markierung
.Range("D3:J6").Interior.ColorIndex = xlNone
.Range("D10:J13").Interior.ColorIndex = xlNone
.Cells(r, c).Interior.ColorIndex = 6 'der aktuelle Zugang wird markiert

'Grundstellung von Daten
.Range("B3") = ""
End With
pZyklus = False

'Nach Zuteilung aller Teams wird Nachricht ausgegeben
If pAnz = 32 Then
MsgBox "Die Turnierauslosung ist abgeschlossen !", vbInformation
ws2.Cells(r, c).Interior.ColorIndex = xlNone 'die Markierung des letzten Zugangs wird aufgehoebn
Exit Sub
End If

'Anzeige arr2 nur im Teststatus
#If Test = 1 Then
With ws2
Range("O" & a1) = g 'Gruppen-Nr
Range("P" & a1) = p 'Position innerhalb der Gruppe
Range("R" & a1) = r 'Zeilen#
Range("S" & a1) = c 'Spalten#
End With
#End If
End Select
End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Hergado · 6. November 2014

PERFEKT! Danke *Smilie

Office: (Office 2007) Zufallsgenerator für Turnierauslosung

Zufallsgenerator für Turnierauslosung

Zufallsgenerator für Turnierauslosung

Zufallsgenerator für Turnierauslosung

Zufallsgenerator für Turnierauslosung

Zufallsgenerator für Turnierauslosung - Similar Threads - Zufallsgenerator Turnierauslosung

Teambuilding mit Zufallsgenerator

Gruppen mit Zufallsgenerator auslosen

Zufallsgenerator ohne Wiederholung und Dokumentation

Gruppeneinteilung: Zufallsgenerator ohne Wiederholung

Gewichteter "Zufallsgenerator"

Zufallsgenerator

Problem beim Erstellen eines Zufallsgenerators