Office: zweiseitiges drucken per automatischen Befehl

Guten Morgen,

in Spalte A und B des sheets2 (Excel 2003) habe ich jeden Tag unterschiedlich viel belegte Zellen (Tag1: A1 bis A5, B1 bis B5; Tag2: A1 bis A14, B1 bis b14; Tag3:A1 bis A8, B1 bis B8...).

Jede Zelle von Spalte A Sheet2 muß im Sheet1 auf ein und dieselbe Zelle (H20) transferiert und ausgedruckt werden. Und von Spalte B Sheet2 in Sheet1 in Zelle B10 transferiert und ausgedruckt werden. Jedoch muß Zelle H20 im Sheet1 auf der Vorderseite und Zelle B10 auf der Rückseite des gedruckten Blattes sein.

Inhalt von sheet2A1 auf sheet1H20, Inhalt von sheet2B1 auf sheet1B10, Print (H20 Vorderseite; B10 Rückseite), H20 und B10 löschen;

Inhalt von sheet2A2 auf sheet1H20, Inhalt von sheet2B2 auf sheet1B10, Print (H20 Vorderseite; B10 Rückseite), H20 und B10 löschen;
...
Kann das irgendwie automatisiert werden?

lg hugin79

:)

 

Hallo ?,

mal vorausgesetzt, das der Duplexdruck schon richtig eingestellt ist.


Sub duplexPrint()
Dim rng As Range, rngP As Range

With Sheets("Sheet2")
Set rngP = .Range("A1:A" & .Cells(.Rows.Count, 1).End(xlUp).Row)
End With

With Sheets("Sheet1")
For Each rng In rngP
.Range("B10") = rng.Offset(0, 1)
.Range("H20") = rng
.PrintOut
Next
.Range("B10") = ""
.Range("H20") = ""
End With

Set rngP = Nothing
Set rng = Nothing
End Sub





« Gruß Sepp »

 

Hallo Josef e,

danke erstmal. Was ist wenn der Duplexdruck noch nicht richtig eingestellt ist? Muß ich das vorher manuell machen und muß ich das dann jedesmal machen?

lg

hugin79

 

Hallo ?,

zeichne das Einstellen des Druckers mit dem Recorder auf und zeig dann den Code.




« Gruß Sepp »

 

Hallo Sepp,

ich hab das Einstellen des Druckers mit dem Recorder versucht aufzuzeichnen, es erscheint aber kein Code im Editor.

Hier mal der manuelle Vorgang. Vielleicht kannst du damit was anfangen:

File-->Print-->Name of printer: \\VIEHWFP1\Sales-Rico Aficio 2051-PCL-->Properties-->Setup-->Duplex-->Opent to Top-->Ok-->Ok

Hilft dir das??

lg Hugin

 

Hallo Sepp,

das aufzeichnen hat doch noch funktioniert: hier der Code:

Application.ActivePrinter = _
"\\VIEHWFP1\Sales - Ricoh Aficio 2051 - PCL on Ne04:"
ActiveWindow.SelectedSheets.PrintOut Copies:=1, ActivePrinter:= _
"\\VIEHWFP1\Sales - Ricoh Aficio 2051 - PCL on Ne04:", Collate:=True

Doch der ist ohne den Duplex-->Open to Top

Der ist nur normales Drucken

lg hugin

 

Hallo ?,

das Einstellen von Duplex-Druck per VBA geht nicht.
Ich würde einen neuen Drucker hinzufügen und bei dem in den Eigenschaften die Einstellungen für den Duplex-Druck vornehmen.
Der Drucker sollte im Namen das Wort "DUPLEX" stehen haben (z. B. "Sales - DUPLEX Ricoh Aficio 2051"), dann kann man den entsprechenden Drucker per Code identifizieren.

' **********************************************************************
' Modul: Modul1 Typ: Allgemeines Modul
' **********************************************************************

Option Explicit

Sub duplexPrint()
Dim rng As Range, rngP As Range
Dim vntPrinter As Variant, lngIndex As Variant
Dim strOldPrinter As String, strDuplex As String
Dim bolDublex As Boolean

strOldPrinter = Application.ActivePrinter

vntPrinter = GetPrinters

For lngIndex = 0 To UBound(vntPrinter)
If vntPrinter(lngIndex) Like "*DUPLEX*" Then
Application.ActivePrinter = vntPrinter(lngIndex)
bolDublex = True
Exit For
End If
Next

If bolDublex Then
With Sheets("Sheet2")
Set rngP = .Range("A1:A" & .Cells(.Rows.Count, 1).End(xlUp).Row)
End With

With Sheets("Sheet1")
For Each rng In rngP
.Range("B10") = rng.Offset(0, 1)
.Range("H20") = rng
.PrintOut
Next
.Range("B10") = ""
.Range("H20") = ""
End With
Application.ActivePrinter = strOldPrinter
Else
MsgBox "Kein Duplex-Drucker gefunden!", vbInformation, "Hinweis"
End If

Set rngP = Nothing
Set rng = Nothing
End Sub

Private Function GetPrinters() As Variant
Dim objWMI As Object, colPrinters As Object, objPrinter As Object
Dim vntPrinter() As Variant, lngIndex As Long

Set objWMI = GetObject("winmgmts:" & "{impersonationLevel=impersonate}!\\" & "." & "\root\cimv2")
Set colPrinters = objWMI.ExecQuery("Select * from Win32_PrinterConfiguration")

For Each objPrinter In colPrinters
Redim Preserve vntPrinter(lngIndex)
vntPrinter(lngIndex) = objPrinter.devicename
lngIndex = lngIndex + 1
Next

GetPrinters = vntPrinter
End Function





« Gruß Sepp »

 

Danke *Smilie