Office: Bild links in der Zelle einfügen

Hallo Zusammen,

mit folgenden Code füge ich ein Bild in der Zelle der Word-Tabelle ein, in dem der Cusor steht.
Bisher wurde das Bild immer linksbündig eingefügt, aus irgendeinem Grund wir das Bild jetzt recht bündig eingefügt.

Was muss ich ändern, dass das Bild wieder linksbündig eingefügt wird?
Danke Für Eure Hilfe , viele Grüße Ulli

Sub lastPicture()
Dim sPath As String, sFile As String, sTest As String
Dim sType As String, dTest As Date, dFile As Date

sPath = ("C:\Users\UI\Desktop\Fotos\")

sType = "*.jpg " ' <<< ggf. anpassen

sTest = Dir(sPath & sType)
If Len(sTest) > 0 Then
sFile = sTest
dFile = FileDateTime(sPath & sTest)
Do While sTest <> ""
dTest = FileDateTime(sPath & sTest)
If dFile < dTest Then
dFile = dTest
sFile = sTest
End If
sTest = Dir
Loop

With Selection.InlineShapes.AddPicture(Filename:=sPath & sFile, _
LinkToFile:=False, SaveWithDocument:=True)
.LockAspectRatio = True
.Width = CentimetersToPoints(5)
Selection.Rows(1).Height = .Height

.ConvertToShape.WrapFormat.Type = wdWrapThrough

Selection.Rows(1).Height = .Height = 12

End With

Else
MsgBox sPath & sType & vbCrLf & vbCrLf & "Keine passende Datei im Pfad gefunden", _
vbCritical, "Dateifehler"
End If
End Sub

 

Hallo Ulli,

Ursächlich erscheint mir diese Zeile:

.ConvertToShape.WrapFormat.Type = wdWrapThrough

Durch das Umwandeln des Inlineshapes in ein Shape werden Absatzeigenschaften aller Art (die Ausrichtung gehört dazu), ignoriert, weil das Bild aus ja der Textebene rausgehoben wird.

Ein Inlineshape würde einer linksbündige Ausrichtung des Zellinhalts folgen. Jedoch entnehme ich dem Parameter wrapThrough, dass du die Umwandlung mit Bedacht gewählt hast, nur mit welchem Ziel? Erklär das doch bitte noch, dass kann man sich eine Lösung überlegen.

Mutmaßung meinerseits: Wenn ein InlineShape offenbar nicht in Frage kommt, musst du noch die Position ders Shapes im Verhältnis zum Zellenrand festlegen. Mit ein bisschen Glück genügen dafür diese zwei Zeilen:

Selection.ShapeRange.Align msoAlignTops, True
Selection.ShapeRange.Align msoAlignLefts, True

Nicht verstanden hab ich übrigens, wofür diese Zeile gut ist...
Selection.Rows(1).Height = .Height = 12
Die liefert dir ja lediglich einen Wahrheitswert (Wahr|Falsch), den du weiter nicht verarbeitest. Falls das problemrelevant ist, bitte auch den Zweck davon erklären.

 

Hallo Gerhard,

danke für deine Nachricht.
wie ich damals zu dem Parameter (wrapThrough) gekommen bin, kann ich dir leider nicht sagen, wahrscheinlich gegoogelt :-)

Das Einfügen der Beiden Zeilen hat nicht den Erfolg gebracht. Ich habe aber gerade folgendes festgestellt:
Wenn der Cursor beim Einfügen in der Zellen keinen Absatz nach links hat, d.h. Einzug links gleich 0, dann verschiebt er das Bild rechtsbünding.
Wenn ich vor dem Einfügen den Absatz "Einzug links" auf 0,1 stelle, dann wird das Bild wie gewohnt linksbündig eingefügt.
Kann man dies in den Code hineinbringen, d.H. vor dem Einfügen Einzug links 0,1 cm?

Viele Grüße Ulli

 

Hallo nochmal,

naja, wenn das wirklich hilft, ist es ja einfach: Vor dem Einfügen des Bildes (Selection.Inlineshapes.Add.....) diese beiden Zeilen (die erste nur sicherheitshalber, falls die Ausrichtung nicht linksbündig ist):

Selection.Paragraphs(1).Alignment = wdAlignParagraphLeft
Selection.Paragraphs(1).LeftIndent = CentimetersToPoints(0.1)

(In der Hoffnung, dass die anvisierte Zelle leer ist bzw. nur einen einzigen Absatz enthält)

 

Hallo Gerhard,

funktioniert einwandfrei.

Ganz Herzlichen Dank !!

Viele Grüße Ulli