Office: Als PDF speichern

mton · 29. Januar 2018

Hallo zusammen,

ich möchte gerne eine Word Datei separat als PDF speichern. Dies klappt auch super. Allerdings möchte ich die PDF Datei gerne nach der aktuellen Rechnungsnummer aus dem Serienbrief benennen. Leider fehlt der Verweis für ".DataFields". Bin hierbei mit meinem Latein leider am Ende.

Code:

Private Sub CommandButton1_Click()

Const path As String = "..."

ActiveDocument.ExportAsFixedFormat _
OutputFileName:=path & "Rechnung_" & .DataFields("Rechnungsnummer").Value & ".pdf", _
ExportFormat:=wdExportFormatPDF, _
OpenAfterExport:=False, _
OptimizeFor:=wdExportOptimizeForPrint, _
Range:=wdExportAllDocument, _
From:=1, _
To:=1, _
Item:=wdExportDocumentContent, _
IncludeDocProps:=True, _
KeepIRM:=True, _
CreateBookmarks:=wdExportCreateNoBookmarks, _
DocStructureTags:=True, _
BitmapMissingFonts:=True, _
UseISO19005_1:=False
End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

:)

Gerhard H · 31. Januar 2018

Hallo mton,

Datafields(...) ist eine Eigenschaft von Datasource, nicht vom aktiven Dokument.

Wenn du pro Datensatz aus deinem Serienbrief ein eigenes PDF-Dokument erzeugen möchtest, versuch folgendes Makro:
Code:

Sub JederDatensatzInEineEigeneDatei()
'*****dieses Makro vom Seriendruck-Hauptdokument aus laufen lassen (statt Dokumente zusammenführen)*********

Dim i As Long, anzahl As Long
Dim dateiname As String, Pfad As String

Pfad = ThisDocument.Path

With ActiveDocument.MailMerge
If .MainDocumentType = wdNotAMergeDocument Then
MsgBox "Das Dokument ist noch nicht mit einer Seriendruckquelle verbunden."
Exit Sub
End If

'Anzahl Datensätze feststellen, Abbruch bei 0
anzahl = .DataSource.RecordCount

If anzahl = 0 Then
MsgBox "Es wurden keine Datensätze gefunden."
Exit Sub
End If

.Destination = wdSendToNewDocument

For i = 1 To anzahl
.DataSource.ActiveRecord = i

dateiname = Pfad & "" & .DataSource.DataFields("Rechnungsnummer").Value
.DataSource.FirstRecord = i
.DataSource.LastRecord = i
.Execute

With ActiveDocument
'Schönheitssache: löscht den abschließenden Abschnittsumbruch
.Range.Find.Execute findtext:="^b", replacewith:=""

' speichern als pdf
ActiveDocument.ExportAsFixedFormat OutputFileName:= _
dateiname & ".pdf", ExportFormat:=wdExportFormatPDF, OpenAfterExport:=False
.Close savechanges:=False
End With
Next i

.DataSource.FirstRecord = 1
End With
MsgBox anzahl & " Dateien erstellt."
End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

mton · 31. Januar 2018

Hey Gerhard,
zunächst einmal vielen Dank, dass du dich meinem kleinen Problem sofort gewidmet hast!

Zwei Anmerkungen habe ich zu deinem Makro:

1. Ist es möglich nur die entsprechende PDF Datei ohne ein weiteres Word Dokument zu erstellen?
2. Lasse ich dein Makro laufen, bekomme ich gesagt, dass bei:

Code:

ActiveDocument.ExportAsFixedFormat OutputFileName:= _
dateiname & ".pdf", ExportFormat:=wdExportFormatPDF, OpenAfterExport:=False
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

...der Verzeichnisname ungültig ist. Muss ich evtl. noch etwas einfügen?

Gerhard H · 31. Januar 2018

Hallo nochmal,

Zu 2: da hat der forumseigene Bug zugeschlagen. Bei dateiname = ... (rote Zeile) muss ein Backslash zwischen die Anführungszeichen.

Bei 1 versteh ich das Problem nicht, weil das erzeugte zusammengeführte Seriendruck-Dokument ja sofort wieder ohne Speichern geschlossen wird.

mton · 31. Januar 2018

Ich habe das Backslash zwischen die Anführungszeichen gesetzt. Fehler besteht leider weiterhin.
Das neue Word Dokument bleibt auch weiterhin geöffnet. Außerdem soll nur das aktuelle Serienbriefblatt als PDF gespeichert werden und nicht alle, weil immer wieder neue Empfänger in der Excelliste hinzugefügt werden.

Beispiel: Serienbrief Dokument öffnen > Durchklicken bis zum gewünschten Empfänger (Bsp. Name: Empfänger 3) > Auf Button klicken und nur die PDF für Empfänger 3 abspeichern.

Gerhard H · 31. Januar 2018

Hallo,

zum Fehler beim Pfad: Füge direkt unter die Zeile Pfad = ThisDocument.Path ein: MsgBox Pfad. Das müsste den Ordnernamen ergeben, in dem dein Hauptdokument gespeichert ist. Wenn nicht, oder wenn die Meldung vollkommen leer ist, hast du das Makro vielleicht nicht ins Hauptdokument eingefügt, sondern z.B. in den ausgeführten Seriendruck, oder sonstwo.
Wenn du nicht zum Ziel kommst, kannst statt Pfad = ThisDocument.Path auch einen festen Pfad eingeben, z.B. pfad = "C:\temp"

