Office: Zuviele Datenpunkte im Diagramm

Hallo!

Ich meine mich erinnern zu können, dass es bei Excel2007 einen Bug gibt, was den Import aus Textdateien betrifft.
Leider finde ich den Artikel nicht mehr, daher kann ich leider auch nicht sagen, ob mich meine Erinnerung trügt oder nicht.

Jedenfalls tritt dieser Fehler bei deiner Datei auch bei mir auf:
Excel2000: alles OK
Excel2007: nur teilweise richtige Erkennung

Sieh dir doch mal den allerersten Thread in diesem Forum an "Excel 2007 - Bug".
Dort ist ein Link zu einem Hotfix eines anderen Bugs.
Vielleicht findest du dort auch irgendwo einen Hotfix für dieses Problem.

PS: Warum zippst du eine Datei der Größe 1KB???

 

Gezippt, weil txt- Datei konnte ich nicht anfügen zumindest war es so und steht auch nicht bei unterstützten Formaten

Noch ne Frage zu der Schleife von dir über alle Datenblätter: Kann ich die so abändern, das er nur die 3 nächsten nimmt, wobei ich 36 Datenblätter habe und dort sollen 3 Blätter zusammen gefasst werden, das neue erstellt mit den Daten von 3en und dazu das Diagramm.

Ja, es ist wie immer eine kleine Frage und dann artet alles in eine monströse Arbeit aus....

Dann werd ich mal den Hotfix laufen lassen und hoffen.....

Danke

 

Hallo!

Damit stoße ich dann auch an die Grenzen meines VBA-Wissens...
Vielleicht indem du die gewünschten 3 Blätter selektierst und dann die Schleife laufen lässt über

Code:

For Each Blatt In ActiveWorkbook.Windows(1).SelectedSheets

 

Also der Hotfix hat nix gebracht, aber mit

.TextFileDecimalSeparator = "."
.TextFileThousandsSeparator = ","

kann man es umgehen und es passt.....

Deinen Vorschlag für's selektieren werde ich gleich testen...

 

Der von mir angegebene Hotfix war ja auch nicht für dein Problem gedacht...

 

Ach Mist.....

Nachdem ich alles mit Makros machen wollte geht jetzt nichts mehr...
Es kommen Fehlermeldungen wegen Namenskonflikt
und was er machen soll tut er auch nicht

Dabei ist es eigentlich einfach:
Je Datenblatt
1. Die 1. Spalte in Spalte 9 kopieren
2. Die 2. Spalte mit -1 multiplizieren und Ergebnis in Spalte 10 schreiben
3. Neues Datenblatt anlegen und aus 3 bestimmten (die ich manuell auswähle) die unter 1. und 2. angelegten Werte hierher kopieren. Also in Spalte 1-6, weil 2 je Datenblatt und aus 3 Datenblättern besteht es
4. Ein Diagramm zeichnen aus den Daten im neuen Datenblatt mit den 3 Datenreihen.

fertig.

Aber leider bin ich zu Doof dies umzusetzen.....

 

Hallo!

Wozu die Hilfsspalten I und J?
Kopiere diesen Code in ein allgemeines Modul und du hast alle gewünschten Daten in einem neuen Blatt:

Code:

Sub Kopieren()
Dim Blatt As Worksheet
Dim Ende As Integer, i As Integer, Spalte As Integer
Dim Serie As String
Serie = InputBox("Bitte die Seriennr. eingeben (z.B. S03 1-Vh)" & _
vbLf & "Die Seriennr. muss eindeutig identifizierbar sein!")
If Serie = "" Then Exit Sub
Spalte = 1
Sheets.Add
ActiveSheet.Name = "Daten " & Serie
For Each Blatt In ThisWorkbook.Worksheets
If Left(Blatt.Name, Len(Serie)) = Serie Then
Ende = Blatt.Range("B65536").End(xlUp).Row
For i = 10 To Ende
With Sheets("Daten " & Serie)
.Cells(i - 7, Spalte) = Blatt.Cells(i, 1)
.Cells(i - 7, Spalte + 1) = Blatt.Cells(i, 2) * -1
End With
Next i
Spalte = Spalte + 2
End If
Next Blatt
End Sub

 

Ja das ist es, ein Blatt und alles drin ohne Zwischenschritte.....

Ihr seid der Meister...


Jetzt versuche ich mich noch am basteln von nem Makro das mir dann noch dazu ein Diagramm macht...

 

Hallo!

Dieser Code ist noch wesentlich schneller als der letzte.
Voraussetzung für beide Codes ist aber, dass die Daten in deinen Quellblättern jeweils in Zeile 10 starten.
Das ist, wie mir aufgefallen ist, nicht unbedingt in allen deinen Blättern der Fall...

Code:

