Office: Den Inhalt der Zwischenablage per Makro suchen

Hallo,

ich suche eine Möglichkeit per Makro in Word bestimmte Begriffe innerhalb eines Absatzes zu suchen. Der zu suchende Begriff steht jeweils am Anfang eines Absatzes.

Also habe ich per Makro diesen Begriff gesucht/markiert/kopiert. Jetzt ist er also in der Zwischenablage und ich will diesen Begriff in die Funktion "suchen nach" einfügen. Leider akzeptiert Word den Shortcut ^c aber nur in der "ersetzen"-Funktion und nicht in der "suchen nach"-Funktion.

Hat jemand eine zündende Idee? Habt 1000 Dank!
Stephan

 

Hallo,

ich begreife nicht wirklich Dein Anliegen: Du suchst nach einem Wort, findest es und willst es trotzdem nochmals in ein Suchdialogfenster eingeben?

In der VBA-Hilfe zum Find-Objekt sind zB. folgende Samples abgedruckt, die die grundsätzliche Funktion der Find- bzw. Replace-Objekte demonstrieren: sehr viel einfacher geht es nicht mehr.

 

Entschuldige bitte, wenn ich mich unklar ausgedrückt habe.

Mein Problem ist, dass ich keinen festen Suchbegriff habe, sondern jeweils das erste Wort eines Absatzes im weiteren Text suche.
Den Suchbegriff nehme ich auf, indem ich per Makro nach der nächsten freien Zeile suche und dann das nächst folgende Wort markiere und in die Zwischenablage kopiere.

Nur wie bekomme ich diesen Begriff aus der Zwischenalage in einem Makro jetzt in das Feld "Suchen nach"?

Danke für die Hilfe!!!

Stephan

 

Hallo,

folgendes Makro kopieren und in ein allgem. Codemodul einfügen und mit der Tastenkombination Alt+F8 und nachfolgender Eingabe-Taste starten.

Es ermittelt die Anzahl der Absätze im aktiven Dokument und markiert das 1. Wort eines jeden Absatzes bzw. zeigt es an, es sei denn, es besteht nur aus 1 Zeichen. Klickt man hier auf 'Abbrechen', beendet man das Makro.
Dieses jeweils gefundene Wort befindet sich in der String-Variablen 'Wort1', welches sich wiederum in der Bereichsvariablen 'ErstesWort' befindet.

Da damit dieses Wort ermittelt ist, ist mir nicht klar, was für einen Nutzen es hat, dieses Wort nachträglich in das Feld des Standarddialoges "Suchen" einzufügen? Nichts desto trotz habe ich auch dies eingebaut. Erst wenn man den Button 'Abbrechen' im Suchendialog klickt, beendet man die Suche und geht zum nächsten Absatz über.

Code:

Public Sub ErstesWort_im_Absatz()
  Dim myStory As Word.Range
  Dim myAbsatz As Word.Paragraph
  Dim ErstesWort As Word.Range, AbsatzNr&, AbsatzAnz&
  Dim Wort1$
  
  On Error Resume Next
  
  'Ermittle den Inhaltsbereich des aktiven Dokumentes
  Set myStory = ActiveDocument.Content
  'Ermittle die Anzahl der Absätze im Inhaltsbereich
  AbsatzAnz& = myStory.Paragraphs.Count
  
  'Für jeden dieser Absätze tue Folgendes:
  For AbsatzNr& = 1 To AbsatzAnz&
    
    'Ermittle den Bereich des 1.Wortes des Absatzes mit Nr. AbsatzNr
    Set ErstesWort = myStory.Paragraphs(AbsatzNr&).Range.Words(1)
    'Ermittle Textinhalt dieses Bereichs; entferne führende und nachfolgende Leerzeichen
    Wort1$ = Trim(ErstesWort.Text)
    
    'Falls dieses Wort länger als 1 Zeichen ist:
    If Len(Wort1$) > 1 Then
      'Markiere diesen Wortbereich
      ErstesWort.Select
      'Zeige dieses Wort an zusammen mit seiner AbsatzNr.
      'Fahre fort oder brich das Ganze ab
      If MsgBox(Prompt:="Das 1.Wort des " & AbsatzNr& & ". Absatzes lautet: '" & Wort1$ & "'", _
                buttons:=vbInformation + vbOKCancel, _
                Title:="Das 1.Wort von " & AbsatzAnz& & " Absätzen") = vbCancel Then Exit Sub
                
      'Ganzen Absatz, in dem sich ErstesWort befindet, markieren
      ErstesWort.Paragraphs(1).Range.Select
      'Standarddialog 'Suchen/Finden' aufrufen
      With Dialogs(wdDialogEditFind)
        'Feld "Suchen nach" mit der Variablen Wort1$ vorbesetzen
        .Find = Wort1$
        'Suchen ausführen, falls anderer Button als 'Abbrechen' geklickt wurde
        If .Show Then .Execute
      End With
      
    End If
    
  'Nächste AbsatzNr.
  Next AbsatzNr&

End Sub

 

Lieber Exl121150,

vielen, lieben Dank für die Mühe!!!

Den zu suchenden Begriff als String-Variable aufzunehmen und über die .Find = Funktion in den Suchdialog zu übergeben, klappt perfekt. Genau das, was ich gesucht habe.

Alles Gute für 2010!

Stephan