Ergebnis 1 bis 1 von 1

Thema: Dynamische Zusammenfassung aus 1. Spalte mit 2. Spalte als "Flatterdaten"

  1. #1
    Office-Hilfe.com - Durchblicker
    Registriert seit
    30.12.2016
    Beiträge
    278

    Dynamische Zusammenfassung aus 1. Spalte mit 2. Spalte als "Flatterdaten"

    Szenario:

    A1:B12:
    Untern. Abteilung
    Firma A A12
    Firma A B42
    Firma A A06
    Firma B B15
    Firma C B23
    Firma C C02
    Firma D H58
    Firma D H25
    Firma D B42
    Firma D A62
    Firma D Y12

    soll werden zu

    E1:F5:
    Untern. Abteilung
    Firma A A12; B42; A06
    Firma B B15
    Firma C B23; C02
    Firma D H58; H25; B42; A62; Y12


    Bedingungen:
    1. Spalte A ist sortiert
    2. Spalte B hat die Fixlänge 3
    3. Es werden vor der letzten Zeile (12) Datensätze eingefügt/gelöscht (dann Formeln weniger lang möglich).

    Formeln (ab xl365 bzw. ca. nach dem Jahr 2019):
    E2: =EINDEUTIG(A2:A12)
    F2: =WECHSELN(TEIL(TEXTVERKETTEN("; ";;B2:B12);
    VERGLEICH(E2#;A2:A12;)*5-4;(
    VERGLEICH(E2#;A2:A12)-
    VERGLEICH(E2#;A2:A12;)+1)*5)&" ";"; ";)

    ___________________________
    Abwandlung für den Wegfall aller Bedingungen (jetzt: 1. A unsortiert, 2. B variabel lang, 3. Daten einfach anhängbar):
    E2: =SORTIEREN(EINDEUTIG(A2:INDEX(A:A;ANZAHL2(A:A))))

    F2: =LET(
    c;SORTIEREN(A2:INDEX(B:B;ANZAHL2(A:A)));
    a;INDEX(c;;1);
    b;INDEX(c;;2);
    d;LÄNGE(b);
    e;MAX(d)+2;k;"Das +2 ist die Länge der Verkettungszeichen '; '";
    f;VERGLEICH(E2#;a;);l;"Speichere nicht binären Vergleich for Speed";
    WECHSELN(WECHSELN(TEIL(TEXTVERKETTEN("; ";;b&WIEDERHOLEN("_";MAX(d)-d));
    f*e-e+1;(VERGLEICH(E2#;a)-f+1)*e)&" ";"; ";);"_";))


    Bemerkungen:
    1. TEXTVERKETTEN lässt sich leider nicht dynamisch bedingt verwenden. Daher wird alles verkettet und mit TEIL und VERGLEICH eingegrenzt.
    2. Eric Jelen zeigt, wie man das auch mit Wertefeldern in Pivot-Tabellen hinbekommt. Vorteil: Sortierung egal; Limit jedoch ebenfalls 32768 Zeichen pro Zelle (mehr wäre auch unsinnig).
    3. Power Query kann das natürlich auch (Link wird nachgereicht).
    Geändert von lupo1 (04.08.2020 um 08:02 Uhr)

Berechtigungen

  • Neue Themen erstellen: Nein
  • Themen beantworten: Nein
  • Anhänge hochladen: Nein
  • Beiträge bearbeiten: Nein
  •  
Excel Ticker - News, Tipps und Tricks zu Microsoft Excel