Office: Zwei Wörterlisten kombinieren

Hallo allerseits,
ich habe folgendes Problem, für welches ich eine bessere Lösung mit Word suche:

Ich habe zwei Listen mit Begriffen, welche ich kombinieren muss.
Nennen wir sie mal Liste A und Liste B.

Liste A sieht so aus:

A1
A2
A3
A4
...

Liste B genauso:

B1
B2
B3
... usw.

Zum Schluß soll aber jedes Wort von Liste A mit allen Begriffen von B kombiniert sein:

A1 + B1
A1 + B2
A1 + B3
...
A2 + B1
A2 + B2
A2 + B3

Ich hoffe das ist insoweit verständlich.
Was ich bisher gemacht habe, ist, dass ich einmal alle B-Wörter mit A1 kombiniert und dann durch die Replace-Funktion A1 mit A2, A2 mit A3 usw. ersetzt habe. Das ist natürlich sehr mühsam...

Kennt jemand eine bessere Lösung? Würde mir sehr helfen :-D

 

Hi,

würde Dir Excel dafür empfehlen... In Word wirst Du das nicht komfortabel lösen können.

Gruß

 

Aha, vielen Dank für die Antwort.
Wie kriege ich das bei Excel hin?

 

So ganz automatisch krieg ichs auch nicht hin, aber wenigstens viel einfacher als in Word:

Liste A kommt in Spalte A, Liste B in Spalte B.

Jetzt in eine freie Zelle (z.B. D1) die folgende Formel: =$A$1&B1 und dann mit dem kleinen Quadrat am rechten unteren Zellenrand nach unten ziehen, bis alle B's abgedeckt sind. Dann für A2 etc. wiederholen.

Gruß

 

das reicht eigentlich schon aus.
Vielen Dank! :-)

 

Hallo Ihr beiden -

Das könnte man noch weiter automatisieren. Diese Formel:
=INDIREKT("A"&SPALTE(A1))&INDIREKT("B"&ZEILE(A1))
irgendwo hin schreiben und nach unten und nach rechts kopieren.

 

Hallo!

Dann hätte ich auch noch einen, falls die Kombinationen alle untereinander stehen sollen:

=INDEX(A:A;1+KÜRZEN((ZEILE(A1)-1)/ANZAHL2(B:B)))&INDEX(B:B;1+REST(ZEILE(A1)-1;ANZAHL2(B:B)))

irgendwo hinschreiben und nach unten kopieren.

 

So, und für den optimalen Komfort hier noch mal beide Formeln mit Fehlerabfang:

Schatzi:
=WENN(ZEILE(A1)<=ANZAHL2(B:B)^2;INDEX(A:A;1+KÜRZEN((ZEILE(A1)-1)/ANZAHL2(B:B)))&INDEX(B:B;1+REST(ZEILE(A1)-1;ANZAHL2(B:B)));"")

Krino:
=WENN((ZEILE(A1)<=ANZAHL2($B:$B))*(SPALTE(A1)<=ANZAHL2($B:$B));INDIREKT("A"&SPALTE(A1))&INDIREKT("B"&ZEILE(A1));"")

 

Und wenn in Spalte A und Spalte B unterschiedlich viele Einträge vorhanden sind, dann lieber dieser Fehlerabfang:

=WENN(ZEILE(A1)<=ANZAHL2(B:B)*ANZAHL2(A:A);INDEX(A:A;1+KÜRZEN((ZEILE(A1)-1)/ANZAHL2(B:B)))&INDEX(B:B;1+REST(ZEILE(A1)-1;ANZAHL2(B:B)));"")

 

Richtig. Und entsprechend für meine "Rechteck"-Lösung
=WENN((SPALTE(A1)<=ANZAHL2($A:$A))*(ZEILE(A1)<=ANZAHL2($B:$B));INDIREKT("A"&SPALTE(A1))&INDIREKT("B"&ZEILE(A1));"")

 

vielen dank für die verbesserung!

 

Ohne Worte !!!

MfG Heinz