Dass das neue Word-Dokument weiter geöffnet bleibt, liegt einfach daran, dass das Makro nicht durchlaufen kann, solange obiger Fehler weiter existiert.

Im Lichte der neuen Erklärung, was du eigentlich willst, sieht das neue Makro so aus:
Code:

Sub NurDenAktivenDatensatzDrucken()
'*****dieses Makro vom Seriendruck-Hauptdokument aus laufen lassen (statt Dokumente zusammenführen)*********

Dim i As Long
Dim anzahl As Long, aktDatensatz As Long
Dim dateiname As String
Dim Pfad As String

Pfad = ThisDocument.Path 'oder festen Pfad eingeben
MsgBox Pfad 'nur zur Kontrolle
With ActiveDocument.MailMerge
If .MainDocumentType = wdNotAMergeDocument Then
MsgBox "Das Dokument ist noch nicht mit einer Seriendruckquelle verbunden."
Exit Sub
End If

'Anzahl Datensätze feststellen, Abbruch bei 0
anzahl = .DataSource.RecordCount

If anzahl = 0 Then
MsgBox "Es wurden keine Datensätze gefunden."
Exit Sub
End If

.Destination = wdSendToNewDocument

aktDatensatz = .DataSource.ActiveRecord

dateiname = Pfad & "\" & .DataSource.DataFields("Rechnungsnummer").Value
MsgBox dateiname & ".pdf" 'nur zur Kontrolle
.Execute

With ActiveDocument
'Schönheitssache: löscht den abschließenden Abschnittsumbruch
.Range.Find.Execute findtext:="^b", replacewith:=""

'speichern als pdf
ActiveDocument.ExportAsFixedFormat OutputFileName:= _
dateiname & ".pdf", ExportFormat:=wdExportFormatPDF, OpenAfterExport:=False
.Close savechanges:=False
End With

.DataSource.FirstRecord = 1
End With
MsgBox " Datei erstellt."
End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Es funktioniert bei mir unter den Annahmen

dass das Makro im Hauptdokument gespeichert wurde

dass das Hauptdokument geöffnet ist

dass du unter Sendungen > Vorschau Ergebnisse > die gewünschte Datensatznummer ausgewählt hast

und dann das Makro startest, anstatt auf die Schaltfläche Fertigstellen und zusammenführen zu klicken.

mton · 1. Februar 2018

Okay, sieht schon mal sehr gut aus, vielen Dank!

+ Der Pfad (+ .pdf) stimmt,
+ Word Dokument wird geschlossen,
+ PDF Datei wird mit der aktuellen Rechnungsnummer am richtigen Platz erstellt.

- In der PDF befinden sich nun allerdings alle Datensätze. Dort soll jedoch ebenfalls nur der aktuelle Datensatz gespeichert werden.

mton · 1. Februar 2018

Okay, sieht schon mal sehr gut aus, vielen Dank!

+ Der Pfad (+ .pdf) stimmt,
+ Word Dokument wird geschlossen,
+ PDF Datei wird mit der aktuellen Rechnungsnummer am richtigen Platz erstellt.

- In der PDF befinden sich nun allerdings alle Datensätze. Dort soll jedoch ebenfalls nur der aktuelle Datensatz gespeichert werden.

Gerhard H · 1. Februar 2018

Sorry, jetzt hab ich geschlafen. Ersetze das alte Makro durch dieses:
Code:

Sub NurDenAktivenDatensatzDrucken()
'*****dieses Makro vom Seriendruck-Hauptdokument aus laufen lassen (statt Dokumente zusammenführen)*********

Dim dateiname As String
Dim Pfad As String

Pfad = ThisDocument.Path ' oder fester Pfad

With ActiveDocument
If .MailMerge.MainDocumentType = wdNotAMergeDocument Then
MsgBox "Das Dokument ist noch nicht mit einer Seriendruckquelle verbunden."
Exit Sub
End If
'aus dem händisch bei Vorschau Ergebnisse eingestellten Datensatz den Dateinamen generieren
dateiname = Pfad & "\" & .MailMerge.DataSource.DataFields("Rechnungsnummer").Value

'ausgewählten Datensatz mit diesem Dateinamen als PDF speichern
ActiveDocument.MailMerge.ViewMailMergeFieldCodes = False
.ExportAsFixedFormat OutputFileName:= _
dateiname & ".pdf", ExportFormat:=wdExportFormatPDF, OpenAfterExport:=False
End With
MsgBox " Datei erstellt."
End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

mton · 1. Februar 2018

DANKE!!! Es funktioniert genau so, wie ich es mir vorgestellt habe.

Office: Als PDF speichern

Als PDF speichern

Als PDF speichern

Als PDF speichern

Als PDF speichern

Als PDF speichern - Similar Threads - PDF speichern

Excel Tabellenblatt als PDF speichern unter Vorgabe Dateinamen aus einer Zelle

Bei speichern von Word als PDF keine Kommentare

PDF mit Namen,Datum speichern im Zielordner

Datei als PDF speichern ohne festen Dateipfad

PDF-Dateinamen aus Zellen zusammensetzen

PDF geöffnet - speichern nicht möglich

Speichern unter PDF