Sub Kopieren()
Dim Blatt As Worksheet
Dim Ende As Integer, Spalte As Integer
Dim Serie As String
Serie = InputBox("Bitte die Seriennr. eingeben (z.B. S03 1-Vh)" & _
vbLf & "Die Seriennr. muss eindeutig identifizierbar sein!")
  If Serie = "" Then Exit Sub
Spalte = 1
Application.ScreenUpdating = False
Sheets.Add
ActiveSheet.Name = "Daten " & Serie
  For Each Blatt In ThisWorkbook.Worksheets
    If Left(Blatt.Name, Len(Serie)) = Serie Then
      Ende = Blatt.Range("B65536").End(xlUp).Row
      With Sheets("Daten " & Serie)
      Blatt.Range("A10:A" & Ende).Copy .Cells(3, Spalte)
      Blatt.Range("B10:B" & Ende).Copy .Cells(3, Spalte + 1)
      .Range("Z1") = -1
      .Range("Z1").Copy
      .Columns(Spalte + 1).SpecialCells(xlCellTypeConstants) _
      .PasteSpecial Operation:=xlMultiply
      Spalte = Spalte + 2
      End With
    End If
  Next Blatt
Sheets("Daten " & Serie).Range("Z1").Clear
Application.ScreenUpdating = True
End Sub

 

Habe es jetzt so gemacht:

Code:

Sub Kopieren()
Dim Blatt As Worksheet
Dim Ende As Integer, i As Integer, Spalte As Integer
Dim Serie As String
Serie = InputBox("Bitte die Seriennr. eingeben (z.B. S03 1-Vh)" & _
vbLf & "Die Seriennr. muss eindeutig identifizierbar sein!")
If Serie = "" Then Exit Sub
Spalte = 1
Sheets.Add
ActiveSheet.Name = "Daten " & Serie
For Each Blatt In ThisWorkbook.Worksheets
If Left(Blatt.Name, Len(Serie)) = Serie Then
Ende = Blatt.Range("B65536").End(xlUp).Row
For i = 10 To Ende
With Sheets("Daten " & Serie)

.Cells(2, Spalte) = "Y - Wert"
.Cells(2, Spalte + 1) = "X - Wert"
.Cells(i - 7, Spalte) = Blatt.Cells(i, 1)
.Cells(i - 7, Spalte + 1) = Blatt.Cells(i, 2) * -1
End With
Next i
Spalte = Spalte + 2
End If
Next Blatt

ActiveSheet.Name = "Daten " & Serie
Charts.Add
ActiveChart.ChartType = xlXYScatterSmooth
ActiveChart.SetSourceData Source:=Range("'Daten S03 1-Vh'!$F$44")
ActiveChart.Name = "Diagramm " & Serie
ActiveChart.SeriesCollection.NewSeries
ActiveChart.SeriesCollection(1).Name = "=""Kontakt"""
ActiveChart.SeriesCollection(1).XValues = "='Daten S03 1-Vh'!$B$3:$B$27"
ActiveChart.SeriesCollection(1).Values = "='Daten S03 1-Vh'!$A$3:$A$27"
ActiveChart.SeriesCollection.NewSeries
ActiveChart.SeriesCollection(2).Name = "=""CZM"""
ActiveChart.SeriesCollection(2).XValues = "='Daten S03 1-Vh'!$D$3:$D$32"
ActiveChart.SeriesCollection(2).Values = "='Daten S03 1-Vh'!$C$3:$C$32"
ActiveChart.SeriesCollection.NewSeries
ActiveChart.SeriesCollection(3).Name = "=""Starr"""
ActiveChart.SeriesCollection(3).XValues = "='Daten S03 1-Vh'!$F$3:$F$39"
ActiveChart.SeriesCollection(3).Values = "='Daten S03 1-Vh'!$E$3:$E$39"

'Modifizieren der Strichsymbole
ActiveChart.SeriesCollection(2).Select
    With Selection
        .MarkerStyle = 1
        .MarkerSize = 4
    End With
ActiveChart.SeriesCollection(1).Select
    With Selection
        .MarkerStyle = 2
        .MarkerSize = 4
    End With
ActiveChart.SeriesCollection(3).Select
    With Selection
        .MarkerStyle = 3
        .MarkerSize = 4
    End With

End Sub

müsste jetzt nur noch wissen wie ich die Linienstärke ändere von 2 1/4 auf 1

und wie ich beim erstellen der Datenreihen vielleicht die festen Wertangaben siehe oben:
ActiveChart.SeriesCollection(2).XValues = "='Daten S03 1-Vh'!$D$3:$D$32"
um gehen kann.....

Danke, das ist das erste richtig Super schnell und qualifizierteste Forum was ich bis jetzt erlebt habe.....

 

Hallo!

Dieser Code klappt bei mir und damit würde ich mich jetzt auch gern aus diesem Thread verabschieden wollen:

Code:

Sub Kopieren2()
Dim Blatt As Worksheet
Dim Ende As Integer, i As Integer, Spalte As Integer
Dim Serie As String
Serie = InputBox("Bitte die Seriennr. eingeben (z.B. S03 1-Vh)" & _
vbLf & "Die Seriennr. muss eindeutig identifizierbar sein!")
If Serie = "" Then Exit Sub
Spalte = 1
Sheets.Add
ActiveSheet.Name = "Daten " & Serie
For Each Blatt In ThisWorkbook.Worksheets
If Left(Blatt.Name, Len(Serie)) = Serie Then
Ende = Blatt.Range("B65536").End(xlUp).Row
For i = 10 To Ende
With Sheets("Daten " & Serie)

.Cells(2, Spalte) = "Y - Wert"
.Cells(2, Spalte + 1) = "X - Wert"
.Cells(i - 7, Spalte) = Blatt.Cells(i, 1)
.Cells(i - 7, Spalte + 1) = Blatt.Cells(i, 2) * -1
End With
Next i
Spalte = Spalte + 2
End If
Next Blatt

Dim Bereich As Range
With Sheets("Daten " & Serie).UsedRange
Set Bereich = .Offset(1, 0).Resize(.Rows.Count - 1, .Columns.Count)
End With
Charts.Add
ActiveChart.ChartType = xlXYScatterSmooth
ActiveChart.SetSourceData Source:=Bereich
ActiveChart.Name = "Diagramm " & Serie
ActiveChart.SeriesCollection.NewSeries
ActiveChart.SeriesCollection(1).Name = "=""Kontakt"""
ActiveChart.SeriesCollection(1).XValues = Bereich.Columns(2)
ActiveChart.SeriesCollection(1).Values = Bereich.Columns(1)
ActiveChart.SeriesCollection.NewSeries
ActiveChart.SeriesCollection(2).Name = "=""CZM"""
ActiveChart.SeriesCollection(2).XValues = Bereich.Columns(4)
ActiveChart.SeriesCollection(2).Values = Bereich.Columns(3)
ActiveChart.SeriesCollection.NewSeries
ActiveChart.SeriesCollection(3).Name = "=""Starr"""
ActiveChart.SeriesCollection(3).XValues = Bereich.Columns(6)
ActiveChart.SeriesCollection(3).Values = Bereich.Columns(5)
ActiveChart.SeriesCollection(4).Delete
ActiveChart.SeriesCollection(4).Delete
ActiveChart.SeriesCollection(4).Delete
ActiveChart.SeriesCollection(4).Delete
ActiveChart.SeriesCollection(4).Delete

'Modifizieren der Strichsymbole
With ActiveChart.SeriesCollection(2)
  .MarkerStyle = 1
  .MarkerSize = 4
  .Border.LineStyle = xlContinuous
  .Border.Weight = xlThin
End With
With ActiveChart.SeriesCollection(1)
  .MarkerStyle = 2
  .MarkerSize = 4
  .Border.LineStyle = xlContinuous
  .Border.Weight = xlThin
End With
With ActiveChart.SeriesCollection(3)
  .MarkerStyle = 3
  .MarkerSize = 4
  .Border.LineStyle = xlContinuous
  .Border.Weight = xlThin
End With

End Sub

 

Perfekt....

Und vielen herzlichen Dank..........

 

Hi,

ich hatte das problem das ich nicht wusste wie man jede 10. Zeile auswählt.
Hier hab ich das file schweden.xls gefunden und mir daraus die zeile:

=INDEX(A$2:A$200;10*ZEILE()-19)

geklaut.

Dann habe ich sie abgewandelt da meine tabelle mehr zeilen hat:

=INDEX(A$1:A$780;10*ZEILE()-10)

nur verstehe ich jetzt nicht was ich da gemacht habe.
klar ich wollte nur jede 10. zeile und hab die -19 durch -10 geändert.
nur bei dem hier angehängten file wolltet ihr ja auch jede 10. zeile.

ich VGA/Excel DAU bin da etwas confused ;)

 

Hallo!

Dass jede 10. Zeile gewählt wird, dafür ist die erste 10 zuständig:

=INDEX(A$1:A$780;10*ZEILE()-10)

Teste es einfach mal, indem du nur diesen Teil als Formel in eine Zelle schreibst und dann runterkopierst:

=10*ZEILE()

Du siehst, je nachdem in welcher Zeile diese Formel steht, erhältst du die zehnfache Zeilennummer.
Also liefert dir deine INDEX-Funktion die Werte aus A10, A20, A30, usw.
Möchtest du aber z.B. die Werte aus A1, A11, A21, usw. erhalten, dann musst du logischerweise jeweils noch 9 abziehen. Dies siehst du an den Ergebnissen der Formel
=10*ZEILE()-9

Kannst du mit der Erklärung etwas anfangen?

 

japp, thx