Office: (Office 2019) Word - nach mehreren Wörtern suchen und diese farbig markieren?

Hallo,

ich möchte in Word ein Dokument immer nach den gleichen ganzen Wörtern durchsuchen und die Ergebnisse unterschiedlich farbig markieren.

Beispiel:

Auto - Bus - Flugzeug - grün markieren

Schiff - LKW - Busfahrer - rot markieren

Ich weiss, das man in Word über die erweiterte Suche nach einzelnen Worten suchen kann und diese dann über Leseervorhebung gelb markieren kann, allerdins muss man die Worte einzeln nacheinander eingeben und verschiedene Farben lassen sich über diesen Weg nicht darstellen.

Ist dies ohne Programmierkenntnisse umsetzbar oder geht das nur über vba?

Karsten

 

Hallo Karsten,

komfortabel (und vor allem: in einem Aufwasch) geht das sicher nur per VBA. Aber verschiedene Farben einstellen geht auch ohne (siehe Bild). Du musst halt jeden Begriff einzeln suchen. und die Hervorhebungsfarbe jeweils vorher auswählen.

Einen VBA-Vorschlag könnte ich dir schon machen, wenn es technisch möglich bzw. gewollt ist (Makros müssen erlaubt sein). Nachvollziehen und ändern dürfte kein allzu großes Problem werden, der Code wird hoffentlich recht übersichtlich.

 

Hallo Gerhard,

danke für die schnelle Rückmeldung - ein VBA Vorschlag mit den oben genannten Suchwörtern wäre super

Danke vorab
Karsten

 

Hallo Karsten,

nachdem du im Nachbarforum noch zwei ähnliche makrofreie Vorschläge bekommen hast, hier noch die versprochene "Ein-Aufwasch-Lösung" per VBA.

Code:

Sub machsBunt()
Dim ArrRot As Variant, arrGruen As Variant
Dim i As Long
Dim fundbereich As Range

'Arrays für gleich zu färbende Begriffe festlegen
ArrRot = Array("Franz", "Taxi", "Bayern")
arrGruen = Array("jagt", "komplett", "quer")

    'Dokument nach den rot zu färbenden Begriffen durchsuchen
    For i = 0 To UBound(ArrRot)
        With ActiveDocument.Range.Find
            .Text = ArrRot(i)
            'Fundstellen rot hinterlegen
            Do While .Execute
                Set fundbereich = .Parent
                fundbereich.Shading.ForegroundPatternColor = wdColorRed
            Loop
        End With
    Next i
   
    'Dokument nach den grün zu färbenden Begriffen durchsuchen
    For i = 0 To UBound(arrGruen)
        With ActiveDocument.Range.Find
            .Text = arrGruen(i)
            'Fundstellen grün hinterlegen
            Do While .Execute
                Set fundbereich = .Parent
                fundbereich.Shading.ForegroundPatternColor = wdColorBrightGreen
            Loop
        End With
    Next i
End Sub

Testen des Makros:
Angehängtes Dokument entzippen und das Makro Sub machsBunt() starten. Zurücksetzen: alles markieren und Strg-Leer drücken
Anpassen des Makros:
Zu suchende Begriffe innerhalb der Array()-Klammern austauschen bzw. erweitern.
Farben: Anpassen in den Zeilen fundbereich.Shading..... Eine Liste der möglichen Farben erhältst du hier. WdColor-Enumeration (Word)

Wohin mit dem Makro?
Wenn es nur immer für das gleiche Dokument eingesetzt werden soll: Im VBA-Editor ins Modul ThisDocument des zu bearbeitenden Dokuments, oder in ein zu erstellendes neuen allgemeines Modul
Wenn es für verschiedene Dokumente eingesetzt werden soll: Im VBA-Editor ins Modul Thisdocument der Normal-Vorlage oder in ein neues Modul dieser Vorlage

Noch eine Bemerkung: Wenn du schon gleichzeitig in verschiedenen Foren fragst, setze bitte jeweils einen Link auf das andere Forum, damit potentielle Helfer über den Stand der Dinge informiert sind.

 

@gerhard: danke für die Rückmeldung - zukünftig werde ich verlinken

Karsten

 

Hallo,

ist es auch möglich dies wie oben zu sehen für eine Excel-Tabelle analog per vba umzusetzen?

Karsten

 

Hallo Karsten,

"ist es auch möglich dies wie oben zu sehen für eine Excel-Tabelle analog per vba umzusetzen?"
Ich könnte mir vorstellen, dass man das in Excel makrofrei mittels bedingter Formatierung macht. Aber wenn du dazu Hilfe brauchst, frag das bitte im Excel-Forum. Ich bin in Excel nicht so zuhause. Füg am besten eine Beispieltabelle bei.