Office: (Office 2016) Dropdown Mehrfachauswahl trotz Blattschutz

Hallo Leute,
ich habe eine Exceldatei, in der ich per Dropdown eine Mehrfachauswahl zu lasse. Das mache ich über folgenden Code (Kopier von: https://www.excel-inside.de/funktionen-a-tipps/895-dropdown-liste-mit-mehrfachauswahl):

Code:

Private Sub Worksheet_Change(ByVal Target As Range)
'** Mehrfachauswahl über DropDown-Liste (Gültigkeitsprüfung)
'** Einfügen im Code-Container des betreffenden Arbeitsblattes

'** Dimensionierung der Variablen
Dim rngDV As Range
Dim wert_old As String
Dim wertnew As String

'** Errorhandling
On Error GoTo Errorhandling

'** Mehrfachauswahl im definierten Bereich (Bsp. B4:B14) durchführen
If Not Application.Intersect(Target, Range("J2:L1000")) Is Nothing Then

  '**Range definieren
  Set rngDV = Target.SpecialCells(xlCellTypeAllValidation)
  If rngDV Is Nothing Then GoTo Errorhandling
  
  '** Prüfen, ob eine gültige Zelle ausgewählt wurde und Werte eintragen
  If Not Application.Intersect(Target, rngDV) Is Nothing Then
    Application.EnableEvents = False
    wertnew = Target.Value
    Application.Undo
    wertold = Target.Value
    Target.Value = wertnew
    If wertold <> "" Then
      If wertnew <> "" Then
        Target.Value = wertold & ", " & wertnew
      End If
    End If
  End If
  Application.EnableEvents = True
End If

Errorhandling:
Application.EnableEvents = True
End Sub

Nun möchte ich das Blatt (bis auf die Eingabezellen) schützen, damit die Kolleginnen nicht die Formeln versehentlich verändern.
Leider wird dadurch der Code ausgeschaltet, sprich:
Auswahl per Dropdown ist möglich, aber die Mehrfachauswahl nicht.

Beim Googlen habe ich gesehen, dass es auch hierfür Codes gibt (zum Beispiel: http://www.office-hilfe.com/support/showthread.php/16349-VBA-Ausführung-trotz-Blattschutz).
Leider habe ich keine Ahnung von Codes und kann mir nicht selbst helfen, indem ich etwas ähnliche fabriziere. Ich kann nur Copy&Paste :D

Ich bräuchte einen Code, der es möglich macht, dass der Code für die Mehrfachauswahl trotz Blattschutz läuft. Oder eine andere Lösung..

Kann mir jemand helfen?

Liebe Grüße
Ramona

 

Hallo Ramona,

dir kann im Prinzip relativ leicht geholfen werden mit folgendem VBA-Code anstelle des bisherigen:

Code:

Private Sub Worksheet_Change(ByVal Target As Range)
  '** Mehrfachauswahl über DropDown-Liste (Gültigkeitsprüfung)
  '** Einfügen im Code-Container des betreffenden Arbeitsblattes

  '** Dimensionierung der Variablen
  Dim rngDV As Range
  Dim wert_old As String
  Dim wert_new As String

  '** Errorhandling
  On Error GoTo Error_Handling

  '** Mehrfachauswahl im definierten Bereich (Bsp. B4:B14) durchführen
  If Not Application.Intersect(Target, Range("B4:B14")) Is Nothing Then
   
     '**Range definieren
     [COLOR="#FF0000"]Me.Unprotect[/COLOR]
     Set rngDV = Target.SpecialCells(xlCellTypeAllValidation)
     If rngDV Is Nothing Then GoTo Error_Handling
     
     '** Prüfen, ob eine gültige Zelle ausgewählt wurde und Werte eintragen
     If Not Application.Intersect(Target, rngDV) Is Nothing Then
       Application.EnableEvents = False
       wert_new = Target.Value
       Application.Undo
       wert_old = Target.Value
       Target.Value = wert_new
       If wert_old <> "" Then
         If wert_new <> "" Then
           Target.Value = wert_old & ", " & wert_new
         End If
       End If
     End If
Exit_Handling:
     Application.EnableEvents = True
     [COLOR="#FF8C00"]Me.Protect DrawingObjects:=True, Contents:=True, Scenarios:=True[/COLOR]
  End If
  Exit Sub
  
Error_Handling:
  Resume Exit_Handling
End Sub

Dabei schaltet im vorgenannten VBA-Code die rote Zeile den Blattschutz aus und die orangene Zeile schaltet ihn wieder ein.
Dabei wird vorausgesetzt, dass für den Blattschutz kein Passwort verwendet wird und dass alle Zellen (auch die gesperrt gekennzeichneten) ausgewählt werden können.
Falls du ein Passwort verwendest, gilt bezüglich Passwort das, was in deinem zitierten Link erwähnt wurde:
http://www.office-hilfe.com/support/showthread.php/16349-VBA-Ausführung-trotz-Blattschutz
Falls du möchtest, dass gesperrte Zellen im Arbeitsblatt nicht ausgewählt werden dürfen, müsstest statt der orangenen Zeile folgende 2 Zeilen einfügen:

Code:

[COLOR="#FF8C00"]     Me.Protect DrawingObjects:=True, Contents:=True, Scenarios:=True
     Me.EnableSelection = xlUnlockedCells[/COLOR]

 

Hallo, ich hoffe es kann mir geholfen werden:
Ich habe mir den VBA-Code (siehe Anhang) in meiner Tabelle hinterlegt um eine Mehrfachauswahl in einigen Zellen zu treffen.

Wenn ich allerdings mein Blatt schütze funktioniert die Mehrfachauswahl nicht mehr und es wird immer nur der jeweilige Wert eingefügt, den ich gerade anklicke und der vorherige gelöscht/überschrieben. Ich habe mich jetzt schon mehrere Tage durch´s Web gegoogelt, aber nicht das richtige als Abhilfe gefunden. Hat evtl. jemand einen Rat bzw. Tipp für mich???

Der Code im vorherigen Thread funktioniert auch nicht bei mir.

Grüße, Marko