Office: Dynamische Zusammenfassung aus 1. Spalte mit 2. Spalte als "Flatterdaten"

Szenario:

A1:B12:
Untern. Abteilung
Firma A A12
Firma A B42
Firma A A06
Firma B B15
Firma C B23
Firma C C02
Firma D H58
Firma D H25
Firma D B42
Firma D A62
Firma D Y12

soll werden zu

E1:F5:
Untern. Abteilung
Firma A A12; B42; A06
Firma B B15
Firma C B23; C02
Firma D H58; H25; B42; A62; Y12

Bedingungen:

1. Spalte A ist sortiert
2. Spalte B hat die Fixlänge 3
3. Es werden vor der letzten Zeile (12) Datensätze eingefügt/gelöscht (dann Formeln weniger lang möglich).

Formeln (ab xl365 bzw. ca. nach dem Jahr 2019):
E2: =EINDEUTIG(A2:A12)
F2: =WECHSELN(TEIL(TEXTVERKETTEN("; ";;B2:B12);
VERGLEICH(E2#;A2:A12;)*5-4;(
VERGLEICH(E2#;A2:A12)-
VERGLEICH(E2#;A2:A12;)+1)*5)&" ";"; ";)
___________________________
Abwandlung für den Wegfall aller Bedingungen (jetzt: 1. A unsortiert, 2. B variabel lang, 3. Daten einfach anhängbar):
E2: =SORTIEREN(EINDEUTIG(A2:INDEX(A:A;ANZAHL2(A:A))))

F2: =LET(
c;SORTIEREN(A2:INDEX(B:B;ANZAHL2(A:A)));
a;INDEX(c;;1);
b;INDEX(c;;2);
d;LÄNGE(b);
e;MAX(d)+2;k;"Das +2 ist die Länge der Verkettungszeichen '; '";
f;VERGLEICH(E2#;a;);l;"Speichere nicht binären Vergleich for Speed";
WECHSELN(WECHSELN(TEIL(TEXTVERKETTEN("; ";;b&WIEDERHOLEN("_";MAX(d)-d));
f*e-e+1;(VERGLEICH(E2#;a)-f+1)*e)&" ";"; ";);"_";))

Bemerkungen:

1. TEXTVERKETTEN lässt sich leider nicht dynamisch bedingt verwenden. Daher wird alles verkettet und mit TEIL und VERGLEICH eingegrenzt.
2. Bill Jelen zeigt, wie man das auch mit Wertefeldern in Pivot-Tabellen hinbekommt. Vorteil: Sortierung egal; Limit jedoch ebenfalls 32768 Zeichen pro Zelle (mehr wäre auch unsinnig).
3. Power Query kann das natürlich auch (Link wird nachgereicht).
4. EDIT 4.4.2021 (Ostersonntag): RPP63 zeigt noch eine kurze MTRANS(FILTER-Variante.

Ein paar Monate später mit neuen dynamischen Funktionen:

Für mittlere Mengen (bis ca. 2200 Datensätze A:B, in XLWeb Stand Oktober 2022 auch mehr) hier noch eine performante Lösung nicht über Vergleiche, sondern mit einem Positions-Sort:

C1: =LAMBDA(ab;o;LET(
a;INDEX(ab;;1);
b;INDEX(ab;;2);
c;EINDEUTIG(a);
d;SCAN(1;a=VSTAPELN(0;WEGLASSEN(a;-1));LAMBDA(y;z;(y+1)*z))+1;
e;SCAN(1;d<VSTAPELN(0;WEGLASSEN(d;-1));LAMBDA(y;z;y+z));
f;MAX(d);
g;MAX(e);
h;REST(SEQUENZ(f*g)-1;f)+1;
i;GANZZAHL(SEQUENZ(f*g;;f)/f);
k;WENNFEHLER(WEGLASSEN(SORTIEREN(HSTAPELN(EINDEUTIG(VSTAPELN(HSTAPELN(d;e);HSTAPELN(h;i)));b);2);;2);"");
m;INDEX(k;SEQUENZ(g;f));
n;NACHZEILE(m;LAMBDA(a;TEXTVERKETTEN(";";;a)));
HSTAPELN(c;WAHL(o;m;n))))(A1:B2200;1)

Bitte hier die möglichen Fehler nachlesen:
(Office 365) - Zeilen gruppieren und zugehörige Spalte aufteilen