Office: (Office 365) Zweispaltige Liste umsortieren

Moin,

eine einspaltige Liste mittels SPALTENUMBRUCH umzusortieren ist ja kein Hexenwerk.
Aber eine zweispaltige Liste so umzusortieren, dass die Datensätze auch zusammenbleiben, will mir momentan nicht gelingen. Vermutlich ist auch das keine große Sache, aber irgendwie stehe ich gerade auf dem Schlauch.

In der angehängten Mappe habe ich Ausgang (A:B) und Wunsch (F:M) einmal dargestellt.

Wer hat eine tolle Idee, das möglichst mit einer einzigen Überlaufformel zu erschlagen?
Vielen Dank im Voraus!

 

Hi,

simple Lösung, es gibt bestimmt bessere:

Code:

=LET(xa;SPALTENUMBRUCH(A1:A60;15);xb;SPALTENUMBRUCH(B1:B60;15);xc;HSTAPELN(xa;xb);SPALTENWAHL(xc;1;5;2;6;3;7;4;8))

 

Moin!
Achtung! Nicht ganz ernst gemeint!
Statt
SPALTENWAHL(xc;1;5;2;6;3;7;4;8)
könnte man natürlich auch folgendes nehmen
SPALTENWAHL(xc;ZUSPALTE(HSTAPELN(SEQUENZ(4);SEQUENZ(4;;5))))

Gruß Ralf

 

Hallo,

meine Lösungsvariante mittels REDUCE()-Funktion:
=LET(dt;A:.B; blöcke;4; Zl;ZEILEN(dt)/blöcke;
r;REDUCE(""; SEQUENZ(blöcke;;1;Zl); LAMBDA(Akk;b; HSTAPELN(Akk;INDEX(dt;b;1):INDEX(dt;b+Zl-1;2))));
WEGLASSEN(r;;1))

 

Hallo,

oder auch folgende Variante:
=LET(dt;$A:.$B; blöcke;4; Zl;ZEILEN(dt)/blöcke;
r;REDUCE(""; SEQUENZ(blöcke;;1;Zl); LAMBDA(Akk;b; HSTAPELN(Akk;ZEILENWAHL(dt;SEQUENZ(Zl;;b)))));
WEGLASSEN(r;;1))

 

Moin,

vielen Dank für eure Antworten, die selbstredend alle super funktionieren.
Das scheint also doch nicht ganz so einfach zu sein wie ich vermutet/gehofft habe. Naja, so brauche ich mich wenigstens nicht zu grämen, das nicht selbst herausgefunden zu haben.

Ganz besonderen Dank an Anton, der mir mit der Syntax "A:.B" etwas völlig Unbekanntes präsentieren konnte, was ich in meinen über 30 Excel-Jahren noch nie zuvor gesehen habe. Der "." scheint den Bereich A:B auf den gefüllten Teil zu beschränken, oder wie funktioniert das genau? Ist das neu? Bringt das auch Performance-Vorteile?

 

Ja, die entsprechende Funktion vorausgesetzt.
Diese Trim-Ref-Operatoren sind sehr neu und gibt es auch als Argumente in ABSCHNBEREICH()
TRIMRANGE-Funktion

Gruß Ralf

 

Das beruhigt mich schon wieder. Nicht auszudenken, wenn eine solche Syntax schon jahrelang neben mir her existiert hätte!
Vielen Dank auch für den Link, Ralf!
Jetzt muss ich mir das nur noch merken...
Und ich muss morgen mal im Büro schauen, ob wir das dort auch schon zur Verfügung haben. Wir arbeiten zwar mit Excel365, hinken aber den neuesten Updates immer ein wenig hinterher.

 

Hallo Excel-Fan's,

ob TrimRange(), AbschnBereich bzw. $A.:.$B der große Renner in Excel-Anwendungen wird, ist doch sehr zu hinterfragen:
- jedes unbedacht eingegebenes Leerzeichen hinter dem gemeinten Bereich
- führt zur Ausdehnung des Bereiches
- ohne das man es wollte
- und die Suche nach dem Fehler kostet Zeit , Geld & Nerven
- man sollte schon in der Lage sein, den Bereich selbst einzuschränken
- durch benannte Bereiche oder Strg-Tabellen
- siehe:

Gruß von Luschi
aus klein-Paris

 

Moin,

ja, dieser Einwand ist nicht ganz unberechtigt.
Als Erweiterung der möglichen Optionen finde ich diese Idee dennoch gut.
Insbesondere in einer Zeit, in der das Zusammenspiel zwischen intelligenten Tabellen und Überlauf-Formeln IMHO noch deutlich ausbaufähig ist.